NAME

IO::Async::Stream - read and write buffers around an IO handle

SYNOPSIS

 use IO::Socket::INET;
 use IO::Async::Stream;

 use IO::Async::Loop::IO_Poll;
 my $loop = IO::Async::Loop::IO_Poll->new();

 my $socket = IO::Socket::INET->new(
    PeerHost => "some.other.host",
    PeerPort => 12345,
    Blocking => 0,                   # This line is very important
 );

 my $stream = IO::Async::Stream->new(
    handle => $socket,

    on_read => sub {
       my ( $self, $buffref, $closed ) = @_;

       if( $$buffref =~ s/^(.*\n)// ) {
          print "Received a line $1";

          return 1;
       }

       if( $closed ) {
          print "Closed; last partial line is $$buffref\n";
       }

       return 0;
    }
 );

 $stream->write( "An initial line here\n" );

Or

 my $record_stream = IO::Async::Stream->new(
    handle => ...,

    on_read => sub {
       my ( $self, $buffref, $closed ) = @_;

       if( length $$buffref >= 16 ) {
          my $record = substr( $$buffref, 0, 16, "" );
          print "Received a 16-byte record: $record\n";

          return 1;
       }

       if( $closed and length $$buffref ) {
          print "Closed: a partial record still exists\n";
       }

       return 0;
    }
 );

Or

 use IO::Handle;

 my $stream = IO::Async::Stream->new(
    read_handle  => \*STDIN,
    write_handle => \*STDOUT,
    ...
 );

DESCRIPTION

This module provides a subclass of IO::Async::Notifier which implements asynchronous communications buffers around stream handles. It provides buffering for both incoming and outgoing data, which are transferred to or from the actual handle when it is read- or write-ready.

Data can be added to the outgoing buffer at any time using the write() method, and will be flushed whenever the underlying handle is notified as being write-ready. Whenever the handle is notified as being read-ready, the data is read in from the handle, and the on_read code is called to indicate the data is available.

This object may be used in one of two ways; with a callback function, or as a base class.

Callbacks

If certain keys are supplied to the constructor, they should contain CODE references to callback functions that will be called in the following manner:

 $ret = $on_read->( $self, \$buffer, $handleclosed )

 $on_read_error->( $self, $errno )

 $on_outgoing_empty->( $self )

 $on_write_error->( $self, $errno )

A reference to the calling IO::Async::Stream object is passed as the first argument, so that the callback can access it.

Base Class

If a subclass is built, then it can override the on_read or on_outgoing_empty methods, which will be called in the following manner:

 $ret = $self->on_read( \$buffer, $handleclosed )

 $self->on_read_error( $errno )

 $self->on_outgoing_empty()

 $self->on_write_error( $errno )

The first argument to the on_read() callback is a reference to a plain perl string. The code should inspect and remove any data it likes, but is not required to remove all, or indeed any of the data. Any data remaining in the buffer will be preserved for the next call, the next time more data is received from the handle.

In this way, it is easy to implement code that reads records of some form when completed, but ignores partially-received records, until all the data is present. If the method is confident no more useful data remains, it should return 0. If not, it should return 1, and the method will be called again. This makes it easy to implement code that handles multiple incoming records at the same time. See the examples at the end of this documentation for more detail.

The second argument to the on_read() method is a scalar indicating whether the handle has been closed. Normally it is false, but will become true once the handle closes. A reference to the buffer is passed to the method in the usual way, so it may inspect data contained in it. Once the method returns a false value, it will not be called again, as the handle is now closed and no more data can arrive.

The on_read() code may also dynamically replace itself with a new callback by returning a CODE reference instead of 0 or 1. The original callback or method that the object first started with may be restored by returning undef. Whenever the callback is changed in this way, the new code is called again; even if the read buffer is currently empty. See the examples at the end of this documentation for more detail.

The on_read_error and on_write_error callbacks are passed the value of $! at the time the error occured. (The $! variable itself, by its nature, may have changed from the original error by the time this callback runs so it should always use the value passed in).

If an error occurs when the corresponding error callback is not supplied, and there is not a subclass method for it, then the close() method is called instead.

The on_outgoing_empty callback is not passed any arguments.

CONSTRUCTOR

$stream = IO::Async::Stream->new( %params )

This function returns a new instance of a IO::Async::Stream object. The %params hash takes the following keys:

read_handle => IO

The IO handle to read from. Must implement fileno and sysread methods.

write_handle => IO

The IO handle to write to. Must implement fileno and syswrite methods.

handle => IO

Shortcut to specifying the same IO handle for both of the above.

on_read => CODE

A CODE reference for when more data is available in the internal receiving buffer.

on_read_error => CODE

A CODE reference for when the sysread() method on the read handle fails.

on_outgoing_empty => CODE

A CODE reference for when the writing data buffer becomes empty.

on_write_error => CODE

A CODE reference for when the syswrite() method on the write handle fails.

If a read handle is given, it is required that either an on_read callback reference is passed, or that the object provides an on_read method. It is optional whether either is true for on_outgoing_empty; if neither is supplied then no action will be taken when the writing buffer becomes empty.

An on_read callback may be supplied even if no read handle is yet given, to be used when a read handle is eventually provided by the set_handles method.

METHODS

$stream->write( $data )

This method adds data to the outgoing data queue. The data is not yet sent to the handle; this will be done later in the on_write_ready() method.

$data

A scalar containing data to write

EXAMPLES

A line-based on_read() method

The following on_read() method accepts incoming \n-terminated lines and prints them to the program's STDOUT stream.

 sub on_read
 {
    my $self = shift;
    my ( $buffref, $handleclosed ) = @_;

    if( $$buffref =~ s/^(.*\n)// ) {
       print "Received a line: $1";
       return 1;
    }

    return 0;
 }

Because a reference to the buffer itself is passed, it is simple to use a s/// regular expression on the scalar it points at, to both check if data is ready (i.e. a whole line), and to remove it from the buffer. If no data is available then 0 is returned, to indicate it should not be tried again. If a line was successfully extracted, then 1 is returned, to indicate it should try again in case more lines exist in the buffer.

Dynamic replacement of on_read()

Consider the following protocol (inspired by IMAP), which consists of \n-terminated lines that may have an optional data block attached. The presence of such a data block, as well as its size, is indicated by the line prefix.

 sub on_read
 {
    my $self = shift;
    my ( $buffref, $handleclosed ) = @_;

    if( $$buffref =~ s/^DATA (\d+):(.*)\n// ) {
       my $length = $1;
       my $line   = $2;

       return sub {
          my $self = shift;
          my ( $buffref, $handleclosed ) = @_;

          return 0 unless length $$buffref >= $length;

          # Take and remove the data from the buffer
          my $data = substr( $$buffref, 0, $length, "" );

          print "Received a line $line with some data ($data)\n";

          return undef; # Restore the original method
       }
    }
    elsif( $$buffref =~ s/^LINE:(.*)\n// ) {
       my $line = $1;

       print "Received a line $line with no data\n";

       return 1;
    }
    else {
       print STDERR "Unrecognised input\n";
       # Handle it somehow
    }
 }

In the case where trailing data is supplied, a new temporary on_read() callback is provided in a closure. This closure captures the $length variable so it knows how much data to expect. It also captures the $line variable so it can use it in the event report. When this method has finished reading the data, it reports the event, then restores the original method by returning undef.

SEE ALSO

• IO::Handle - Supply object methods for I/O handles

AUTHOR

Paul Evans <leonerd@leonerd.org.uk>

cpanm IO::Async

perl -MCPAN -e shell
install IO::Async