NAME

Exception::Class - A module that allows you to declare real exception classes in Perl

SYNOPSIS

  use Exception::Class (
                  'MyException',
                  'AnotherException' => { isa => 'MyException' },
                  'YetAnotherException' => { isa => 'AnotherException',
                                             description => 'These exceptions are related to IPC' }                                  );

  eval { MyException->throw( error => 'I feel funny.'; };

  print $@->error, "\n";

  MyException->Trace(1);
  eval { MyException->throw( error => 'I feel funnier.'; };

  print $@->error, "\n", $@->trace->as_string, "\n";
  print join ' ',  $@->euid, $@->egid, $@->uid, $@->gid, $@->pid, $@->time;

  # catch
  if ($@->isa('MyException'))
  {
     do_something();
  }
  elsif ($@->isa('FooException'))
  {
     go_foo_yourself();
  }
  else
  {
     $@->rethrow;
  }

DESCRIPTION

Exception::Class allows you to declare exceptions in your modules in a manner similar to how exceptions are declared in Java.

It features a simple interface allowing programmers to 'declare' exception classes at compile time. It also has a base exception class, Exception::Class::Base, that can be used for classes stored in files (aka modules ;) ) that are subclasses.

It is designed to make structured exception handling simpler and better by encouraging people to use hierarchies of exceptions in their applications.

NOTE: This module does not implement any try/catch syntax. Please see the OTHER EXCEPTION MODULES (try/catch syntax) section for more information on how to get this syntax.

DECLARING EXCEPTION CLASSES

The 'use Exception::Class' syntax lets you automagically create the relevant Exception::Class::Base subclasses. You can also create subclasses via the traditional means of external modules loaded via 'use'. These two methods may be combined.

The syntax for the magic declarations is as follows:

'MANDATORY CLASS NAME' => \%optional_hashref

The hashref may contain two options:

• isa

  This is the class's parent class. If this isn't provided then the class name is $Exception::Class::BASE_EXC_CLASS is assumed to be the parent (see below).

  This parameter lets you create arbitrarily deep class hierarchies. This can be any other Exception::Class::Base subclass in your declaration _or_ a subclass loaded from a module.

  To change the default exception class you will need to change the value of $Exception::Class::BASE_EXC_CLASS _before_ calling import. To do this simply do something like this:

  BEGIN { $Exception::Class::BASE_EXC_CLASS = 'SomeExceptionClass'; }

  If anyone can come up with a more elegant way to do this please let me know.

  CAVEAT: If you want to automagically subclass an Exception::Class::Base subclass loaded from a file, then you _must_ compile the class (via use or require or some other magic) _before_ you do 'use Exception::Class' or you'll get a compile time error.

  This may change if I decide to use Perl 5.6's CHECK blocks, which could allow even more crazy automagicalness (which may or may not be a good thing).

• fields

  This allows you to define additional attributes for your exception class. Any field you define can be passed to the throw method as an additional parameter for the constructor. In addition, your exception object will have an accessor method for the fields you define.

  This parameter can be either a scalar (for a single field) or an array reference if you need to define multiple fields.

  Fields will be inherited by subclasses.

• description

  Each exception class has a description method that returns a fixed string. This should describe the exception _class_ (as opposed to the particular exception being thrown). This is useful for debugging if you start catching exceptions you weren't expecting (particularly if someone forgot to document them) and you don't understand the error messages.

The Exception::Class magic attempts to detect circular class hierarchies and will die if it finds one. It also detects missing links in a chain so if you declare Bar to be a subclass of Foo and never declare Foo then it will also die.

Exception::Class::Base CLASS METHODS

• Trace($true_or_false)

  Each Exception::Class::Base subclass can be set individually to include a a stracktrace when the as_string method is called.. The default is to not include a stacktrace. Calling this method with a value changes this behavior. It always returns the current value (after any change is applied).

  This value is inherited by any subclasses. However, if this value is set for a subclass, it will thereafter be independent of the value in Exception::Class::Base.

  This is a class method, not an object method.

• throw( message => $message ) OR throw ( error => $error )

  This method creates a new Exception::Class::Base object with the given error message. If no error message is given, $! is used. It then die's with this object as its argument.

  This method also takes a show_trace parameter which indicates whether or not the particular exception object being created should show a stacktrace when its as_string method is called. This overrides the value of Trace for this class if it is given.

• new( message => $message ) OR new ( error => $error )

  Returns a new Exception::Class::Base object with the given error message. If no message is given, $! is used instead.

  This method also takes a show_trace parameter which indicates whether or not the particular exception object being created should show a stacktrace when its as_string method is called. This overrides the value of Trace for this class if it is given.

• description

  Returns the description for the given Exception::Class::Base subclass. The Exception::Class::Base class's description is 'Generic exception' (this may change in the future). This is also an object method.

Exception::Class::Base OBJECT METHODS

• rethrow

  Simply dies with the object as its sole argument. It's just syntactic sugar. This does not change any of the object's attribute values. However, it will cause caller to report the die as coming from within the Exception::Class::Base class rather than where rethrow was called.

• message

  Returns the message associated with the exception. This is synonymous with the error method.

• error

  Returns the error message associated with the exception. This is synonymous with the message method.

• pid

  Returns the pid at the time the exception was thrown.

• uid

  Returns the real user id at the time the exception was thrown.

• gid

  Returns the real group id at the time the exception was thrown.

• euid

  Returns the effective user id at the time the exception was thrown.

• egid

  Returns the effective group id at the time the exception was thrown.

• time

  Returns the time in seconds since the epoch at the time the exception was thrown.

• package

  Returns the package from which the exception was thrown.

• file

  Returns the file within which the exception was thrown.

• line

  Returns the line where the exception was thrown.

• trace

  Returns the trace object associated with the object.

• as_string

  Returns a string form of the error message (something like what you'd expect from die). If the class or object is set to show traces then then it also includes this in string form (like Carp::confess).

• full_message

  Called by the as_string method to get the message. By default, this is the same as calling the message method, but may be overridden by a subclass. See below for details.

OVERLOADING

The Exception::Class::Base object is overloaded so that stringification produces a normal error message. It just calls the as_string method described above. This means that you can just print $@ after an eval and not worry about whether or not its an actual object. It also means an application or module could do this:

 $SIG{__DIE__} = sub { Exception::Class::Base->throw( error => join '', @_ ); };

and this would probably not break anything (unless someone was expecting a different type of exception object from die).

OVERRIDING THE as_string METHOD

By default, the as_string method simply returns the value message or error param plus a stack trace, if one exists.

However, once you add new fields to a subclass, you may want to include those fields in the stringified error.

Inside the as_string method, the message (non-stack trace) portion of the error is generated by calling the full_message method. This can be easily overridden. For example:

  sub full_message
  {
      my $self = shift;

      my $msg = $self->message;

      $msg .= " and foo was " . $self->foo;

      return $msg;
  }

USAGE RECOMMENDATION

If you're creating a complex system that throws lots of different types of exceptions consider putting all the exception declarations in one place. For an app called Foo you might make a Foo::Exceptions module and use that in all your code. This module could just contain the code to make Exception::Class do its automagic class creation. This allows you to more easily see what exceptions you have and makes it easier to keep track of them all (as opposed to looking at the top of 10-20 different files). It's also ever so slightly faster as the Class::Exception->import method doesn't get called over and over again (though a given class is only ever made once).

This might look something like this:

  package Foo::Bar::Exceptions;

  use Exception::Class ( Foo::Bar::Exception::Senses =>
                        { description => 'sense-related exception' },

                         Foo::Bar::Exception::Smell =>
                         { isa => 'Foo::Bar::Exception::Senses',
                           fields => 'odor',
                            description => 'stinky!' },

                         Foo::Bar::Exception::Taste =>
                         { isa => 'Foo::Bar::Exception::Senses',
                           fields => [ 'taste', 'bitterness' ],
                           description => 'like, gag me with a spoon!' },

                         ... );

You may want to create a real module to subclass Exception::Class::Base as well, particularly if you want your exceptions to have more methods. Read the "DECLARING EXCEPTION CLASSES" for more details.

OTHER EXCEPTION MODULES (try/catch syntax)

If you are interested in adding try/catch/finally syntactic sugar to your code then I recommend you check out Graham Barr's Error module, which implements this syntax. It also includes its own base exception class, Error::Simple.

If you would prefer to use the Exception::Class::Base included with this module, you'll have to add this to your code somewhere:

  push @Exception::Class::Base::ISA, 'Error';

It's a hack but apparently it works.

AUTHOR

Dave Rolsky, <autarch@urth.org>

SEE ALSO

Devel::StackTrace

cpanm Exception::Class

perl -MCPAN -e shell
install Exception::Class