The Perl Toolchain Summit needs more sponsors. If your company depends on Perl, please support this very important event.
 / 
App-Rad-0.6
River stage two • 16 direct dependents • 26 total dependents
8 ++
/ App::Rad

NAME

App::Rad - Rapid (and easy!) creation of command line applications

VERSION

Version 0.6

SYNOPSIS

This is your smallest working application (let's call it myapp.pl)

    use App::Rad;
    App::Rad->run();

That's it, your program already works and you can use it directly via the command line (try it!)

    [user@host]$ ./myapp.pl
    Usage: myapp.pl command [arguments]
    
    Available Commands:
        help

Next, start creating your own functions (e.g.) inside myapp.pl:

    sub hello {
        return "Hello, World!";
    }

And now your simple command line program myapp.pl has a 'hello' command!

   [user@host]$ myapp.pl hello
   Hello, World!

Of course, you probably want to create a more meaningful command, with arguments and options:

    # dice roller: 2d6, 1d10, etc...
    sub roll {
        my $c = shift;
        my $value = 0;

        if ( $c->argv->[0] =~ m/(\d+)d(\d+)/ ) {
            for (1..$1) {
                $value += int(rand ($2) + 1);
            }
        }
        return $value;
    }

There it is, a brand new 'roll' command! You can try on the command line:

   [user@host]$ myapp.pl roll 3d4
   5

WARNING

This module is very young, likely to change in strange ways and to have some bugs (please report if you find any!). I will try to keep the API stable, but even that is subject to change (let me know if you find anything annoying or have a wishlist). You have been warned!

WARNING II (MODULE NAME)

I'm still trying to figure out a nice name for this module, so it might change. Feel free to offer me any naming suggestions you might have :)

DESCRIPTION

App::Rad aims to be a simple yet powerful framework for developing your command-line applications. It can easily transform your Perl one-liners into reusable subroutines than can be called directly by the user of your program.

It also tries to provide a handy interface for your common command-line tasks. If you have a feature request to easen out your tasks even more, please drop me an email or a RT feature request.

BUILT-IN COMMANDS

This module comes with the following default commands. You are free to override them as you see fit.

help

Shows help information for your program. This built-in function displays the program name and all available commands (including the ones you included). If a user of our minimal myapp.pl example typed the 'help' command, or no command at all, or any command that does not exist (as they'd fall into the 'default' control function which (by default) calls 'help'), this would be the output:

    [user@host]$ myapp.pl help
    Usage: myapp.pl command [arguments]
    
    Available Commands:
        hello
        help
        roll

OTHER BUILT IN COMMANDS (OPT-IN)

The 'include' and 'exclude' commands below let the user include and exclude commands to your program and, as this might be dangerous when the user is not yourself, you have to opt-in on them:

   use App::Rad qw(include);  # add the 'include' command
   use App::Rad qw(exclude);  # add the 'exclude' command

though you'll probably want to set them both:

   use App::Rad qw(include exclude);

include [command_name] -perl_params 'your subroutine code'

Includes the given subroutine into your program on-the-fly, just as you would writing it directly into your program.

Let's say you have your simple 'myapp.pl' program that uses App::Rad sitting on your system quietly. One day, perhaps during your sysadmin's tasks, you create a really amazing one-liner to solve a really hairy problem, and want to keep it for posterity (reusability is always a good thing!).

For instance, to change a CSV file in place, adding a column on position #2 containing the line number, you might do something like this (this is merely illustrative, it's not actually the best way to do it):

    $ perl -i -paF, -le 'splice @F,1,0,$.; $_=join ",",@F' somesheet.csv

And you just found out that you might use this other times. What do you do? App::Rad to the rescue!

In the one-liner above, just switch 'perl' to 'myapp.pl include SUBNAME' and remove the trailing parameters (somesheet.csv):

    $ myapp.pl include addcsvcol -i -paF, -le 'splice @F,1,0,$.; $_=join ",",@F'

That's it! Now myapp.pl has the 'addcsvcol' command (granted, not the best name) and you can call it directly whenever you want:

    $ myapp.pl addcsvcol somesheet.csv

App::Rad not only transforms and adjusts your one-liner so it can be used inside your program, but also automatically formats it with Perl::Tidy (if you have it). This is what the one-liner above would look like inside your program:

    sub addcsvcol {
        my $c = shift;
    
        # its probably safe to remove the line below
        local (@ARGV) = @{ $c->argv };
    
        local ($^I) = "";
        local ($/)  = "\n";
        local ($\)  = "\n";
      LINE: while ( defined( $_ = <ARGV> ) ) {
            chomp $_;
            our (@F) = split( /,/, $_, 0 );
            splice @F, 1, 0, $.;
            $_ = join( ',', @F );
        }
        continue {
            die "-p destination: $!\n" unless print $_;
        }
    }

With so many arguments (-i, -p, -a -F,, -l -e), this is about as bad as it gets. And still one might find this way easier to document and mantain than a crude one-liner stored in your ~/.bash_history or similar.

Note: If you don't supply a name for your command, App::Rad will make one up for you (cmd1, cmd2, ...). But don't do that, as you'll have a hard time figuring out what that specific command does.

Another Note: App::Rad tries to adjust the command to its interface, but please keep in mind this module is still in its early stages so it's not guaranteed to work every time. *PLEASE* let me know via email or RT bug request if your one-liner was not correctly translated into an App::Rad command. Thanks!

exclude command_name

Removes the requested function from your program. Note that this will delete the actual code from your program, so be *extra* careful. It is strongly recommended that you do not use this command and either remove the subroutine yourself or add the function to your excluded list inside setup().

Note that built-in commands such as 'help' cannot be removed via exclude. They have to be added to your excluded list inside setup().

ROLLING YOUR OWN COMMANDS

Creating a new command is as easy as writing any sub inside your program. Some names ("setup", "default", "invalid", "pre_process", "post_process" and "teardown") are reserved for special purposes (see the Control Functions section of this document). App::Rad provides a nice interface for reading command line input and writing formatted output:

The Controller

Every command (sub) you create receives the controller object "$c" (sometimes referred as "$self" in other projects) as an argument. The controller is the main interface to App::Rad and has several methods to easen your command manipulation and execution tasks.

Reading arguments

$c->argv

When someone types in a command, she may pass some arguments to it. Those arguments are stored in raw format inside the array reference $c->argv. This way it's up to you to control how many arguments (if at all) you want to receive and/or use.

So, in order to manipulate and use any arguments, remember:

    sub my_command {
        my $c = shift;
    
        # now everything the user typed after the name of
        # your command is inside @{$c->argv} so you can
        # use $c->argv->[0], $c->argv->[1], and so on, to
        # get and even reset any parameters.
    }

$c->options

App::Rad lets you automatically retrieve any POSIX syntax command line options (getopt-style) passed to your command via the $c->options method. This method returns a hash reference with keys as given parameters and values as, well, values. The 'options' method automatically supports two simple argument structures:

Extended (long) option. Translates --parameter or --parameter=value into $c->options->{parameter}

Single-letter option. Translates -p into $c->options->{p}.

Single-letter options can be nested together, so -abc will be parsed into $c->options->{a}, $c->options->{b} and $c->options{c}, while --abc will be parsed into $c->options->{abc}. So our example dice-rolling command can be written this way:

    sub roll {
        my $c = shift;

        my $value = 0;
        for ( 1..$c->options->{'times'} ) {
            $value += ( int(rand ($c->options->{'faces'}) + 1));
        }
        return $value;
    }

And now you can call your 'roll' command like:

    $ myapp.pl roll --faces=6 --times=2

Note that the App::Rad does not control which arguments can or cannot be passed: they are all parsed into $c->options and it's up to you to use whichever you want. For a more advanced use and control, see the $c->getopt method below.

$c->getopt (Advanced Getopt usage)

App::Rad is also smoothly integrated with Getopt::Long, so you can have even more flexibility and power while parsing your command's arguments, such as aliases and types. Call the $c->getopt() method anytime inside your commands (or just once in your "pre_process" function to always have the same interface) passing a simple array with your options, and refer back to $c->options to see them. For instance:

    sub roll {
        my $c = shift;

        $c->getopt( 'faces|f=i', 'times|t=i' )
            or $c->execute('usage') and return undef;

        # and now you have C<< $c->options->{'faces'} >> 
        # and C<< $c->options->{'times'} >> just like above.
    }

This becomes very handy for complex or feature-rich commands. Please refer to the Getopt::Long module for more usage examples.

Sharing Data: $c->stash

The "stash" is a universal hash for storing data among your Commands:

    $c->stash->{foo} = 'bar';
    $c->stash->{herculoids} = [ qw(igoo tundro zok gloop gleep) ];
    $c->stash->{application} = { name => 'My Application' };

You can use it for more granularity and control over your program. For instance, you can email the output of a command if (and only if) something happened:

    sub command {
        my $c = shift;
        my $ret = do_something();

        if ( $ret =~ /critical error/ ) {
            $c->stash->{mail} = 1;
        }
        return $ret;
    }

    sub post_process {
        my $c = shift;

        if ( $c->stash->{mail} ) {
            # send email alert...
        }
        else {
            print $c->output . "\n";
        }
    }

Returning output

Once you're through, return whatever you want to give as output for your command:

    my $ret = "Here's the list: ";
    $ret .= join ', ', 1..5;
    return $ret;
    
    # this prints "Here's the list: 1, 2, 3, 4, 5"

App::Rad lets you post-process the returned value of every command, so refrain from printing to STDOUT directly whenever possible as it will give much more power to your programs. See the post_process() control function further below in this document.

HELPER METHODS

App::Rad's controller comes with several methods to help you manage your application easily. If you can think of any other useful command that is not here, please drop me a line or RT request.

$c->execute( COMMAND_NAME )

Runs the given command. If no command is given, runs the one stored in $c->cmd. If the command does not exist, the 'default' command is ran instead. Each execute() call also invokes pre_process and post_process, so you can easily manipulate income and outcome of every command.

$c->cmd

Returns a string containing the name of the command (that is, the first argument of your program), that will be called right after pre_process.

$c->command

Alias for $c->cmd.

$c->commands()

Returns a list of available commands (functions) inside your program

$c->is_command ( COMMAND_NAME )

Returns 1 (true) if the given COMMAND_NAME is available, 0 (false) otherwise.

$c->create_command_name()

Returns a valid name for a command (i.e. a name slot that's not been used by your program). This goes in the form of 'cmd1', 'cmd2', etc., so don't use unless you absolutely have to. App::Rad, for instance, uses this whenever you try to include (see below) a new command but do not supply a name for it.

$c->load_config( FILE (FILE2, FILE3, ...) )

NOTE: This will most likely become a separate App::Rad::Extensions::Config (or something like that)

This method lets you easily load into your program one or more configuration files written like this:

    # comments and blank lines are discarded
    key1 value1
    key2:value2
    key3=value3
    key5           # stand-alone attribute (and inline-comment)

$c->config

NOTE: This will most likely become a separate App::Rad::Extensions::Config (or something like that)

Returns a hash reference with any loaded config values (see $c->load_config() above).

$c->register_command ( NAME, CODEREF )

Registers a coderef as a callable command. Note that you don't have to call this in order to register a sub inside your program as a command, run() will already do this for you - and if you don't want some subroutines to be issued as commands you can always use $c->register_commands() (note the plural) inside setup(). This is just an interface to dinamically include commands in your programs. The function returns the command name in case of success, undef otherwise.

It is also very useful for creating aliases for your commands:

    sub setup {
        my $c = shift;
        $c->register_commands();

        $c->register('myalias', \&command);
    }

    sub command { return "Hi!" }

and, on the command line:

    [user@host]$ ./myapp.pl command
    Hi!

    [user@host]@ ./myapp.pl myalias
    Hi!

$c->register ( NAME, CODEREF )

Shorter alias for $c->register_command()

$c->register_commands ()

This method, usually called during setup(), tells App::Rad to register all subroutines available in the main program as valid commands. It may optionally receive a hashref as an argument, letting you choose which subroutines to add as commands. The following keys may be used:

  • ignore_prefix: subroutine names starting with the given string won't be added as commands

  • ignore_suffix: subroutine names ending with the given string won't be added as commands

  • ignore_regexp: subroutine names matching the given regular expression (as a string) won't be added as commands

For example:

    use App::Rad;
    App::Rad->run();

    sub setup { 
        my $c = shift; 
        $c->register_commands( { ignore_prefix => '_' } );
    }

    sub foo  {}  # will become a command
    sub bar  {}  # will become a command
    sub _baz {}  # will *NOT* become a command

This way you can easily segregate between commands and helper functions, making your code even more reusable without jeopardizing the command line interface.

$c->unregister_command ( NAME )

Unregisters a given command name so it's not available anymore. Note that the subroutine will still be there to be called from inside your program - it just won't be accessible via command line anymore.

$c->unregister ( NAME )

Shorter alias for $c->unregister_command().

$c->debug( MESSAGE )

Will print the given message on screen only if the debug flag is enabled:

    use App::Rad  qw( debug );

run()

this is the main execution command for the application. That's the *ONLY* thing your script needs to actively do. Leave all the rest to your subs.

CONTROL FUNCTIONS (to possibly override)

App::Rad implements some control functions which are expected to be overridden by implementing them in your program. They are as follows:

setup()

This function is responsible for setting up what your program can and cannot do, plus everything you need to set before actually running any command (connecting to a database or host, check and validate things, download a document, whatever). Note that, if you override setup(), you *must* call $c->register_commands() or at least $c->register_command() so your subs are classified as valid commands (check $c->register_commands() above for more information).

Another interesting thing you can do with setup is to manipulate the command list. For instance, you may want to be able to use the include and exclude commands, but not let them available for all users. So instead of writing:

    use App::Rad qw(include exclude);
    App::Rad->run();

you can write something like this:

    use App::Rad;
    App::Rad->run();

    sub setup {
        my $c = shift;
        $c->register_commands();

        # EUID is 'root'
        if ( $> == 0 ) {
            $c->register_command('include', \&App::Rad::include);
            $c->register_command('exclude', \&App::Rad::exclude);
        }
    }

to get something like this:

    [user@host]$ myapp.pl help
    Usage: myapp.pl command [arguments]

    Available Commands:
       help

    [user@host]$ sudo myapp.pl help
    Usage: myapp.pl command [arguments]

    Available Commands:
       exclude
       help
       include

default()

If no command is given to your application, it will fall in here. Please note that invalid (non-existant) command will fall here too, but you can change this behavior with the invalid() function below (although usually you don't want to).

Default's default (grin) is just an alias for the help command.

    sub default {
        my $c = shift;

        # will fall here if the given
        # command isn't valid.
    }

You are free (and encouraged) to change the default behavior to whatever you want. This is rather useful for when your program will only do one thing, and as such it receives only parameters instead of command names. In those cases, use the "default()" sub as your main program's sub and parse the parameters with $c->argv and $c->getopt as you would in any other command.

invalid()

This is a special function to provide even more flexibility while creating your command line applications. This is called when the user requests a command that does not exist. The built-in invalid() will simply redirect itself to default() (see above), so usually you just have to worry about this when you want to differentiate between "no command given" (with or without getopt-like arguments) and "invalid command given" (with or without getopt-like arguments).

teardown()

If implemented, this function is called automatically after your application runs. It can be used to clean up after your operations, removing temporary files, disconnecting a database connection established in the setup function, logging, sending data over a network, or even storing state information via Storable or whatever.

pre_process()

If implemented, this function is called automatically right before the actual wanted command is called. This way you have an optional pre-run hook, which permits functionality to be added, such as preventing some commands to be run from a specific uid (e.g. root):

    sub pre_process {
        my $c = shift;

        if ( $c->cmd eq 'some_command' and $> != 0 ) {
            $c->cmd = 'default'; # or some standard error message
        }
    }

post_process()

If implemented, this function is called automatically right after the requested function returned. It receives the Controller object right after a given command has been executed (and hopefully with some output returned), so you can manipulate it at will. In fact, the default "post_process" function is as goes:

    sub post_process {
        my $c = shift;

        if ( $c->output() ) {
            print $c->output() . "\n";
        }
    }

You can override this function to include a default header/footer for your programs (either a label or perhaps a "Content-type: " string), parse the output in any ways you see fit (CPAN is your friend, as usual), etc.

IMPORTANT NOTE ON PRINTING INSIDE YOUR COMMANDS

The post_process() function above is why your application should *NEVER* print to STDOUT. Using print (or say, in 5.10) to send output to STDOUT is exclusively the domain of the post_process() function. Breaking this rule is a common source of errors. If you want your functions to be interactive (for instance) and print everything themselves, you should disable post-processing in setup(), or create an empty post_process function or make your functions return undef (so post_process() will only add a blank line to the output).

DIAGNOSTICS

If you see a '1' printed on the screen after a command is issued, it's probably because that command is returning a "true" value instead of an output string. If you don't want to return the command output for post processing(you'll loose some nice features, though) you can return undef or make post_process() empty.

CONFIGURATION AND ENVIRONMENT

App::Rad requires no configuration files or environment variables.

DEPENDENCIES

App::Rad depends only on 5.8 core modules (Carp for errors, Getopt::Long for "$c->getopt" and O/B::Deparse for the "include" command).

If you have Perl::Tidy installed, the "include" command will tidy up your code before inclusion.

The test suite depends on Test::More and File::Temp, both also core modules.

INCOMPATIBILITIES

None reported.

BUGS AND LIMITATIONS

Please report any bugs or feature requests to bug-app-easy at rt.cpan.org, or through the web interface at http://rt.cpan.org/garu/ReportBug.html?Queue=App-Rad. I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.

SUPPORT

You can find documentation for this module with the perldoc command.

    perldoc App::Rad

You can also look for information at:

TODO

This is a small list of features I plan to add in the near future (in no particular order). Feel free to contribute with your wishlist and comentaries!

  • Shell-like environment

  • Extension possibilities (plugins!)

  • Loadable commands (in an external container file)

  • Modularized commands (similar to App::Cmd::Commands ?)

  • Output Templating

  • Embedded help

  • app-starter

  • command inclusion by prefix, suffix and regexp (feature request by fco)

  • command inclusion and exclusion also by attributes

  • some extra integration, maybe IPC::Cmd and IO::Prompt

AUTHOR

Breno G. de Oliveira, <garu at cpan.org>

ACKNOWLEDGEMENTS

This module was inspired by Kenichi Ishigaki's presentation "Web is not the only one that requires frameworks" during YAPC::Asia::2008 and the modules it exposed (mainly App::Cmd and App::CLI).

Also, many thanks to CGI::App(now Titanium)'s Mark Stosberg and all the Catalyst developers, as some of App::Rad's functionality was taken from those (web) frameworks.

LICENSE AND COPYRIGHT

Copyright 2008 Breno G. de Oliveira <garu at cpan.org>. All rights reserved.

This module is free software; you can redistribute it and/or modify it under the same terms as Perl itself. See perlartistic.

DISCLAIMER OF WARRANTY

BECAUSE THIS SOFTWARE IS LICENSED FREE OF CHARGE, THERE IS NO WARRANTY FOR THE SOFTWARE, TO THE EXTENT PERMITTED BY APPLICABLE LAW. EXCEPT WHEN OTHERWISE STATED IN WRITING THE COPYRIGHT HOLDERS AND/OR OTHER PARTIES PROVIDE THE SOFTWARE "AS IS" WITHOUT WARRANTY OF ANY KIND, EITHER EXPRESSED OR IMPLIED, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE. THE ENTIRE RISK AS TO THE QUALITY AND PERFORMANCE OF THE SOFTWARE IS WITH YOU. SHOULD THE SOFTWARE PROVE DEFECTIVE, YOU ASSUME THE COST OF ALL NECESSARY SERVICING, REPAIR, OR CORRECTION.

IN NO EVENT UNLESS REQUIRED BY APPLICABLE LAW OR AGREED TO IN WRITING WILL ANY COPYRIGHT HOLDER, OR ANY OTHER PARTY WHO MAY MODIFY AND/OR REDISTRIBUTE THE SOFTWARE AS PERMITTED BY THE ABOVE LICENCE, BE LIABLE TO YOU FOR DAMAGES, INCLUDING ANY GENERAL, SPECIAL, INCIDENTAL, OR CONSEQUENTIAL DAMAGES ARISING OUT OF THE USE OR INABILITY TO USE THE SOFTWARE (INCLUDING BUT NOT LIMITED TO LOSS OF DATA OR DATA BEING RENDERED INACCURATE OR LOSSES SUSTAINED BY YOU OR THIRD PARTIES OR A FAILURE OF THE SOFTWARE TO OPERATE WITH ANY OTHER SOFTWARE), EVEN IF SUCH HOLDER OR OTHER PARTY HAS BEEN ADVISED OF THE POSSIBILITY OF SUCH DAMAGES.