NAME

IO::Async::Timer::Countdown - event callback after a fixed delay

SYNOPSIS

 use IO::Async::Timer::Countdown;

 use IO::Async::Loop;
 my $loop = IO::Async::Loop->new();

 my $timer = IO::Async::Timer::Countdown->new(
    delay => 10,

    on_expire => sub {
       print "Sorry, your time's up\n";
       $loop->loop_stop;
    },
 );

 $timer->start;

 $loop->add( $timer );

 $loop->loop_forever;

DESCRIPTION

This module provides a subclass of IO::Async::Timer for implementing one-shot fixed delays. The object implements a countdown timer, which invokes its callback after the given period from when it was started. After it has expired the Timer may be started again, when it will wait the same period then invoke the callback again. A timer that is currently running may be stopped or reset.

For a Timer object that repeatedly runs a callback at regular intervals, see instead IO::Async::Timer::Periodic.

This object may be used in one of two ways; with a callback function, or as a base class.

Callbacks

If the on_expire key is supplied to the constructor, it should contain a CODE reference to a callback function to be invoked at the appropriate time:

 $on_expire->( $self )

Base Class

If a subclass is built, then it can override the on_expire method.

 $self->on_expire()

PARAMETERS

The following named parameters may be passed to new or configure:

on_expire => CODE

CODE reference to callback to invoke when the timer expires. If not supplied, the subclass method will be called instead.

delay => NUM

The delay in seconds after starting the timer until it expires. Cannot be changed if the timer is running.

Once constructed, the timer object will need to be added to the Loop before it will work. It will also need to be started by the start method.

$timer->reset

If the timer is running, restart the countdown period from now. If the timer is not running, this method has no effect.

EXAMPLES

Watchdog Timer

Because the reset method restarts a running countdown timer back to its full period, it can be used to implement a watchdog timer. This is a timer which will not expire provided the method is called at least as often as it is configured. If the method fails to be called, the timer will eventually expire and run its callback.

For example, to expire an accepted connection after 30 seconds of inactivity:

 ...

 on_accept => sub {
    my ( $newclient ) = @_;

    my $stream;

    my $watchdog = IO::Async::Timer::Countdown->new(
       delay => 30,

       on_expire => sub { $stream->close },
    );
    $stream->add_child( $watchdog );

    $stream = IO::Async::Stream->new(
       handle => $newclient,

       on_read => sub {
          my ( $self, $buffref, $closed ) = @_;
          $watchdog->reset;

          ...
       },

       on_closed => sub {
          $watchdog->stop;
       },
    ) );

    $watchdog->start;

    $loop->add( $watchdog );
 }

AUTHOR

Paul Evans <leonerd@leonerd.org.uk>