From Code to Community: Sponsoring The Perl and Raku Conference 2025 Learn more

ETJ / PDL-Graphics-TriD-2.102 / lib / PDL / Graphics / TriD / Quaternion.pm 

            

              
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149

              
##############################################
#
# Quaternions... inefficiently.
#
# Should probably use PDL and C... ?
#
# Stored as [c,x,y,z].
#
# XXX REMEMBER!!!! First component = cos(angle/2), *NOT* cos(angle)
package PDL::Graphics::TriD::Quaternion;
use strict;
use warnings;
sub _scalar_wrap {
  my ($v) = @_;
  return PDL::Graphics::TriD::Quaternion->new($v,0,0,0) if !ref $v;
  return PDL::Graphics::TriD::Quaternion->new(@$v) if ref $v eq 'ARRAY';
  $v;
}
use overload
  '=' => sub {$_[0]}, # without this, `$this->{Quat} .= $q` errors
  '.=' => sub {
    my ($a1, $a2) = @_;
    $a1->set(_scalar_wrap $a2);
  },
  '+' => sub {
    my ($a1, $a2, $swap) = @_;
    $a1->add(_scalar_wrap $a2);
  },
  '*' => sub {
    my ($a1, $a2, $swap) = @_;
    $a2 = _scalar_wrap $a2;
    ($a2, $a1) = ($a1, $a2) if $swap;
    $a1->multiply($a2);
  },
  '/' => sub {
    my ($a1, $a2, $swap) = @_;
    $a2 = _scalar_wrap $a2;
    ($a2, $a1) = ($a1, $a2) if $swap;
    $a1->multiply($a2->invert);
  },
  '!' => \&invert,
  '""' => sub { ref($_[0])."->new(".join(',', @{$_[0]}).")" };
sub new {
        my($type,$c,$x,$y,$z) = @_;
        my $this;
   if(ref($type)){
          $this = $type;
        }else{
          $this = bless [$c,$x,$y,$z],$type;
        }
        return $this;
}
sub copy {
  PDL::Graphics::TriD::Quaternion->new(@{$_[0]});
}
sub new_vrmlrot {
        my($type,$x,$y,$z,$c) = @_;
        my $l = sqrt($x**2+$y**2+$z**2);
        my $this = bless [cos($c/2),map {sin($c/2)*$_/$l} $x,$y,$z],$type;
        $this->normalise;
}
sub to_vrmlrot {
        my($this) = @_;
        my $d = POSIX::acos($this->[0]);
        if(abs($d) < 0.0000001) {
                return [0,0,1,0];
        }
        return [(map {$_/sin($d)} @{$this}[1..3]),2*$d];
}
sub multiply {
  my($this,$with) = @_;
  return PDL::Graphics::TriD::Quaternion->new(
        $this->[0] * $with->[0]
      - $this->[1] * $with->[1]
      - $this->[2] * $with->[2]
      - $this->[3] * $with->[3],
            $this->[0] * $with->[1]
          + $this->[1] * $with->[0]
          + $this->[2] * $with->[3]
          - $this->[3] * $with->[2],
        $this->[0] * $with->[2]
      - $this->[1] * $with->[3]
      + $this->[2] * $with->[0]
      + $this->[3] * $with->[1],
            $this->[0] * $with->[3]
          + $this->[1] * $with->[2]
          - $this->[2] * $with->[1]
          + $this->[3] * $with->[0],
  );
}
sub set {
  my($this,$new) = @_;
  @$this = @$new;
  $this;
}
sub add {
  my($this,$with) = @_;
  PDL::Graphics::TriD::Quaternion->new(map $this->[$_]+$with->[$_], 0..3);
}
sub abssq {
        my($this) = @_;
        return  $this->[0] ** 2 +
                $this->[1] ** 2 +
                $this->[2] ** 2 +
                $this->[3] ** 2 ;
}
sub invert {
        my($this) = @_;
        my $abssq = $this->abssq();
        return PDL::Graphics::TriD::Quaternion->new(
                 1/$abssq * $this->[0] ,
                -1/$abssq * $this->[1] ,
                -1/$abssq * $this->[2] ,
                -1/$abssq * $this->[3] );
}
sub invert_rotation_this {
        my($this) = @_;
        $this->[0] = - $this->[0];
}
sub normalise {
  my($this) = @_;
  my $abs = sqrt($this->abssq);
  @$this = map $_/$abs, @$this;
  $this;
}
sub rotate {
  my($this,$vec) = @_;
  my $q = PDL::Graphics::TriD::Quaternion->new(0,@$vec);
  my $m = $this->multiply($q->multiply($this->invert));
  return [@$m[1..3]];
}
1;