NAME

AnyEvent::Redis::RipeRedis - Flexible non-blocking Redis client with reconnect feature

SYNOPSIS

  use AnyEvent;
  use AnyEvent::Redis::RipeRedis qw( :err_codes );

  my $cv = AE::cv();

  my $redis = AnyEvent::Redis::RipeRedis->new(
    host => 'localhost',
    port => '6379',
    password => 'yourpass',
    encoding => 'utf8',
    on_error => sub {
      my $err_msg = shift;
      my $err_code = shift;

      # handle the error
    },
  );

  # Set value
  $redis->set( 'foo', 'string', {
    on_done => sub {
      print "SET is done\n";
      $cv->send();
    },
    on_error => sub {
      my $err_msg = shift;
      my $err_code = shift;

      # handle the error
    }
  } );

  $cv->recv();

  $redis->disconnect();

DESCRIPTION

AnyEvent::Redis::RipeRedis is the flexible non-blocking Redis client with reconnect feature. The client supports subscriptions, transactions and connection via UNIX-socket.

Requires Redis 1.2 or higher, and any supported event loop.

CONSTRUCTOR

new()

  my $redis = AnyEvent::Redis::RipeRedis->new(
    host => 'localhost',
    port => '6379',
    password => 'yourpass',
    database => 7,
    lazy => 1,
    connection_timeout => 5,
    read_timeout => 5,
    reconnect => 1,
    encoding => 'utf8',
    on_connect => sub {
      print "Connected to Redis server\n";
    },
    on_disconnect => sub {
      print "Disconnected from Redis server\n";
    },
    on_connect_error => sub {
      my $err_msg = shift;

      # handle the error
    },
    on_error => sub {
      my $err_msg = shift;
      my $err_code = shift;

      # handle the error
    },
  );

host

Server hostname (default: 127.0.0.1)

port

Server port (default: 6379)

password

If the password is specified, then the AUTH command is sent immediately to the server after every connection.

database

Database index. If the index is specified, then the client is switched to the specified database immediately after every connection.

The default database index is 0.

connection_timeout

If this parameter specified and connection to the Redis server is fails after specified timeout, then the on_error or on_connect_error callback is called. In case, when on_error callback is called, E_CANT_CONN error code is passed to callback in the second argument. The timeout must be specified in seconds and can contain a fractional part.

  my $redis = AnyEvent::Redis::RipeRedis->new(
    connection_timeout => 10.5,
  );

By default the client use kernel's connection timeout.

read_timeout

If this parameter specified and the client could not receive a response from the Redis server after specified timeout on any command, then the client close connection to the server and call on_error callback with the E_READ_TIMEDOUT error code. The timeout must be specified in seconds and can contain a fractional part.

  my $redis = AnyEvent::Redis::RipeRedis->new(
    read_timeout => 3.5,
  );

Not set by default.

lazy

If this parameter is set, then the connection establishes, when you will send the first command to the server. By default the connection establishes after calling of the method new.

reconnect

If the connection to the Redis server was lost and the parameter 'reconnect' is TRUE, then the client try to restore the connection on a next executuion of the command. The client try to reconnect only once and if it fails, then is called the on_error callback. If you need several attempts of the reconnection, just retry a command from the on_error callback as many times, as you need. This feature made the client more responsive.

By default is TRUE.

encoding

Used for encode/decode strings at time of input/output operations.

Not set by default.

on_connect => $cb->()

The on_connect callback is called, when the connection is successfully established.

Not set by default.

on_disconnect => $cb->()

The on_disconnect callback is called, when the connection is closed by any reason.

Not set by default.

on_connect_error => $cb->( $err_msg )

The on_connect_error callback is called, when the connection could not be established. If this collback isn't specified, then the on_error callback is called with the E_CANT_CONN error code.

Not set by default.

on_error => $cb->( $err_msg, $err_code )

The on_error callback is called, when any error occurred. If the callback is not set, the client just print an error message to STDERR.

COMMAND EXECUTION

<command>( [ @args[, \%callbacks ] ] )

The full list of the Redis commands can be found here: http://redis.io/commands.

  # Set value
  $redis->set( 'foo', 'string' );

  # Increment
  $redis->incr( 'bar', {
    on_done => sub {
      my $data = shift;
      print "$data\n";
    },
  } );

  # Get list of values
  $redis->lrange( 'list', 0, -1, {
    on_done => sub {
      my $data = shift;
      foreach my $val ( @{$data}  ) {
        print "$val\n";
      }
    },
    on_error => sub {
      my $err_msg = shift;
      my $err_code = shift;

      # handle the error
    },
  } );

