NAME

DBD::drizzle - MySQL driver for the Perl5 Database Interface (DBI)

SYNOPSIS

use DBI;

$dsn = "DBI:drizzle:database=$database;host=$hostname;port=$port";

$dbh = DBI->connect($dsn, $user, $password);


$drh = DBI->install_driver("drizzle");
@databases = DBI->data_sources("drizzle");
   or
@databases = DBI->data_sources("drizzle",
  {"host" => $host, "port" => $port, "user" => $user, password => $pass});

$sth = $dbh->prepare("SELECT * FROM foo WHERE bla");
   or
$sth = $dbh->prepare("LISTFIELDS $table");
   or
$sth = $dbh->prepare("LISTINDEX $table $index");
$sth->execute;
$numRows = $sth->rows;
$numFields = $sth->{'NUM_OF_FIELDS'};
$sth->finish;

$rc = $drh->func('createdb', $database, $host, $user, $password, 'admin');
$rc = $drh->func('dropdb', $database, $host, $user, $password, 'admin');
$rc = $drh->func('shutdown', $host, $user, $password, 'admin');
$rc = $drh->func('reload', $host, $user, $password, 'admin');

$rc = $dbh->func('createdb', $database, 'admin');
$rc = $dbh->func('dropdb', $database, 'admin');
$rc = $dbh->func('shutdown', 'admin');
$rc = $dbh->func('reload', 'admin');

EXAMPLE

#!/usr/bin/perl

use strict;
use DBI();

# Connect to the database.
my $dbh = DBI->connect("DBI:drizzle:database=test;host=localhost",
                       "joe", "joe's password",
                       {'RaiseError' => 1});

# Drop table 'foo'. This may fail, if 'foo' doesn't exist.
# Thus we put an eval around it.
eval { $dbh->do("DROP TABLE foo") };
print "Dropping foo failed: $@\n" if $@;

# Create a new table 'foo'. This must not fail, thus we don't
# catch errors.
$dbh->do("CREATE TABLE foo (id INTEGER, name VARCHAR(20))");

# INSERT some data into 'foo'. We are using $dbh->quote() for
# quoting the name.
$dbh->do("INSERT INTO foo VALUES (1, " . $dbh->quote("Tim") . ")");

# Same thing, but using placeholders
$dbh->do("INSERT INTO foo VALUES (?, ?)", undef, 2, "Jochen");

# Now retrieve data from the table.
my $sth = $dbh->prepare("SELECT * FROM foo");
$sth->execute();
while (my $ref = $sth->fetchrow_hashref()) {
  print "Found a row: id = $ref->{'id'}, name = $ref->{'name'}\n";
}
$sth->finish();

# Disconnect from the database.
$dbh->disconnect();

DESCRIPTION

DBD::drizzle is the Perl5 Database Interface driver for the MySQL database. In other words: DBD::drizzle is an interface between the Perl programming language and the MySQL programming API that comes with the MySQL relational database management system. Most functions provided by this programming API are supported. Some rarely used functions are missing, mainly because noone ever requested them. :-)

In what follows we first discuss the use of DBD::drizzle, because this is what you will need the most. For installation, see the sections on INSTALLATION, and "WIN32 INSTALLATION" below. See EXAMPLE for a simple example above.

From perl you activate the interface with the statement

use DBI;

After that you can connect to multiple MySQL database servers and send multiple queries to any of them via a simple object oriented interface. Two types of objects are available: database handles and statement handles. Perl returns a database handle to the connect method like so:

  $dbh = DBI->connect("DBI:drizzle:database=$db;host=$host",
		      $user, $password, {RaiseError => 1});

Once you have connected to a database, you can can execute SQL statements with:

  my $query = sprintf("INSERT INTO foo VALUES (%d, %s)",
		      $number, $dbh->quote("name"));
  $dbh->do($query);

See DBI(3) for details on the quote and do methods. An alternative approach is

  $dbh->do("INSERT INTO foo VALUES (?, ?)", undef,
	   $number, $name);

in which case the quote method is executed automatically. See also the bind_param method in DBI(3). See "DATABASE HANDLES" below for more details on database handles.

If you want to retrieve results, you need to create a so-called statement handle with:

$sth = $dbh->prepare("SELECT * FROM $table");
$sth->execute();

This statement handle can be used for multiple things. First of all you can retreive a row of data:

my $row = $sth->fetchrow_hashref();

