NAME

Test::Count - Module for keeping track of the number of tests in a test script.

VERSION

version 0.1105

SYNOPSIS

    $ cat "t/mytest.t" | perl -MTest::Count::Filter -e 'filter()'

DESCRIPTION

Test::Count is a set of perl modules for keeping track of the number of tests in a test file. It works by putting in comments of the form # TEST (one test), # TEST*$EXPR or # TEST+$EXPR (both are multiple tests). Test::Count count these tests throughout the fileand return all of their results.

One can put any mathematical expressions (using parentheses, +, -, *, / and % there). One can also assign variables using # TEST:$myvar=5+6;$second_var=$myvar+3 and later use them in the add to count expressions. A $var++ construct is also available.

One can find example test scripts under t/.

A simple Vim (http://www.vim.org/) function to update the count of the tests in the file is:

    function! Perl_Tests_Count()
        %!perl -MTest::Count::Filter -e 'Test::Count::Filter->new({})->process()'
    endfunction

FUNCTIONS

my $counter = Test::Count->new({'input_fh' => \*MYFILEHANDLE});

Creates a new Test::Count object that process the filehandle specified in 'input_fh'. Optional keys are:

• 'assert_prefix_regex' => qr{; TEST}

  A regular expression for specifying the prefix for a "TEST" assertion that updates the grammar. Defaults to "# TEST".

$counter->process();

Process the filehandle specified in 'input_fh' in ->new(), and return a hash ref with the following keys:

• tests_count

  The count of the test.

• lines

  The lines of the stream as is.

GRAMMAR DESCRIPTION

You can put any mathematical expressions (using parentheses, +, -, *, / and % there). You can also assign variables using # TEST:$myvar=5+6;$second_var=$myvar+3 and later use them in the add to count expressions. A $var++ construct is also available. Also available are +=, -= and *=.

You can also do # TEST:source "path-to-file-here.txt" where the filename comes in quotes, in order to include the filename and process it (similar to the C-shell or Bash "source" command) . You can use the special variable $^CURRENT_DIRNAME there for the dirname of the current file.

Finally, # TEST*EXPR() and # TEST+$EXPR() add tests to the count.

EXAMPLES

Trivial

The first example is very trivial:

    #!/usr/bin/perl

    use strict;
    use warnings;

    use Test::More tests => 2;

    # TEST
    ok (1, "True is true.");

    {
        my $val = 'foobar';

        # TEST
        is ($val, 'foobar', 'The variable $val has the right value.');
    }

As you can see, the # TEST comments are very close to the assertions where they are easily noticable and easy to maintain by the tests (if more tests are added or removed).

Loops

Now, let's suppose you have several files which you'd like to make sure validate according to the spec, and are processed well using the processor.

    #!/usr/bin/perl

    use strict;
    use warnings;

    use Test::More tests => 18;
    use IO::All qw/ io /;
    use Test::Differences qw/ eq_or_diff /;

    use MyFormatProcessor ();

    # TEST:$num_files=6;
    my @basenames =
    (qw(
        basic
        with_ampersands
        with_comments
        with_bold
        with_italics
        with_bold_and_italics
    ));

    foreach my $basename (@basenames)
    {
        my $processor = MyFormatProcessor->new(
            {
                filename => "t/data/input/$basename.myformat",
            }
        );

        # TEST*$num_files
        ok ($processor,
            "Construction of a processor for '$basename' was successful."
        );

        # TEST*$num_files
        ok (scalar($processor->is_valid()), "'$basename' is valid.");

        # TEST*$num_files
        eq_or_diff ($processor->convert_to_xhtml,
            scalar(io("t/data/want-output/$basename.xhtml")->slurp()),
            "Converting '$basename' is successful."
        );
    }

As you can see, the number of files is kept in one central place, and each assertion inside the loop is multiplied by it. So if we add or remove files, we only need to add or remove them from their declarations.

Loops using FILTER()

Starting from Test::Count version 0.1100 one can also use the FILTER(MULT($expr)) and ENDFILTER() notations.

    #!/usr/bin/perl

    use strict;
    use warnings;

    use Test::More tests => 18;
    use IO::All qw/ io /;
    use Test::Differences qw/ eq_or_diff /;

    use MyFormatProcessor ();

    # TEST:$num_files=6;
    my @basenames =
    (qw(
        basic
        with_ampersands
        with_comments
        with_bold
        with_italics
        with_bold_and_italics
    ));

    # TEST:FILTER(MULT($num_files))
    foreach my $basename (@basenames)
    {
        my $processor = MyFormatProcessor->new(
            {
                filename => "t/data/input/$basename.myformat",
            }
        );

        # TEST
        ok ($processor,
            "Construction of a processor for '$basename' was successful."
        );

        # TEST
        ok (scalar($processor->is_valid()), "'$basename' is valid.");

        # TEST
        eq_or_diff ($processor->convert_to_xhtml,
            scalar(io("t/data/want-output/$basename.xhtml")->slurp()),
            "Converting '$basename' is successful."
        );
    }
    # TEST:ENDFILTER()

AUTHOR

Shlomi Fish, http://www.shlomifish.org/ .

ACKNOWLEDGEMENTS

COPYRIGHT & LICENSE

Copyright 2006 Shlomi Fish.

This program is released under the following license: MIT X11.

SUPPORT

Websites

The following websites have more information about this module, and may be of help to you. As always, in addition to those websites please use your favorite search engine to discover more resources.

• MetaCPAN

  A modern, open-source CPAN search engine, useful to view POD in HTML format.

  https://metacpan.org/release/Test-Count

• RT: CPAN's Bug Tracker

  The RT ( Request Tracker ) website is the default bug/issue tracking system for CPAN.

  https://rt.cpan.org/Public/Dist/Display.html?Name=Test-Count

• CPANTS

  The CPANTS is a website that analyzes the Kwalitee ( code metrics ) of a distribution.

  http://cpants.cpanauthors.org/dist/Test-Count

• CPAN Testers

  The CPAN Testers is a network of smoke testers who run automated tests on uploaded CPAN distributions.

  http://www.cpantesters.org/distro/T/Test-Count

• CPAN Testers Matrix

  The CPAN Testers Matrix is a website that provides a visual overview of the test results for a distribution on various Perls/platforms.

  http://matrix.cpantesters.org/?dist=Test-Count

• CPAN Testers Dependencies

  The CPAN Testers Dependencies is a website that shows a chart of the test results of all dependencies for a distribution.

  http://deps.cpantesters.org/?module=Test::Count

Bugs / Feature Requests

Please report any bugs or feature requests by email to bug-test-count at rt.cpan.org, or through the web interface at https://rt.cpan.org/Public/Bug/Report.html?Queue=Test-Count. You will be automatically notified of any progress on the request by the system.

Source Code

The code is open to the world, and available for you to hack on. Please feel free to browse it and play with it, or whatever. If you want to contribute patches, please send me a diff or prod me to pull from your repository :)

https://github.com/shlomif/perl-test-count

  git clone git://github.com/shlomif/perl-test-count.git

AUTHOR

Shlomi Fish <shlomif@cpan.org>

BUGS

Please report any bugs or feature requests on the bugtracker website https://github.com/shlomif/perl-test-count/issues

When submitting a bug or request, please include a test-file or a patch to an existing test-file that illustrates the bug or desired feature.

COPYRIGHT AND LICENSE

This software is Copyright (c) 2006 by Shlomi Fish.

This is free software, licensed under:

  The MIT (X11) License

cpanm Test::Count

perl -MCPAN -e shell
install Test::Count