on_done => $cb->( [ $data ] ): The on_done callback is called, when the current operation is done.
on_error => $cb->( $err_msg, $err_code ): The on_error callback is called, if any error occurred. If the on_error callback is not specified here, then the on_error callback specified in constructor is called.

TRANSACTIONS

The detailed information abount the Redis transactions can be found here: http://redis.io/topics/transactions.

multi( [ \%callbacks ] )

Marks the start of a transaction block. Subsequent commands will be queued for atomic execution using EXEC.

exec( [ \%callbacks ] )

Executes all previously queued commands in a transaction and restores the connection state to normal. When using WATCH, EXEC will execute commands only if the watched keys were not modified.

If after EXEC command at least one operation fails, then on_error callback is called with E_OPRN_ERROR error code and with reply data. Reply data is passed in third argument of on_error callback and will contain errors of failed operations and replies of successful operations. Errors will be represented as objects of the class AnyEvent::Redis::RipeRedis::Error. Each error object has two methods: message() to get error message and code() to get error code.

  $redis->multi();
  $redis->set( 'foo', 'string' );
  $redis->incr( 'foo' ); # causes an error
  $redis->exec( {
    on_error => sub {
      my $err_msg = shift;
      my $err_code = shift;
      my $data = shift;

      warn "$err_msg\n";
      foreach my $reply ( @{$data}  ) {
        if ( ref( $reply ) eq 'AnyEvent::Redis::RipeRedis::Error' ) {
          my $oprn_err_msg = $reply->message();
          my $oprn_err_code = $reply->code();

          # handle the error
        }
      }

      $cv->send();
    },
  } );

discard( [ \%callbacks ] )

Flushes all previously queued commands in a transaction and restores the connection state to normal.

If WATCH was used, DISCARD unwatches all keys.

watch( @keys[, \%callbacks ] )

Marks the given keys to be watched for conditional execution of a transaction.

unwatch( [ \%callbacks ] )

Forget about all watched keys.

SUBSCRIPTIONS

The detailed information about Redis Pub/Sub can be found here: http://redis.io/topics/pubsub

Subscribes the client to the specified channels.

Once the client enters the subscribed state it is not supposed to issue any other commands, except for additional SUBSCRIBE, PSUBSCRIBE, UNSUBSCRIBE and PUNSUBSCRIBE commands.

  $redis->subscribe( qw( ch_foo ch_bar ), {
    on_done =>  sub {
      my $ch_name = shift;
      my $subs_num = shift;
      print "Subscribed: $ch_name. Active: $subs_num\n";
    },
    on_message => sub {
      my $ch_name = shift;
      my $msg = shift;
      print "$ch_name: $msg\n";
    },
    on_error => sub {
      my $err_msg = shift;
      my $err_code = shift;

      # handle the error
    },
  } );

on_done => $cb->( $ch_name, $sub_num ): The on_done callback is called on every specified channel, when the current subscription operation is done.
on_message => $cb->( $ch_name, $msg ): The on_message callback is called, when a published message is received.
on_error => $cb->( $err_msg, $err_code ): The on_error callback is called, if the subscription operation fails. If the on_error callback is not specified here, then the on_error callback specified in constructor is called.

psubscribe( @patterns[, \%callbacks ] )

Subscribes the client to the given patterns.

  $redis->psubscribe( qw( info_* err_* ), {
    on_done =>  sub {
      my $ch_pattern = shift;
      my $subs_num = shift;
      print "Subscribed: $ch_pattern. Active: $subs_num\n";
    },
    on_message => sub {
      my $ch_name = shift;
      my $msg = shift;
      my $ch_pattern = shift;
      print "$ch_name ($ch_pattern): $msg\n";
    },
    on_error => sub {
      my $err_msg = shift;
      my $err_code = shift;

      # handle the error
    },
  } );

on_done => $cb->( $ch_pattern, $sub_num ): The on_done callback is called on every specified pattern, when the current subscription operation is done.
on_message => $cb->( $ch_name, $msg, $ch_pattern ): The on_message callback is called, when published message is received.
on_error => $cb->( $err_msg, $err_code ): The on_error callback is called, if the subscription operation fails. If the on_error callback is not specified here, then the on_error callback specified in constructor is called.

