NAME

IO::Async::Listener - listen on network sockets for incoming connections

SYNOPSIS

This object is used indirectly via an IO::Async::Loop:

 use Socket qw( SOCK_STREAM );

 use IO::Async::Stream;

 use IO::Async::Loop::IO_Poll;
 my $loop = IO::Async::Loop::IO_Poll->new();

 $loop->enable_childmanager;

 $loop->listen(
    service  => "echo",
    socktype => SOCK_STREAM,

    on_accept => sub {
       my ( $newclient ) = @_;

       $loop->add( IO::Async::Stream->new(
          handle => $newclient,

          on_read => sub {
             my ( $self, $buffref, $closed ) = @_;
             $self->write( $$buffref );
             $$buffref = "";
             return 0;
          },
       ) );
    },

    on_resolve_error => sub { print STDERR "Cannot resolve - $_[0]\n"; },
    on_error         => sub { print STDERR "Cannot $_[0] - $_[-1]\n"; },
 );

 $loop->loop_forever;

DESCRIPTION

This module extends an IO::Async::Loop to give it the ability to create listening sockets, and accept incoming connections on them.

There are two modes of operation. Firstly, a list of addresses can be provided which will be listened on. Alternatively as a convenience, if a service name is provided instead of a list of addresses, then these will be resolved using the underlying loop's resolve() method into a list of addresses.

METHODS

$loop->listen( %params )

This method sets up a listening socket per address it is given, and will invoke a callback each time a new connection is accepted on a socket. Addresses may be given directly, or they may be looked up using the system's name resolver.

In plain address mode, the %params hash takes the following keys:

addrs => ARRAY

Reference to an array of (possibly-multiple) address structures to listen on. Each should be in the layout described for addr. Such a layout is returned by the getaddrinfo named resolver.

addr => ARRAY

Shortcut for passing a single address to listen on; it may be passed directly with this key, instead of in another array of its own.

The address (or each element of the addrs array) should be a reference to an array, with at least the following elements:

 [ $family, $socktype, $protocol, $address ]

The first three arguments will be passed to a socket() call and, if successful, the fourth to a bind() call on the resulting socket. The socket will then be listen()ed to put it into listening mode. Any trailing elements in this array will be ignored.

In named resolver mode, the %params hash takes the following keys:

service => STRING

The service name to listen on.

host => STRING

The hostname to listen on. Optional. Will listen on all addresses if not supplied.

family => INT

socktype => INT

protocol => INT

flags => INT

Optional. Other arguments to pass along with host and service to the getaddrinfo() call.

on_resolve_error => CODE

A callback that is invoked when the name resolution attempt fails. This is invoked in the same way as the on_error callback for the resolve method.

In either case, the following keys are also taken:

on_accept => CODE

A callback that is invoked whenever a new client connects to any of the sockets being listened on. It is passed the new socket handle

 $on_accept->( $clientsocket );

on_listen => CODE

Optional. A callback that is invoked when each listening socket is ready. Typically this would be used in the name resolver case, in order to inspect the socket's sockname address, or otherwise inspect the filehandle.

 $on_listen->( $listensocket );

on_error => CODE

A callback that is invoked if a syscall fails while attempting to create the listening sockets. It is passed the name of the syscall that failed, the arguments that were passed to it, and the error generated. I.e.

 $on_error->( "socket", $family, $socktype, $protocol, $! );

 $on_error->( "bind", $sock, $address, $! );

 $on_error->( "listen", $sock, $queuesize, $! );

queuesize => INT

Optional. The queue size to pass to the listen() calls. If not supplied, then 3 will be given instead.

If more than one address is provided or resolved, then a separate listening socket will be created on each.

AUTHOR

Paul Evans <leonerd@leonerd.org.uk>