NAME

Text::MicroMason::Devel - MicroMason Template Syntax And Tips

DESCRIPTION

This document describes the default template syntax and subroutine assembly used by Text::MicroMason.

This behavior can be supplemented or overridden by subclasses. (Of particular interest are the private lex(), assemble(), and eval_sub() methods.)

TEMPLATE SYNTAX

Text::MicroMason::Base supports the following subset of the HTML::Mason syntax:

• literal_text

  Anything not specifically parsed by one of the below rules is interpreted as literal text.

• <% perl_expr %>

  A Perl expression to be interpolated into the result.

  For example, the following template text will return a scheduled greeting:

      Good <% (localtime)[2]>11 ? 'afternoon' : 'morning' %>.

  The block may span multiple lines and is scoped inside a "do" block, so it may contain multiple Perl statements and it need not end with a semicolon.

      Good <% my $h = (localtime)[2]; $h > 11 ? 'afternoon' 
                                              : 'morning'  %>.

• % perl_code

  Lines which begin with the % character, without any leading whitespace, may contain arbitrary Perl code to be executed when encountering this portion of the template. Their result is not interpolated into the result.

  For example, the following template text will return a scheduled greeting:

      % my $daypart = (localtime)[2]>11 ? 'afternoon' : 'morning';
      Good <% $daypart %>.

  The line may contain one or more statements. This code is not placed in its own scope, although it is automatically terminated by a semicolon. However, it can still form a spanning block scope closed by a later perl block.

  For example, the following template text will return one of two different messages each time it's interpreted:

      % if ( int rand 2 ) {
        Hello World!
      % } else {
        Goodbye Cruel World!
      % }

  This also allows you to quickly comment out sections of a template by prefacing each line with % #.

• <%perl> perl_code </%perl>

  Blocks surrounded by %perl tags may contain arbitrary Perl code. Their result is not interpolated into the result.

  These blocks may span multiple lines in your template file. For example, the below template initializes a Perl variable inside a %perl block, and then interpolates the result into a message.

      <%perl> 
        my $count = join '', map "$_... ", ( 1 .. 9 ); 
      </%perl>
      Here are some numbers: <% $count %>

  The block may contain one or more statements. This code is not placed in its own scope, although it is automatically terminated by a semicolon. However, it can still form a spanning block scope closed by a later perl block.

  For example, when the below template text is evaluated it will return a sequence of digits:

      Here are some numbers: 
      <%perl> 
        foreach my $digit ( 1 .. 9 ) { 
      </%perl>
          <% $digit %>... 
      <%perl> 
        } 
      </%perl>

  If the block is immediately followed by a line break, that break is discarded. These blocks are not whitespace sensitive, so the template could be combined into a single line if desired.

• <%init> perl_code </%init>

  Similar to a %perl block, except that the code is moved up to the start of the subroutine. This allows a template's initialization code to be moved to the end of the file rather than requiring it to be at the top.

  For example, the following template text will return a scheduled greeting:

      Good <% $daypart %>.
      <%init> 
        my $daypart = (localtime)[2]>11 ? 'afternoon' : 'morning';
      </%init>

• <%cleanup> perl_code </%cleanup>

  Similar to a %perl block, except that the code is moved down to the end of the subroutine.

• <%once> perl_code </%once>

  Similar to a %perl block, except that the code is executed once, when the template is first compiled. (If a caller is using execute, this code will be run repeatedly, but if they call compile and then invoke the resulting subroutine multiple times, the %once code will only execute during the compilation step.)

  This code does not have access to %ARGS and can not generate output. It can be used to define constants, create persistent variables, or otherwise prepare the environment.

  For example, the following template text will return a increasing number each time it is called:

      <%once> 
        my $counter = 1000;
      </%once>
      The count is <% ++ $counter %>.

• <%args> variable => default </%args>

  Defines a collection of variables to be initialized from named arguments passed to the subroutine. Arguments are separated by one or more newlines, and may optionally be followed by a default value. If no default value is provided, the argument is required and the subroutine will croak if it is not provided.

  For example, adding the following block to a template will initialize the three named variables, and will fail if no a => '...' argument pair is passed:

    <%args>
      $a
      @b => qw( foo bar baz )
      %c => ()
    </%args>

  All the arguments are available as lexically scoped ("my") variables in the rest of the component. Default expressions are evaluated in top-to-bottom order, and one expression may reference an earlier one.

  Only valid Perl variable names may be used in <%args> sections. Parameters with non-valid variable names cannot be pre-declared and must be fetched manually out of the %ARGS hash.

• <& template_filename, arguments &>

  Includes the results of a separate file containing MicroMason code, compiling it and executing it with any arguments passed after the filename.

  For example, we could place the following template text into an separate file:

      Good <% $ARGS{hour} >11 ? 'afternoon' : 'morning' %>.

  Assuming this file was named "greeting.msn", its results could be embedded within the output of another script as follows:

    <& "greeting.msn", hour => (localtime)[2] &>

• <%doc> ... </%doc>

  Provides space for template developer documentation or comments which are not included in the output.

TEMPLATE DEVELOPER NOTES

Assembling Perl Source Code

When Text::MicroMason::Base assembles your lexed template into the equivalent Perl subroutine, all of the literal (non-Perl) pieces are converted to $_out->('text'); statements, and the interpolated expressions are converted to $_out->( do { expr } ); statements. Code from %perl blocks and % lines are included exactly as-is.

Your code is eval'd in the Text::MicroMason::Commands package. The use strict; pragma is enabled by default to simplify debugging.

Internal Sub-templates

You can create sub-templates within your template text by defining them as anonymous subroutines and then calling them repeatedly. For example, the following template will concatenate the results of the draw_item sub-template for each of three items:

    <h1>We've Got Items!</h1>
    
    % my $draw_item = sub {
      <p><b><% $_[0] %></b>:<br>
        <a href="/more?item=<% $_[0] %>">See more about <% $_[0] %>.</p>
    % };
    
    <%perl>
      foreach my $item ( qw( Foo Bar Baz ) ) {
        $draw_item->( $item );
      }
    </%perl>

Returning Text from Perl Blocks

To append to the result from within Perl code, call $_out->(text). (The $_out->() syntax is unavailable in older versions of Perl; use the equivalent &$_out() syntax instead.)

For example, the below template text will return '123456789' when it is evaluated:

    <%perl>
      foreach my $digit ( 1 .. 9 ) {
        $_out->( $digit )
      }
    </%perl>

You can also directly manipulate the value $OUT, which contains the accumulating result.

For example, the below template text will return an altered version of its message if a true value for 'minor' is passed as an argument when the template is executed:

    This is a funny joke.
    % $OUT =~ tr[a-z][n-za-m] if $ARGS{minor};

SEE ALSO

For the core functionality of this package see Text::MicroMason and Text::MicroMason::Base.

For distribution, installation, support, copyright and license information, see Text::MicroMason::ReadMe.