NAME

MCE::Grep - Parallel grep model similar to the native grep function

VERSION

This document describes MCE::Grep version 1.499_005

SYNOPSIS

   ## Exports mce_grep, mce_grep_f, and mce_grep_s
   use MCE::Grep;

   ## Array or array_ref
   my @a = mce_grep { $_ % 5 == 0 } 1..10000;
   my @b = mce_grep { $_ % 5 == 0 } [ 1..10000 ];

   ## File_path, glob_ref, or scalar_ref
   my @c = mce_grep_f { /phrase/ } "/path/to/file";
   my @d = mce_grep_f { /phrase/ } $file_handle;
   my @e = mce_grep_f { /phrase/ } \$scalar;

   ## Sequence of numbers (begin, end [, step, format])
   my @f = mce_grep_s { %_ * 3 == 0 } 1, 10000, 5;
   my @g = mce_grep_s { %_ * 3 == 0 } [ 1, 10000, 5 ];

   my @h = mce_grep_s { %_ * 3 == 0 } {
      begin => 1, end => 10000, step => 5, format => undef
   };

DESCRIPTION

This module provides a parallel grep implementation via Many-core Engine. MCE incurs a small overhead due to passing of data. Therefore, a fast code block will likely run faster using the native grep function in Perl. The overhead quickly diminishes as the complexity of the code block increases.

   my @m1 =     grep { $_ % 5 == 0 } 1..1000000;          ## 0.137 secs
   my @m2 = mce_grep { $_ % 5 == 0 } 1..1000000;          ## 0.295 secs

Chunking, enabled by default, greatly reduces the overhead behind the scene. The time for mce_grep below also includes the time for data exchanges between the manager and worker processes. More parallelization will be seen when the code block requires more CPU time code-wise.

   my @m1 =     grep { /[2357][1468][9]/ } 1..1000000;    ## 0.653 secs
   my @m2 = mce_grep { /[2357][1468][9]/ } 1..1000000;    ## 0.347 secs

The mce_grep_s funtion will provide better times, useful when input data is simply a range of numbers. Workers generate sequences mathematically among themselves without any interaction from the manager process. Two arguments are required for mce_grep_s (begin, end). Step defaults to 1 if begin is smaller than end, otherwise -1.

   my @m3 = mce_grep_s { /[2357][1468][9]/ } 1, 1000000;  ## 0.271 secs

Although this documentation is about MCE::Grep, the MCE::Stream module can write results immediately without waiting for all chunks to complete. This is made possible by passing the reference of the array (in this case @m4 and @m5).

   use MCE::Stream default_mode => 'grep';

   my @m4; mce_stream \@m4, sub { /[2357][1468][9]/ }, 1..1000000;

      ## Completed in 0.304 secs. That is amazing considering the
      ## overhead for passing data between the manager and worker.

   my @m5; mce_stream_s \@m5, sub { /[2357][1468][9]/ }, 1, 1000000;

      ## Completed in 0.227 secs. Like with mce_grep_s, specifying a
      ## sequence specification turns out to be faster due to lesser
      ## overhead for the manager process.

OVERRIDING DEFAULTS

The following list 5 options which may be overridden when loading the module.

   use Sereal qw(encode_sereal decode_sereal);

   use MCE::Grep
         max_workers => 4,                    ## Default 'auto' 
         chunk_size  => 100,                  ## Default 'auto'
         tmp_dir     => "/path/to/app/tmp",   ## $MCE::Signal::tmp_dir
         freeze      => \&encode_sereal,      ## \&Storable::freeze
         thaw        => \&decode_sereal       ## \&Storable::thaw
   ;

There is a simplier way to enable Sereal with MCE 1.5. The following will attempt to use Sereal if available, otherwise will default back to using Storable for serialization.

   use MCE::Grep Sereal => 1;

   ## Serialization is through Sereal if available.
   my @m2 = mce_grep { $_ % 5 == 0 } 1..10000;

CUSTOMIZING MCE

init

The init function takes a hash of MCE options. The gather option, if specified, will be set to undef due to being used internally by the module.

   use MCE::Grep;

   MCE::Grep::init {
      chunk_size => 1, max_workers => 4,

      user_begin => sub {
         print "## ", MCE->wid, " started\n";
      },

      user_end => sub {
         print "## ", MCE->wid, " completed\n";
      }
   };

   my @a = mce_grep { $_ % 5 == 0 } 1..100;

   print "\n", "@a", "\n";

   -- output

   ## 2 started
   ## 3 started
   ## 1 started
   ## 4 started
   ## 3 completed
   ## 4 completed
   ## 1 completed
   ## 2 completed

   5 10 15 20 25 30 35 40 45 50 55 60 65 70 75 80 85 90 95 100

API DOCUMENTATION

mce_grep { code } list

Input data can be specified using a list or passing a reference to an array.

   my @a = mce_grep { /[2357]/ } 1..1000;
   my @b = mce_grep { /[2357]/ } [ 1..1000 ];

mce_grep_f { code } file

The fastest of these is the /path/to/file. Workers communicate the next offset position among themselves without any interaction from the manager process.

   my @c = mce_grep_f { /phrase/ } "/path/to/file";
   my @d = mce_grep_f { /phrase/ } $file_handle;
   my @e = mce_grep_f { /phrase/ } \$scalar;

mce_grep_s { code } sequence

Sequence can be specified as a list, an array reference, or a hash reference. The functions require both begin and end values to run. Step and format are optional. The format is passed to sprintf (% can be omitted below).

   my ($beg, $end, $step, $fmt) = (10, 20, 0.1, "%4.1f");

   my @f = mce_grep_s { /[1234]\.[5678]/ } $beg, $end, $step, $fmt;
   my @g = mce_grep_s { /[1234]\.[5678]/ } [ $beg, $end, $step, $fmt ];

   my @h = mce_grep_s { /[1234]\.[5678]/ } {
      begin => $beg, end => $end, step => $step, format => $fmt
   };

MANUAL SHUTDOWN

finish

MCE workers remain persistent as much as possible after running. Shutdown occurs when the script exits. One can manually shutdown MCE by simply calling finish after running. This resets the MCE instance.

   use MCE::Grep;

   MCE::Grep::init {
      chunk_size => 20, max_workers => 'auto'
   };

   my @a = mce_grep { ... } 1..100;

   MCE::Grep::finish;

INDEX

MCE

AUTHOR

Mario E. Roy, <marioeroy AT gmail DOT com>

LICENSE

This program is free software; you can redistribute it and/or modify it under the terms of either: the GNU General Public License as published by the Free Software Foundation; or the Artistic License.

See http://dev.perl.org/licenses/ for more information.

cpanm MCE

perl -MCPAN -e shell
install MCE