NAME

AnyEvent::Handle - non-blocking I/O on file handles via AnyEvent

SYNOPSIS

   use AnyEvent;
   use AnyEvent::Handle;

   my $cv = AnyEvent->condvar;

   my $handle =
      AnyEvent::Handle->new (
         fh => \*STDIN,
         on_eof => sub {
            $cv->send;
         },
      );

   # send some request line
   $handle->push_write ("getinfo\015\012");

   # read the response line
   $handle->push_read (line => sub {
      my ($handle, $line) = @_;
      warn "read line <$line>\n";
      $cv->send;
   });

   $cv->recv;

DESCRIPTION

This module is a helper module to make it easier to do event-based I/O on filehandles. For utility functions for doing non-blocking connects and accepts on sockets see AnyEvent::Util.

The AnyEvent::Intro tutorial contains some well-documented AnyEvent::Handle examples.

In the following, when the documentation refers to of "bytes" then this means characters. As sysread and syswrite are used for all I/O, their treatment of characters applies to this module as well.

All callbacks will be invoked with the handle object as their first argument.

METHODS

new (%args)

The constructor supports these arguments (all as key => value pairs).

fh => $filehandle [MANDATORY]

The filehandle this AnyEvent::Handle object will operate on.

NOTE: The filehandle will be set to non-blocking mode (using AnyEvent::Util::fh_nonblocking) by the constructor and needs to stay in that mode.

on_eof => $cb->($handle)

Set the callback to be called when an end-of-file condition is detected, i.e. in the case of a socket, when the other side has closed the connection cleanly.

For sockets, this just means that the other side has stopped sending data, you can still try to write data, and, in fact, one can return from the EOF callback and continue writing data, as only the read part has been shut down.

While not mandatory, it is highly recommended to set an EOF callback, otherwise you might end up with a closed socket while you are still waiting for data.

If an EOF condition has been detected but no on_eof callback has been set, then a fatal error will be raised with $! set to <0>.

on_error => $cb->($handle, $fatal)

This is the error callback, which is called when, well, some error occured, such as not being able to resolve the hostname, failure to connect or a read error.

Some errors are fatal (which is indicated by $fatal being true). On fatal errors the handle object will be shut down and will not be usable (but you are free to look at the current ->rbuf). Examples of fatal errors are an EOF condition with active (but unsatisifable) read watchers (EPIPE) or I/O errors.

Non-fatal errors can be retried by simply returning, but it is recommended to simply ignore this parameter and instead abondon the handle object when this callback is invoked. Examples of non-fatal errors are timeouts ETIMEDOUT) or badly-formatted data (EBADMSG).

On callback entrance, the value of $! contains the operating system error (or ENOSPC, EPIPE, ETIMEDOUT or EBADMSG).

While not mandatory, it is highly recommended to set this callback, as you will not be notified of errors otherwise. The default simply calls croak.

on_read => $cb->($handle)

This sets the default read callback, which is called when data arrives and no read request is in the queue (unlike read queue callbacks, this callback will only be called when at least one octet of data is in the read buffer).

To access (and remove data from) the read buffer, use the ->rbuf method or access the $handle-{rbuf}> member directly. Note that you must not enlarge or modify the read buffer, you can only remove data at the beginning from it.

When an EOF condition is detected then AnyEvent::Handle will first try to feed all the remaining data to the queued callbacks and on_read before calling the on_eof callback. If no progress can be made, then a fatal error will be raised (with $! set to EPIPE).

on_drain => $cb->($handle)

This sets the callback that is called when the write buffer becomes empty (or when the callback is set and the buffer is empty already).

To append to the write buffer, use the ->push_write method.

This callback is useful when you don't want to put all of your write data into the queue at once, for example, when you want to write the contents of some file to the socket you might not want to read the whole file into memory and push it into the queue, but instead only read more data from the file when the write queue becomes empty.

timeout => $fractional_seconds

If non-zero, then this enables an "inactivity" timeout: whenever this many seconds pass without a successful read or write on the underlying file handle, the on_timeout callback will be invoked (and if that one is missing, a non-fatal ETIMEDOUT error will be raised).

Note that timeout processing is also active when you currently do not have any outstanding read or write requests: If you plan to keep the connection idle then you should disable the timout temporarily or ignore the timeout in the on_timeout callback, in which case AnyEvent::Handle will simply restart the timeout.