publish( $channel, $message[, \%callbacks ] )

Posts a message to the given channel.

unsubscribe( [ @channels ][, \%callbacks ] )

Unsubscribes the client from the given channels, or from all of them if none is given.

When no channels are specified, the client is unsubscribed from all the previously subscribed channels. In this case, a message for every unsubscribed channel will be sent to the client.

on_done => $cb->( $ch_name, $sub_num ): The on_done callback is called on every specified channel, when the current unsubscription operation is done.
on_error => $cb->( $err_msg, $err_code ): The on_error callback is called, if the unsubscription operation fails. If the on_error callback is not specified here, then the on_error callback specified in constructor is called.

punsubscribe( [ @patterns ][, \%callbacks ] )

Unsubscribes the client from the given patterns, or from all of them if none is given.

When no patters are specified, the client is unsubscribed from all the previously subscribed patterns. In this case, a message for every unsubscribed pattern will be sent to the client.

on_done => $cb->( $ch_name, $sub_num ): The on_done callback is called on every specified pattern, when the current unsubscription operation is done.
on_error => $cb->( $err_msg, $err_code ): The on_error callback is called, if the unsubscription operation fails. If the on_error callback is not specified here, then the on_error callback specified in constructor is called.

CONNECTION VIA UNIX-SOCKET

Redis 2.2 and higher support connection via UNIX domain socket. To connect via a UNIX-socket in the parameter host you have to specify unix/, and in the parameter port you have to specify the path to the socket.

  my $redis = AnyEvent::Redis::RipeRedis->new(
    host => 'unix/',
    port => '/tmp/redis.sock',
  );

LUA SCRIPTS EXECUTION

Redis 2.6 and higher support execution of Lua scripts on the server side. To execute a Lua script you can use one of the commands EVAL or EVALSHA, or you can use the special method eval_cached().

If Lua script returns multi-bulk reply with at least one error reply, then on_error callback is called with E_OPRN_ERROR error code and with reply data. Reply data is passed in third argument of on_error callback and will contain returned errors and other data. Errors will be represented as objects of the class AnyEvent::Redis::RipeRedis::Error. Each error object has two methods: message() to get error message and code() to get error code.

  $redis->eval( "return { 'foo', redis.error_reply( 'Error.' ) }", 0, {
    on_error => sub {
      my $err_msg = shift;
      my $err_code = shift;
      my $data = shift;

      warn "$err_msg\n";
      foreach my $reply ( @{$data}  ) {
        if ( ref( $reply ) eq 'AnyEvent::Redis::RipeRedis::Error' ) {
          my $oprn_err_msg = $reply->message();
          my $oprn_err_code = $reply->code();

          # handle the error
        }
      }
      $cv->send();
    }
  } );

eval_cached( $script, $numkeys[, [ @keys, ][ @args, ]\%callbacks ] );

When you call the eval_cached() method, the client first generate a SHA1 hash for a Lua script and cache it in memory. Then the client optimistically send the EVALSHA command under the hood. If the NO_SCRIPT error will be returned, the client send the EVAL command.

If you call the eval_cached() method with the same Lua script, client don not generate a SHA1 hash for this script repeatedly, it gets a hash from the cache instead.

  $redis->eval_cached( 'return { KEYS[1], KEYS[2], ARGV[1], ARGV[2] }',
      2, 'key1', 'key2', 'first', 'second', {
    on_done => sub {
      my $data = shift;
      foreach my $val ( @{$data}  ) {
        print "$val\n";
      }
    }
  } );

Be care, passing a different Lua scripts to eval_cached() method every time cause memory leaks.

ERROR CODES

Every time when the calback on_error is called, the current error code is passed to it in the second argument. Error codes can be used for programmatic handling of errors.

AnyEvent::Redis::RipeRedis provides constants of error codes, which can be imported and used in expressions.

  use AnyEvent::Redis::RipeRedis qw( :err_codes );

Error codes and constants corresponding to them:

  1  - E_CANT_CONN
  2  - E_LOADING_DATASET
  3  - E_IO
  4  - E_CONN_CLOSED_BY_REMOTE_HOST
  5  - E_CONN_CLOSED_BY_CLIENT
  6  - E_NO_CONN
  9  - E_OPRN_ERROR
  10 - E_UNEXPECTED_DATA
  11 - E_NO_SCRIPT
  12 - E_READ_TIMEDOUT