If your table has columns ID and NAME, then $row will be hash ref with keys ID and NAME. See "STATEMENT HANDLES" below for more details on statement handles.

But now for a more formal approach:

Class Methods

connect

use DBI;

$dsn = "DBI:drizzle:$database";
$dsn = "DBI:drizzle:database=$database;host=$hostname";
$dsn = "DBI:drizzle:database=$database;host=$hostname;port=$port";

$dbh = DBI->connect($dsn, $user, $password);

A database must always be specified.

host

port

The hostname, if not specified or specified as '' or 'localhost', will default to a MySQL server running on the local machine using the default for the UNIX socket. To connect to a MySQL server on the local machine via TCP, you must specify the loopback IP address (127.0.0.1) as the host.

Should the MySQL server be running on a non-standard port number, you may explicitly state the port number to connect to in the hostname argument, by concatenating the hostname and port number together separated by a colon ( : ) character or by using the port argument.

To connect to a MySQL server on localhost using TCP/IP, you must specify the hostname as 127.0.0.1 (with the optional port).

drizzle_client_found_rows

Enables (TRUE value) or disables (FALSE value) the flag CLIENT_FOUND_ROWS while connecting to the MySQL server. This has a somewhat funny effect: Without drizzle_client_found_rows, if you perform a query like

UPDATE $table SET id = 1 WHERE id = 1

then the MySQL engine will always return 0, because no rows have changed. With drizzle_client_found_rows however, it will return the number of rows that have an id 1, as some people are expecting. (At least for compatibility to other engines.)

drizzle_compression

As of MySQL 3.22.3, a new feature is supported: If your DSN contains the option "drizzle_compression=1", then the communication between client and server will be compressed.

drizzle_connect_timeout

If your DSN contains the option "drizzle_connect_timeout=##", the connect request to the server will timeout if it has not been successful after the given number of seconds.

drizzle_read_default_file

drizzle_read_default_group

These options can be used to read a config file like /etc/my.cnf or ~/.my.cnf. By default MySQL's C client library doesn't use any config files unlike the client programs (drizzle, drizzleadmin, ...) that do, but outside of the C client library. Thus you need to explicitly request reading a config file, as in

$dsn = "DBI:drizzle:test;drizzle_read_default_file=/home/joe/my.cnf";
$dbh = DBI->connect($dsn, $user, $password)

The option drizzle_read_default_group can be used to specify the default group in the config file: Usually this is the client group, but see the following example:

[client]
host=localhost

[perl]
host=perlhost