Zero (the default) disables this timeout.

on_timeout => $cb->($handle)

Called whenever the inactivity timeout passes. If you return from this callback, then the timeout will be reset as if some activity had happened, so this condition is not fatal in any way.

rbuf_max => <bytes>

If defined, then a fatal error will be raised (with $! set to ENOSPC) when the read buffer ever (strictly) exceeds this size. This is useful to avoid some forms of denial-of-service attacks.

For example, a server accepting connections from untrusted sources should be configured to accept only so-and-so much data that it cannot act on (for example, when expecting a line, an attacker could send an unlimited amount of data without a callback ever being called as long as the line isn't finished).

autocork => <boolean>

When disabled (the default), then push_write will try to immediately write the data to the handle, if possible. This avoids having to register a write watcher and wait for the next event loop iteration, but can be inefficient if you write multiple small chunks (on the wire, this disadvantage is usually avoided by your kernel's nagle algorithm, see no_delay, but this option can save costly syscalls).

When enabled, then writes will always be queued till the next event loop iteration. This is efficient when you do many small writes per iteration, but less efficient when you do a single write only per iteration (or when the write buffer often is full). It also increases write latency.

no_delay => <boolean>

When doing small writes on sockets, your operating system kernel might wait a bit for more data before actually sending it out. This is called the Nagle algorithm, and usually it is beneficial.

In some situations you want as low a delay as possible, which can be accomplishd by setting this option to a true value.

The default is your opertaing system's default behaviour (most likely enabled), this option explicitly enables or disables it, if possible.

read_size => <bytes>

The default read block size (the amount of bytes this module will try to read during each loop iteration, which affects memory requirements). Default: 8192.

low_water_mark => <bytes>

Sets the amount of bytes (default: 0) that make up an "empty" write buffer: If the write reaches this size or gets even samller it is considered empty.

Sometimes it can be beneficial (for performance reasons) to add data to the write buffer before it is fully drained, but this is a rare case, as the operating system kernel usually buffers data as well, so the default is good in almost all cases.

linger => <seconds>

If non-zero (default: 3600), then the destructor of the AnyEvent::Handle object will check whether there is still outstanding write data and will install a watcher that will write this data to the socket. No errors will be reported (this mostly matches how the operating system treats outstanding data at socket close time).

This will not work for partial TLS data that could not be encoded yet. This data will be lost. Calling the stoptls method in time might help.

tls => "accept" | "connect" | Net::SSLeay::SSL object

When this parameter is given, it enables TLS (SSL) mode, that means AnyEvent will start a TLS handshake as soon as the conenction has been established and will transparently encrypt/decrypt data afterwards.

TLS mode requires Net::SSLeay to be installed (it will be loaded automatically when you try to create a TLS handle): this module doesn't have a dependency on that module, so if your module requires it, you have to add the dependency yourself.

Unlike TCP, TLS has a server and client side: for the TLS server side, use accept, and for the TLS client side of a connection, use connect mode.

You can also provide your own TLS connection object, but you have to make sure that you call either Net::SSLeay::set_connect_state or Net::SSLeay::set_accept_state on it before you pass it to AnyEvent::Handle.

IMPORTANT: since Net::SSLeay "objects" are really only integers, passing in the wrong integer will lead to certain crash. This most often happens when one uses a stylish tls => 1 and is surprised about the segmentation fault.

See the ->starttls method for when need to start TLS negotiation later.

tls_ctx => $ssl_ctx

Use the given Net::SSLeay::CTX object to create the new TLS connection (unless a connection object was specified directly). If this parameter is missing, then AnyEvent::Handle will use AnyEvent::Handle::TLS_CTX.

json => JSON or JSON::XS object

This is the json coder object used by the json read and write types.

If you don't supply it, then AnyEvent::Handle will create and use a suitable one (on demand), which will write and expect UTF-8 encoded JSON texts.

Note that you are responsible to depend on the JSON module if you want to use this functionality, as AnyEvent does not have a dependency itself.

$fh = $handle->fh

This method returns the file handle used to create the AnyEvent::Handle object.

$handle->on_error ($cb)

Replace the current on_error callback (see the on_error constructor argument).

$handle->on_eof ($cb)

Replace the current on_eof callback (see the on_eof constructor argument).

$handle->on_timeout ($cb)

Replace the current on_timeout callback, or disables the callback (but not the timeout) if $cb = undef. See the timeout constructor argument and method.

$handle->autocork ($boolean)

Enables or disables the current autocork behaviour (see autocork constructor argument). Changes will only take effect on the next write.

$handle->no_delay ($boolean)

Enables or disables the no_delay setting (see constructor argument of the same name for details).

$handle->timeout ($seconds)

Configures (or disables) the inactivity timeout.

WRITE QUEUE

AnyEvent::Handle manages two queues per handle, one for writing and one for reading.

The write queue is very simple: you can add data to its end, and AnyEvent::Handle will automatically try to get rid of it for you.

When data could be written and the write buffer is shorter then the low water mark, the on_drain callback will be invoked.

$handle->on_drain ($cb)

Sets the on_drain callback or clears it (see the description of on_drain in the constructor).

$handle->push_write ($data)

Queues the given scalar to be written. You can push as much data as you want (only limited by the available memory), as AnyEvent::Handle buffers it independently of the kernel.

$handle->push_write (type => @args)

Instead of formatting your data yourself, you can also let this module do the job by specifying a type and type-specific arguments.

Predefined types are (if you have ideas for additional types, feel free to drop by and tell us):

netstring => $string

Formats the given value as netstring (http://cr.yp.to/proto/netstrings.txt, this is not a recommendation to use them).

packstring => $format, $data

An octet string prefixed with an encoded length. The encoding $format uses the same format as a Perl pack format, but must specify a single integer only (only one of cCsSlLqQiInNvVjJw is allowed, plus an optional !, < or > modifier).

json => $array_or_hashref

Encodes the given hash or array reference into a JSON object. Unless you provide your own JSON object, this means it will be encoded to JSON text in UTF-8.

JSON objects (and arrays) are self-delimiting, so you can write JSON at one end of a handle and read them at the other end without using any additional framing.

The generated JSON text is guaranteed not to contain any newlines: While this module doesn't need delimiters after or between JSON texts to be able to read them, many other languages depend on that.

A simple RPC protocol that interoperates easily with others is to send JSON arrays (or objects, although arrays are usually the better choice as they mimic how function argument passing works) and a newline after each JSON text:

   $handle->push_write (json => ["method", "arg1", "arg2"]); # whatever
   $handle->push_write ("\012");

An AnyEvent::Handle receiver would simply use the json read type and rely on the fact that the newline will be skipped as leading whitespace:

   $handle->push_read (json => sub { my $array = $_[1]; ... });

Other languages could read single lines terminated by a newline and pass this line into their JSON decoder of choice.

storable => $reference

Freezes the given reference using Storable and writes it to the handle. Uses the nfreeze format.

AnyEvent::Handle::register_write_type type => $coderef->($handle, @args)

This function (not method) lets you add your own types to push_write. Whenever the given type is used, push_write will invoke the code reference with the handle object and the remaining arguments.

The code reference is supposed to return a single octet string that will be appended to the write buffer.

Note that this is a function, and all types registered this way will be global, so try to use unique names.

READ QUEUE

AnyEvent::Handle manages two queues per handle, one for writing and one for reading.

The read queue is more complex than the write queue. It can be used in two ways, the "simple" way, using only on_read and the "complex" way, using a queue.

In the simple case, you just install an on_read callback and whenever new data arrives, it will be called. You can then remove some data (if enough is there) from the read buffer ($handle->rbuf). Or you cna leave the data there if you want to accumulate more (e.g. when only a partial message has been received so far).

In the more complex case, you want to queue multiple callbacks. In this case, AnyEvent::Handle will call the first queued callback each time new data arrives (also the first time it is queued) and removes it when it has done its job (see push_read, below).

This way you can, for example, push three line-reads, followed by reading a chunk of data, and AnyEvent::Handle will execute them in order.

Example 1: EPP protocol parser. EPP sends 4 byte length info, followed by the specified number of bytes which give an XML datagram.

   # in the default state, expect some header bytes
   $handle->on_read (sub {
      # some data is here, now queue the length-header-read (4 octets)
      shift->unshift_read (chunk => 4, sub {
         # header arrived, decode
         my $len = unpack "N", $_[1];

         # now read the payload
         shift->unshift_read (chunk => $len, sub {
            my $xml = $_[1];
            # handle xml
         });
      });
   });

Example 2: Implement a client for a protocol that replies either with "OK" and another line or "ERROR" for the first request that is sent, and 64 bytes for the second request. Due to the availability of a queue, we can just pipeline sending both requests and manipulate the queue as necessary in the callbacks.

When the first callback is called and sees an "OK" response, it will unshift another line-read. This line-read will be queued before the 64-byte chunk callback.

   # request one, returns either "OK + extra line" or "ERROR"
   $handle->push_write ("request 1\015\012");

   # we expect "ERROR" or "OK" as response, so push a line read
   $handle->push_read (line => sub {
      # if we got an "OK", we have to _prepend_ another line,
      # so it will be read before the second request reads its 64 bytes
      # which are already in the queue when this callback is called
      # we don't do this in case we got an error
      if ($_[1] eq "OK") {
         $_[0]->unshift_read (line => sub {
            my $response = $_[1];
            ...
         });
      }
   });

   # request two, simply returns 64 octets
   $handle->push_write ("request 2\015\012");

   # simply read 64 bytes, always
   $handle->push_read (chunk => 64, sub {
      my $response = $_[1];
      ...
   });

$handle->on_read ($cb)

This replaces the currently set on_read callback, or clears it (when the new callback is undef). See the description of on_read in the constructor.

$handle->rbuf

Returns the read buffer (as a modifiable lvalue).

You can access the read buffer directly as the ->{rbuf} member, if you want. However, the only operation allowed on the read buffer (apart from looking at it) is removing data from its beginning. Otherwise modifying or appending to it is not allowed and will lead to hard-to-track-down bugs.

NOTE: The read buffer should only be used or modified if the on_read, push_read or unshift_read methods are used. The other read methods automatically manage the read buffer.

$handle->push_read ($cb)

$handle->unshift_read ($cb)

Append the given callback to the end of the queue (push_read) or prepend it (unshift_read).

The callback is called each time some additional read data arrives.

It must check whether enough data is in the read buffer already.

If not enough data is available, it must return the empty list or a false value, in which case it will be called repeatedly until enough data is available (or an error condition is detected).

If enough data was available, then the callback must remove all data it is interested in (which can be none at all) and return a true value. After returning true, it will be removed from the queue.

$handle->push_read (type => @args, $cb)

$handle->unshift_read (type => @args, $cb)

Instead of providing a callback that parses the data itself you can chose between a number of predefined parsing formats, for chunks of data, lines etc.

Predefined types are (if you have ideas for additional types, feel free to drop by and tell us):

chunk => $octets, $cb->($handle, $data)

Invoke the callback only once $octets bytes have been read. Pass the data read to the callback. The callback will never be called with less data.

Example: read 2 bytes.

   $handle->push_read (chunk => 2, sub {
      warn "yay ", unpack "H*", $_[1];
   });

line => [$eol, ]$cb->($handle, $line, $eol)

The callback will be called only once a full line (including the end of line marker, $eol) has been read. This line (excluding the end of line marker) will be passed to the callback as second argument ($line), and the end of line marker as the third argument ($eol).

The end of line marker, $eol, can be either a string, in which case it will be interpreted as a fixed record end marker, or it can be a regex object (e.g. created by qr), in which case it is interpreted as a regular expression.

The end of line marker argument $eol is optional, if it is missing (NOT undef), then qr|\015?\012| is used (which is good for most internet protocols).

Partial lines at the end of the stream will never be returned, as they are not marked by the end of line marker.

regex => $accept[, $reject[, $skip], $cb->($handle, $data)

Makes a regex match against the regex object $accept and returns everything up to and including the match.

Example: read a single line terminated by '\n'.

   $handle->push_read (regex => qr<\n>, sub { ... });

If $reject is given and not undef, then it determines when the data is to be rejected: it is matched against the data when the $accept regex does not match and generates an EBADMSG error when it matches. This is useful to quickly reject wrong data (to avoid waiting for a timeout or a receive buffer overflow).

Example: expect a single decimal number followed by whitespace, reject anything else (not the use of an anchor).

   $handle->push_read (regex => qr<^[0-9]+\s>, qr<[^0-9]>, sub { ... });

If $skip is given and not undef, then it will be matched against the receive buffer when neither $accept nor $reject match, and everything preceding and including the match will be accepted unconditionally. This is useful to skip large amounts of data that you know cannot be matched, so that the $accept or $reject regex do not have to start matching from the beginning. This is purely an optimisation and is usually worth only when you expect more than a few kilobytes.

Example: expect a http header, which ends at \015\012\015\012. Since we expect the header to be very large (it isn't in practise, but...), we use a skip regex to skip initial portions. The skip regex is tricky in that it only accepts something not ending in either \015 or \012, as these are required for the accept regex.

   $handle->push_read (regex =>
      qr<\015\012\015\012>,
      undef, # no reject
      qr<^.*[^\015\012]>,
      sub { ... });

netstring => $cb->($handle, $string)

A netstring (http://cr.yp.to/proto/netstrings.txt, this is not an endorsement).

Throws an error with $! set to EBADMSG on format violations.

packstring => $format, $cb->($handle, $string)

For example, DNS over TCP uses a prefix of n (2 octet network order), EPP uses a prefix of N (4 octtes).

Example: read a block of data prefixed by its length in BER-encoded format (very efficient).

   $handle->push_read (packstring => "w", sub {
      my ($handle, $data) = @_;
   });

json => $cb->($handle, $hash_or_arrayref)

Reads a JSON object or array, decodes it and passes it to the callback. When a parse error occurs, an EBADMSG error will be raised.

If a json object was passed to the constructor, then that will be used for the final decode, otherwise it will create a JSON coder expecting UTF-8.

This read type uses the incremental parser available with JSON version 2.09 (and JSON::XS version 2.2) and above. You have to provide a dependency on your own: this module will load the JSON module, but AnyEvent does not depend on it itself.

Since JSON texts are fully self-delimiting, the json read and write types are an ideal simple RPC protocol: just exchange JSON datagrams. See the json write type description, above, for an actual example.

storable => $cb->($handle, $ref)

Deserialises a Storable frozen representation as written by the storable write type (BER-encoded length prefix followed by nfreeze'd data).

Raises EBADMSG error if the data could not be decoded.

AnyEvent::Handle::register_read_type type => $coderef->($handle, $cb, @args)

This function (not method) lets you add your own types to push_read.

Whenever the given type is used, push_read will invoke the code reference with the handle object, the callback and the remaining arguments.

The code reference is supposed to return a callback (usually a closure) that works as a plain read callback (see ->push_read ($cb)).

It should invoke the passed callback when it is done reading (remember to pass $handle as first argument as all other callbacks do that).

Note that this is a function, and all types registered this way will be global, so try to use unique names.

For examples, see the source of this module (perldoc -m AnyEvent::Handle, search for register_read_type)).

$handle->stop_read

$handle->start_read

In rare cases you actually do not want to read anything from the socket. In this case you can call stop_read. Neither on_read nor any queued callbacks will be executed then. To start reading again, call start_read.

Note that AnyEvent::Handle will automatically start_read for you when you change the on_read callback or push/unshift a read callback, and it will automatically stop_read for you when neither on_read is set nor there are any read requests in the queue.

These methods will have no effect when in TLS mode (as TLS doesn't support half-duplex connections).

$handle->starttls ($tls[, $tls_ctx])

Instead of starting TLS negotiation immediately when the AnyEvent::Handle object is created, you can also do that at a later time by calling starttls.

The first argument is the same as the tls constructor argument (either "connect", "accept" or an existing Net::SSLeay object).

The second argument is the optional Net::SSLeay::CTX object that is used when AnyEvent::Handle has to create its own TLS connection object.

The TLS connection object will end up in $handle->{tls} after this call and can be used or changed to your liking. Note that the handshake might have already started when this function returns.

If it an error to start a TLS handshake more than once per AnyEvent::Handle object (this is due to bugs in OpenSSL).

$handle->stoptls

Shuts down the SSL connection - this makes a proper EOF handshake by sending a close notify to the other side, but since OpenSSL doesn't support non-blocking shut downs, it is not possible to re-use the stream afterwards.

$handle->destroy

Shuts down the handle object as much as possible - this call ensures that no further callbacks will be invoked and resources will be freed as much as possible. You must not call any methods on the object afterwards.

Normally, you can just "forget" any references to an AnyEvent::Handle object and it will simply shut down. This works in fatal error and EOF callbacks, as well as code outside. It does NOT work in a read or write callback, so when you want to destroy the AnyEvent::Handle object from within such an callback. You MUST call ->destroy explicitly in that case.

The handle might still linger in the background and write out remaining data, as specified by the linger option, however.

AnyEvent::Handle::TLS_CTX

This function creates and returns the Net::SSLeay::CTX object used by default for TLS mode.

The context is created like this:

   Net::SSLeay::load_error_strings;
   Net::SSLeay::SSLeay_add_ssl_algorithms;
   Net::SSLeay::randomize;

   my $CTX = Net::SSLeay::CTX_new;

   Net::SSLeay::CTX_set_options $CTX, Net::SSLeay::OP_ALL

NONFREQUENTLY ASKED QUESTIONS

I undef the AnyEvent::Handle reference inside my callback and still get further invocations!

That's because AnyEvent::Handle keeps a reference to itself when handling read or write callbacks.

It is only safe to "forget" the reference inside EOF or error callbacks, from within all other callbacks, you need to explicitly call the ->destroy method.

I get different callback invocations in TLS mode/Why can't I pause reading?

Unlike, say, TCP, TLS connections do not consist of two independent communication channels, one for each direction. Or put differently. The read and write directions are not independent of each other: you cannot write data unless you are also prepared to read, and vice versa.

This can mean than, in TLS mode, you might get on_error or on_eof callback invocations when you are not expecting any read data - the reason is that AnyEvent::Handle always reads in TLS mode.

During the connection, you have to make sure that you always have a non-empty read-queue, or an on_read watcher. At the end of the connection (or when you no longer want to use it) you can call the destroy method.

How do I read data until the other side closes the connection?

If you just want to read your data into a perl scalar, the easiest way to achieve this is by setting an on_read callback that does nothing, clearing the on_eof callback and in the on_error callback, the data will be in $_[0]{rbuf}:

   $handle->on_read (sub { });
   $handle->on_eof (undef);
   $handle->on_error (sub {
      my $data = delete $_[0]{rbuf};
      undef $handle;
   });

The reason to use on_error is that TCP connections, due to latencies and packets loss, might get closed quite violently with an error, when in fact, all data has been received.

It is usually better to use acknowledgements when transferring data, to make sure the other side hasn't just died and you got the data intact. This is also one reason why so many internet protocols have an explicit QUIT command.

I don't want to destroy the handle too early - how do I wait until all data has been written?

After writing your last bits of data, set the on_drain callback and destroy the handle in there - with the default setting of low_water_mark this will be called precisely when all data has been written to the socket:

   $handle->push_write (...);
   $handle->on_drain (sub {
      warn "all data submitted to the kernel\n";
      undef $handle;
   });

SUBCLASSING AnyEvent::Handle

In many cases, you might want to subclass AnyEvent::Handle.

To make this easier, a given version of AnyEvent::Handle uses these conventions:

all constructor arguments become object members.

At least initially, when you pass a tls-argument to the constructor it will end up in $handle->{tls}. Those members might be changed or mutated later on (for example tls will hold the TLS connection object).
other object member names are prefixed with an _.

All object members not explicitly documented (internal use) are prefixed with an underscore character, so the remaining non-_-namespace is free for use for subclasses.
all members not documented here and not prefixed with an underscore are free to use in subclasses.

Of course, new versions of AnyEvent::Handle may introduce more "public" member variables, but thats just life, at least it is documented.

AUTHOR

Robin Redeker <elmex at ta-sa.org>, Marc Lehmann <schmorp@schmorp.de>.

To install AnyEvent, copy and paste the appropriate command in to your terminal.

cpanm

cpanm AnyEvent

CPAN shell

perl -MCPAN -e shell
install AnyEvent

For more information on module installation, please visit the detailed CPAN module installation guide.

	Global
`s`	Focus search bar
`?`	Bring up this help dialog

	GitHub
`g` `p`	Go to pull requests
`g` `i`	go to github issues (only if github is preferred repository)

	POD
`g` `a`	Go to author
`g` `c`	Go to changes
`g` `i`	Go to issues
`g` `d`	Go to dist
`g` `r`	Go to repository/SCM
`g` `s`	Go to source
`g` `b`	Go to file browse

	Search terms
module: (e.g. module:Plugin)
distribution: (e.g. distribution:Dancer auth)
author: (e.g. author:SONGMU Redis)
version: (e.g. version:1.00)