E_CANT_CONN: Can not connect to the server. All operations were aborted.
E_LOADING_DATASET: Redis is loading the dataset in memory.
E_IO: Input/Output operation error. The connection to the Redis server was closed and all operations were aborted.
E_CONN_CLOSED_BY_REMOTE_HOST: The connection closed by remote host. All operations were aborted.
E_CONN_CLOSED_BY_CLIENT: Uncompleted operations were aborted at time of calling disconnect() method or after executing QUIT command.
E_NO_CONN: No connection to the Redis server. Connection was lost by any reason on previous operation.
E_OPRN_ERROR: Operation error. For example, wrong number of arguments for a command.
E_UNEXPECTED_DATA: The client received unexpected data from the server. The connection to the Redis server was closed and all operations were aborted.
E_NO_SCRIPT: No matching script. Use the EVAL command.
E_READ_TIMEDOUT: Read timed out. The connection to the Redis server was closed and all operations were aborted.

DISCONNECTION

When the connection to the server is no longer needed you can close it in three ways: call the method disconnect(), send the QUIT command or you can just "forget" any references to an AnyEvent::Redis::RipeRedis object, but in this case a client object is destroyed without calling any callbacks including the on_disconnect callback to avoid an unexpected behavior.

disconnect()

The method for synchronous disconnection.

  $redis->disconnect();

OTHER METHODS

connection_timeout( $seconds )

Get, set or reset to default the connection_timeout of the client.

read_timeout( $seconds )

Get, set or disable the read_timeout of the client.

reconnect( $boolean )

Enable or disable reconnection mode of the client.

encoding( $enc_name )

Get, set or disable the encoding.

on_connect( $callback )

Get, set or disable the on_connect callback.

on_disconnect( $callback )

Get, set or disable the on_disconnect callback.

on_connect_error( $callback )

Get, set or disable the on_connect_error callback.

on_error( $callback )

Get, set or disable the on_error callback.

AUTHOR

Eugene Ponizovsky, <ponizovsky@gmail.com>

Special thanks

Alexey Shrub
Vadim Vlasov
Konstantin Uvarin

COPYRIGHT AND LICENSE

This module is free software; you can redistribute it and/or modify it under the same terms as Perl itself.

To install AnyEvent::Redis::RipeRedis, copy and paste the appropriate command in to your terminal.

cpanm

cpanm AnyEvent::Redis::RipeRedis

CPAN shell

perl -MCPAN -e shell
install AnyEvent::Redis::RipeRedis

For more information on module installation, please visit the detailed CPAN module installation guide.

	Global
`s`	Focus search bar
`?`	Bring up this help dialog

	GitHub
`g` `p`	Go to pull requests
`g` `i`	go to github issues (only if github is preferred repository)

	POD
`g` `a`	Go to author
`g` `c`	Go to changes
`g` `i`	Go to issues
`g` `d`	Go to dist
`g` `r`	Go to repository/SCM
`g` `s`	Go to source
`g` `b`	Go to file browse

	Search terms
module: (e.g. module:Plugin)
distribution: (e.g. distribution:Dancer auth)
author: (e.g. author:SONGMU Redis)
version: (e.g. version:1.00)

NAME

SYNOPSIS

DESCRIPTION

CONSTRUCTOR

new()

COMMAND EXECUTION

<command>( [ @args[, \%callbacks ] ] )

TRANSACTIONS

multi( [ \%callbacks ] )

exec( [ \%callbacks ] )

discard( [ \%callbacks ] )

watch( @keys[, \%callbacks ] )

unwatch( [ \%callbacks ] )

SUBSCRIPTIONS

subscribe( @channels[, \%callbacks ] )

psubscribe( @patterns[, \%callbacks ] )

publish( $channel, $message[, \%callbacks ] )

unsubscribe( [ @channels ][, \%callbacks ] )

punsubscribe( [ @patterns ][, \%callbacks ] )

CONNECTION VIA UNIX-SOCKET

LUA SCRIPTS EXECUTION

eval_cached( $script, $numkeys[, [ @keys, ][ @args, ]\%callbacks ] );

ERROR CODES

DISCONNECTION

disconnect()

OTHER METHODS

connection_timeout( $seconds )

read_timeout( $seconds )

reconnect( $boolean )

encoding( $enc_name )

on_connect( $callback )

on_disconnect( $callback )

on_connect_error( $callback )

on_error( $callback )

SEE ALSO

AUTHOR

Special thanks

COPYRIGHT AND LICENSE

Module Install Instructions