(Note the order of the entries! The example won't work, if you reverse the [client] and [perl] sections!)

If you read this config file, then you'll be typically connected to localhost. However, by using

$dsn = "DBI:drizzle:test;drizzle_read_default_group=perl;"
    . "drizzle_read_default_file=/home/joe/my.cnf";
$dbh = DBI->connect($dsn, $user, $password);

you'll be connected to perlhost. Note that if you specify a default group and do not specify a file, then the default config files will all be read. See the documentation of the C function drizzle_options() for details.

drizzle_socket

As of MySQL 3.21.15, it is possible to choose the Unix socket that is used for connecting to the server. This is done, for example, with

drizzle_socket=/dev/drizzle

Usually there's no need for this option, unless you are using another location for the socket than that built into the client.

drizzle_ssl

A true value turns on the CLIENT_SSL flag when connecting to the MySQL database:

drizzle_ssl=1

This means that your communication with the server will be encrypted.

If you turn drizzle_ssl on, you might also wish to use the following flags:

drizzle_ssl_client_key

drizzle_ssl_client_cert

drizzle_ssl_ca_file

drizzle_ssl_ca_path

drizzle_ssl_cipher

These are used to specify the respective parameters of a call to drizzle_ssl_set, if drizzle_ssl is turned on.

drizzle_local_infile

As of MySQL 3.23.49, the LOCAL capability for LOAD DATA may be disabled in the MySQL client library by default. If your DSN contains the option "drizzle_local_infile=1", LOAD DATA LOCAL will be enabled. (However, this option is *ineffective* if the server has also been configured to disallow LOCAL.)

Need to find out about this for drizzle

Prepared statement support (server side prepare)

Drizzle does not support server side prepared statements.

Private MetaData Methods

ListDBs

my $drh = DBI->install_driver("drizzle");
@dbs = $drh->func("$hostname:$port", '_ListDBs');
@dbs = $drh->func($hostname, $port, '_ListDBs');
@dbs = $dbh->func('_ListDBs');

Returns a list of all databases managed by the MySQL server running on $hostname, port $port. This is a legacy method. Instead, you should use the portable method

@dbs = DBI->data_sources("drizzle");

Server Administration

admin

$rc = $drh->func("createdb", $dbname, [host, user, password,], 'admin');
$rc = $drh->func("dropdb", $dbname, [host, user, password,], 'admin');
$rc = $drh->func("shutdown", [host, user, password,], 'admin');
$rc = $drh->func("reload", [host, user, password,], 'admin');

  or

$rc = $dbh->func("createdb", $dbname, 'admin');
$rc = $dbh->func("dropdb", $dbname, 'admin');
$rc = $dbh->func("shutdown", 'admin');
$rc = $dbh->func("reload", 'admin');

For server administration you need a server connection. For obtaining this connection you have two options: Either use a driver handle (drh) and supply the appropriate arguments (host, defaults localhost, user, defaults to '' and password, defaults to ''). A driver handle can be obtained with

$drh = DBI->install_driver('drizzle');

Otherwise reuse the existing connection of a database handle (dbh).

There's only one function available for administrative purposes, comparable to the m(y)sqladmin programs. The command being execute depends on the first argument:

createdb

Creates the database $dbname. Equivalent to "m(y)sqladmin create $dbname".

dropdb

Drops the database $dbname. Equivalent to "m(y)sqladmin drop $dbname".

It should be noted that database deletion is not prompted for in any way. Nor is it undo-able from DBI.

Once you issue the dropDB() method, the database will be gone!

These method should be used at your own risk.

shutdown

Silently shuts down the database engine. (Without prompting!) Equivalent to "m(y)sqladmin shutdown".

reload

Reloads the servers configuration files and/or tables. This can be particularly important if you modify access privileges or create new users.

DATABASE HANDLES

The DBD::drizzle driver supports the following attributes of database handles (read only):

$errno = $dbh->{'drizzle_errno'};
$error = $dbh->{'drizzle_error'};
$info = $dbh->{'drizzle_hostinfo'};
$info = $dbh->{'drizzle_info'};
$insertid = $dbh->{'drizzle_insertid'};
$info = $dbh->{'drizzle_protoinfo'};
$info = $dbh->{'drizzle_serverinfo'};
$info = $dbh->{'drizzle_stat'};
$threadId = $dbh->{'drizzle_thread_id'};

These correspond to drizzle_errno(), drizzle_error(), drizzle_get_host_info(), drizzle_info(), drizzle_insert_id(), drizzle_get_proto_info(), drizzle_get_server_info(), drizzle_stat() and drizzle_thread_id(), respectively.

$info_hashref = $dhb->{drizzle_dbd_stats}

DBD::drizzle keeps track of some statistics in the drizzle_dbd_stats attribute. The following stats are being maintained:

auto_reconnects_ok

The number of times that DBD::drizzle successfully reconnected to the drizzle server.

auto_reconnects_failed

The number of times that DBD::drizzle tried to reconnect to drizzle but failed.

The DBD::drizzle driver also supports the following attribute(s) of database handles (read/write):

$bool_value = $dbh->{drizzle_auto_reconnect};
$dbh->{drizzle_auto_reconnect} = $AutoReconnect ? 1 : 0;

drizzle_auto_reconnect

This attribute determines whether DBD::drizzle will automatically reconnect to drizzle if the connection be lost. This feature defaults to off; however, if either the GATEWAY_INTERFACE or MOD_PERL envionment variable is set, DBD::drizzle will turn drizzle_auto_reconnect on. Setting drizzle_auto_reconnect to on is not advised if 'lock tables' is used because if DBD::drizzle reconnect to drizzle all table locks will be lost. This attribute is ignored when AutoCommit is turned off, and when AutoCommit is turned off, DBD::drizzle will not automatically reconnect to the server.

drizzle_use_result

This attribute forces the driver to use drizzle_use_result rather than drizzle_store_result. The former is faster and less memory consuming, but tends to block other processes. (That's why drizzle_store_result is the default.)

It is possible to set default value of the drizzle_use_result attribute for $dbh using several ways:

- through DSN 

  $dbh= DBI->connect("DBI:drizzle:test;drizzle_use_result=1", "root", "");

- after creation of database handle

  $dbh->{'drizzle_use_result'}=0; #disable
  $dbh->{'drizzle_use_result'}=1; #enable

It is possible to set/unset the drizzle_use_result attribute after creation of statement handle. See below.

drizzle_enable_utf8

This attribute determines whether DBD::drizzle should assume strings stored in the database are utf8. This feature defaults to off.

When set, a data retrieved from a textual column type (char, varchar, etc) will have the UTF-8 flag turned on if necessary. This enables character semantics on that string. You will also need to ensure that your database / table / column is configured to use UTF8. See Chapter 10 of the drizzle manual for details.

Additionally, turning on this flag tells MySQL that incoming data should be treated as UTF-8. This will only take effect if used as part of the call to connect(). If you turn the flag on after connecting, you will need to issue the command SET NAMES utf8 to get the same effect.

This option is experimental and may change in future versions.

STATEMENT HANDLES

The statement handles of DBD::drizzle support a number of attributes. You access these by using, for example,

my $numFields = $sth->{'NUM_OF_FIELDS'};

Note, that most attributes are valid only after a successfull execute. An undef value will returned in that case. The most important exception is the drizzle_use_result attribute: This forces the driver to use drizzle_use_result rather than drizzle_store_result. The former is faster and less memory consuming, but tends to block other processes. (That's why drizzle_store_result is the default.)

To set the drizzle_use_result attribute, use either of the following:

my $sth = $dbh->prepare("QUERY", { "drizzle_use_result" => 1});

or

my $sth = $dbh->prepare("QUERY");
$sth->{"drizzle_use_result"} = 1;

Column dependent attributes, for example NAME, the column names, are returned as a reference to an array. The array indices are corresponding to the indices of the arrays returned by fetchrow and similar methods. For example the following code will print a header of table names together with all rows:

  my $sth = $dbh->prepare("SELECT * FROM $table");
  if (!$sth) {
      die "Error:" . $dbh->errstr . "\n";
  }
  if (!$sth->execute) {
      die "Error:" . $sth->errstr . "\n";
  }
  my $names = $sth->{'NAME'};
  my $numFields = $sth->{'NUM_OF_FIELDS'};
  for (my $i = 0;  $i < $numFields;  $i++) {
      printf("%s%s", $i ? "," : "", $$names[$i]);
  }
  print "\n";
  while (my $ref = $sth->fetchrow_arrayref) {
      for (my $i = 0;  $i < $numFields;  $i++) {
	  printf("%s%s", $i ? "," : "", $$ref[$i]);
      }
      print "\n";
  }

For portable applications you should restrict yourself to attributes with capitalized or mixed case names. Lower case attribute names are private to DBD::drizzle. The attribute list includes:

ChopBlanks

this attribute determines whether a fetchrow will chop preceding and trailing blanks off the column values. Chopping blanks does not have impact on the max_length attribute.

drizzle_insertid

MySQL has the ability to choose unique key values automatically. If this happened, the new ID will be stored in this attribute. An alternative way for accessing this attribute is via $dbh->{'drizzle_insertid'}. (Note we are using the $dbh in this case!)

drizzle_is_blob

Reference to an array of boolean values; TRUE indicates, that the respective column is a blob. This attribute is valid for MySQL only.

drizzle_is_key

Reference to an array of boolean values; TRUE indicates, that the respective column is a key. This is valid for MySQL only.

drizzle_is_num

Reference to an array of boolean values; TRUE indicates, that the respective column contains numeric values.

drizzle_is_pri_key

Reference to an array of boolean values; TRUE indicates, that the respective column is a primary key.

drizzle_is_auto_increment

Reference to an array of boolean values; TRUE indicates that the respective column is an AUTO_INCREMENT column. This is only valid for MySQL.

drizzle_length

drizzle_max_length

A reference to an array of maximum column sizes. The max_length is the maximum physically present in the result table, length gives the theoretically possible maximum. max_length is valid for MySQL only.

NAME

A reference to an array of column names.

NULLABLE

A reference to an array of boolean values; TRUE indicates that this column may contain NULL's.

NUM_OF_FIELDS

Number of fields returned by a SELECT or LISTFIELDS statement. You may use this for checking whether a statement returned a result: A zero value indicates a non-SELECT statement like INSERT, DELETE or UPDATE.

drizzle_table

A reference to an array of table names, useful in a JOIN result.

TYPE

A reference to an array of column types. The engine's native column types are mapped to portable types like DBI::SQL_INTEGER() or DBI::SQL_VARCHAR(), as good as possible. Not all native types have a meaningfull equivalent, for example DBD::drizzle::FIELD_TYPE_INTERVAL is mapped to DBI::SQL_VARCHAR(). If you need the native column types, use drizzle_type. See below.

drizzle_type

A reference to an array of MySQL's native column types, for example DBD::drizzle::FIELD_TYPE_SHORT() or DBD::drizzle::FIELD_TYPE_STRING(). Use the TYPE attribute, if you want portable types like DBI::SQL_SMALLINT() or DBI::SQL_VARCHAR().

drizzle_type_name

Similar to drizzle, but type names and not numbers are returned. Whenever possible, the ANSI SQL name is preferred.

drizzle_warning_count

The number of warnings generated during execution of the SQL statement.

TRANSACTION SUPPORT

Beginning with DBD::drizzle 2.0416, transactions are supported. The transaction support works as follows:

• By default AutoCommit mode is on, following the DBI specifications.

• If you execute

  $dbh->{'AutoCommit'} = 0;

  or

  $dbh->{'AutoCommit'} = 1;

  then the driver will set the MySQL server variable autocommit to 0 or 1, respectively. Switching from 0 to 1 will also issue a COMMIT, following the DBI specifications.

• The methods

  $dbh->rollback();
  $dbh->commit();

  will issue the commands COMMIT and ROLLBACK, respectively. A ROLLBACK will also be issued if AutoCommit mode is off and the database handles DESTROY method is called. Again, this is following the DBI specifications.

Given the above, you should note the following:

• You should never change the server variable autocommit manually, unless you are ignoring DBI's transaction support.

• Switching AutoCommit mode from on to off or vice versa may fail. You should always check for errors, when changing AutoCommit mode. The suggested way of doing so is using the DBI flag RaiseError. If you don't like RaiseError, you have to use code like the following:

  $dbh->{'AutoCommit'} = 0;
  if ($dbh->{'AutoCommit'}) {
    # An error occurred!
  }

• If you detect an error while changing the AutoCommit mode, you should no longer use the database handle. In other words, you should disconnect and reconnect again, because the transaction mode is unpredictable. Alternatively you may verify the transaction mode by checking the value of the server variable autocommit. However, such behaviour isn't portable.

• DBD::drizzle has a "reconnect" feature that handles the so-called MySQL "morning bug": If the server has disconnected, most probably due to a timeout, then by default the driver will reconnect and attempt to execute the same SQL statement again. However, this behaviour is disabled when AutoCommit is off: Otherwise the transaction state would be completely unpredictable after a reconnect.

• The "reconnect" feature of DBD::drizzle can be toggled by using the drizzle_auto_reconnect attribute. This behaviour should be turned off in code that uses LOCK TABLE because if the database server time out and DBD::drizzle reconnect, table locks will be lost without any indication of such loss.

MULTIPLE RESULT SETS

As of version 3.0002_5, DBD::drizzle supports multiple result sets (Thanks to Guy Harrison!). This is the first release of this functionality, so there may be issues. Please report bugs if you run into them!

The basic usage of multiple result sets is

do 
{
  while (@row= $sth->fetchrow_array())
  {
    do stuff;
  }
} while ($sth->more_results)

An example would be:

 $dbh->do("drop procedure if exists someproc") or print $DBI::errstr;

 $dbh->do("create procedure somproc() deterministic
  begin
  declare a,b,c,d int;
  set a=1;
  set b=2;
  set c=3;
  set d=4;
  select a, b, c, d;
  select d, c, b, a;
  select b, a, c, d;
  select c, b, d, a;
 end") or print $DBI::errstr;

 $sth=$dbh->prepare('call someproc()') || 
 die $DBI::err.": ".$DBI::errstr;

 $sth->execute || die DBI::err.": ".$DBI::errstr; $rowset=0;
 do {
   print "\nRowset ".++$i."\n---------------------------------------\n\n";
   foreach $colno (0..$sth->{NUM_OF_FIELDS}) {
     print $sth->{NAME}->[$colno]."\t";
   }
   print "\n";
   while (@row= $sth->fetchrow_array())  {
     foreach $field (0..$#row) {
       print $row[$field]."\t";
     }
     print "\n";
   }
 } until (!$sth->more_results)

For more examples, please see the eg/ directory. This is where helpful DBD::drizzle code snippits will be added in the future.

Issues with Multiple result sets

So far, the main issue is if your result sets are "jagged", meaning, the number of columns of your results vary. Varying numbers of columns could result in your script crashing. This is something that will be fixed soon.

MULTITHREADING

The multithreading capabilities of DBD::drizzle depend completely on the underlying C libraries: The modules are working with handle data only, no global variables are accessed or (to the best of my knowledge) thread unsafe functions are called. Thus DBD::drizzle is believed to be completely thread safe, if the C libraries are thread safe and you don't share handles among threads.

The obvious question is: Are the C libraries thread safe? In the case of MySQL the answer is "mostly" and, in theory, you should be able to get a "yes", if the C library is compiled for being thread safe (By default it isn't.) by passing the option -with-thread-safe-client to configure. See the section on How to make a threadsafe client in the manual.

INSTALLATION

Windows users may skip this section and pass over to "WIN32 INSTALLATION" below. Others, go on reading.

First of all, you do not need an installed MySQL server for installing DBD::drizzle. However, you need at least the client libraries and possibly the header files, if you are compiling DBD::drizzle from source. In the case of MySQL you can create a client-only version by using the configure option --without-server. If you are using precompiled binaries, then it may be possible to use just selected RPM's like MySQL-client and MySQL-devel or something similar, depending on the distribution.

First you need to install the DBI module. For using dbimon, a simple DBI shell it is recommended to install Data::ShowTable another Perl module.

I recommend trying automatic installation via the CPAN module. Try

perl -MCPAN -e shell

If you are using the CPAN module for the first time, it will prompt you a lot of questions. If you finally receive the CPAN prompt, enter

install Bundle::DBD::drizzle

If this fails (which may be the case for a number of reasons, for example because you are behind a firewall or don't have network access), you need to do a manual installation. First of all you need to fetch the modules from CPAN search

http://search.cpan.org/ 

The following modules are required

DBI
Data::ShowTable
DBD::drizzle

Then enter the following commands (note - versions are just examples):

gzip -cd DBI-(version).tar.gz | tar xf -
cd DBI-(version)
perl Makefile.PL
make
make test
make install

cd ..
gzip -cd Data-ShowTable-(version).tar.gz | tar xf -
cd Data-ShowTable-3.3
perl Makefile.PL
make
make install

cd ..
gzip -cd DBD-drizzle-(version)-tar.gz | tar xf -
cd DBD-drizzle-(version)
perl Makefile.PL
make
make test
make install

During "perl Makefile.PL" you will be prompted some questions. Other questions are the directories with header files and libraries. For example, of your file drizzle.h is in /usr/include/drizzle/drizzle.h, then enter the header directory /usr, likewise for /usr/lib/drizzle/libdrizzleclient.a or /usr/lib/libdrizzleclient.so.

WIN32 INSTALLATION

There currently is no support for Drizzle or DBD::drizzle on windows. The documentation below is a remnant o DBD::mysql left here in the event that windows support becomes manifest.

If you are using ActivePerl, you may use ppm to install DBD-drizzle. For Perl 5.6, upgrade to Build 623 or later, then it is sufficient to run

ppm install DBI
ppm install DBD::drizzle

If you need an HTTP proxy, you might need to set the environment variable http_proxy, for example like this:

set http_proxy=http://myproxy.com:8080/

As of this writing, DBD::drizzle is missing in the ActivePerl 5.8.0 repository. However, Randy Kobes has kindly donated an own distribution and the following might succeed:

ppm install http://theoryx5.uwinnipeg.ca/ppms/DBD-drizzle.ppd

Otherwise you definitely *need* a C compiler. And it *must* be the same compiler that was being used for compiling Perl itself. If you don't have a C compiler, the file README.win32 from the Perl source distribution tells you where to obtain freely distributable C compilers like egcs or gcc. The Perl sources are available via CPAN search

http://search.cpan.org

I recommend using the win32clients package for installing DBD::drizzle under Win32, available for download on www.tcx.se. The following steps have been required for me:

-

The current Perl versions (5.6, as of this writing) do have a problem with detecting the C libraries. I recommend to apply the following patch:

*** c:\Perl\lib\ExtUtils\Liblist.pm.orig Sat Apr 15 20:03:40 2000
--- c:\Perl\lib\ExtUtils\Liblist.pm      Sat Apr 15 20:03:45 2000
***************
*** 230,235 ****
--- 230,239 ----
    # add "$Config{installarchlib}/CORE" to default search path
    push @libpath, "$Config{installarchlib}/CORE";

+     if ($VC  and  exists($ENV{LIB})  and  defined($ENV{LIB})) {
+       push(@libpath, split(/;/, $ENV{LIB}));
+     }
+
    foreach (Text::ParseWords::quotewords('\s+', 0, $potential_libs)){

      $thislib = $_;
                                                                     

-

Extract sources into C:\. This will create a directory C:\drizzle with subdirectories include and lib.

IMPORTANT: Make sure this subdirectory is not shared by other TCX files! In particular do *not* store the MySQL server in the same directory. If the server is already installed in C:\drizzle, choose a location like C:\tmp, extract the win32clients there. Note that you can remove this directory entirely once you have installed DBD::drizzle.

-

Extract the DBD::drizzle sources into another directory, for example C:\src\siteperl

-

Open a DOS shell and change directory to C:\src\siteperl.

-

The next step is only required if you repeat building the modules: Make sure that you have a clean build tree by running

nmake realclean

If you don't have VC++, replace nmake with your flavour of make. If error messages are reported in this step, you may safely ignore them.

-

Run

perl Makefile.PL

which will prompt you for some settings. The really important ones are:

Which DBMS do you want to use?

enter a 1 here (MySQL only), and

Where is your drizzle installed? Please tell me the directory that
contains the subdir include.

where you have to enter the win32clients directory, for example C:\drizzle or C:\tmp\drizzle.

-

Continued in the usual way:

nmake
nmake install

If you want to create a PPM package for the ActiveState Perl version, then modify the above steps as follows: Run

perl Makefile.PL NAME=DBD-drizzle BINARY_LOCATION=DBD-drizzle.tar.gz
nmake ppd
nmake

Once that is done, use tar and gzip (for example those from the CygWin32 distribution) to create an archive:

mkdir x86
tar cf x86/DBD-drizzle.tar blib
gzip x86/DBD-drizzle.tar

Put the files x86/DBD-drizzle.tar.gz and DBD-drizzle.ppd onto some WWW server and install them by typing

install http://your.server.name/your/directory/DBD-drizzle.ppd

in the PPM program.

AUTHORS

The current version of DBD::drizzle is based off of DBD::mysql which the majority of was written by Jochen Wiedmann. Much code was re-shuffled, sliced, diced and decrufticated by Patrick Galbraith (patg@drizzle.com) and Clint Byrum (clint@fewbar.com) to work with Drizzle.

The first version's author was Alligator Descartes, who was aided and abetted by Gary Shea, Andreas König and Tim Bunce amongst others. Also credit goes to Rudy Lippan for his stewardship, development (emulation) and maintenance of DBD::mysql for several years.

COPYRIGHT

This module is Large Portions Copyright (c) 2004-2009 Patrick Galbraith, Clint Byrum Alexey Stroganov 2004-2006, Large Portions Copyright (c) 2003-2005 Rudolf Lippan; Large Portions Copyright (c) 1997-2003 Jochen Wiedmann, with code portions Copyright (c)1994-1997 their original authors This module is released under the same license as Perl itself. See the Perl README for details.

MAILING LIST SUPPORT

This module is maintained and supported on a mailing list,

perl@lists.drizzle.com

To subscribe to this list, go to

http://lists.drizzle.com/perl?sub=1

Mailing list archives are available at

http://lists.drizzle.com/perl

Additionally you might try the dbi-user mailing list for questions about DBI and its modules in general. Subscribe via

dbi-users-subscribe@perl.org

Mailing list archives are at

http://groups.google.com/group/perl.dbi.users?hl=en&lr=

Also, the main DBI site is at

http://dbi.perl.org/

ADDITIONAL DBI INFORMATION

Additional information on the DBI project can be found on the World Wide Web at the following URL:

http://dbi.perl.org

where documentation, pointers to the mailing lists and mailing list archives and pointers to the most current versions of the modules can be used.

Information on the DBI interface itself can be gained by typing:

perldoc DBI

right now!

BUG REPORTING, ENHANCEMENT/FEATURE REQUESTS

Please report bugs, including all the information needed such as DBD::drizzle version, DRIZZLE version, OS type/version, etc to this link:

https://code.launchpad.net/drizzle

cpanm DBD::drizzle

perl -MCPAN -e shell
install DBD::drizzle