++ed by:

21 PAUSE users
9 non-PAUSE users.

Robert 'phaylon' Sedlacek
and 1 contributors


MooseX::Types - Organise your Moose types in libraries


Library Definition

  package MyLibrary;

  # predeclare our own types
  use MooseX::Types 
      -declare => [qw( PositiveInt NegativeInt )];

  # import builtin types
  use MooseX::Types::Moose 'Int';

  # type definition
  subtype PositiveInt, 
      as Int, 
      where { $_ > 0 },
      message { "Int is not larger than 0" };
  subtype NegativeInt,
      as Int,
      where { $_ < 0 },
      message { "Int is not smaller than 0" };

  # type coercion
  coerce PositiveInt,
      from Int,
          via { 1 };



  package Foo;
  use Moose;
  use MyLibrary qw( PositiveInt NegativeInt );

  # use the exported constants as type names
  has 'bar',
      isa    => PositiveInt,
      is     => 'rw';
  has 'baz',
      isa    => NegativeInt,
      is     => 'rw';

  sub quux {
      my ($self, $value);

      # test the value
      print "positive\n" if is_PositiveInt($value);
      print "negative\n" if is_NegativeInt($value);

      # coerce the value, NegativeInt doesn't have a coercion
      # helper, since it didn't define any coercions.
      $value = to_PositiveInt($value) or die "Cannot coerce";



The types provided with Moose are by design global. This package helps you to organise and selectively import your own and the built-in types in libraries. As a nice side effect, it catches typos at compile-time too.

However, the main reason for this module is to provide an easy way to not have conflicts with your type names, since the internal fully qualified names of the types will be prefixed with the library's name.

This module will also provide you with some helper functions to make it easier to use Moose types in your code.



A constant with the name of your type. It contains the type's fully qualified name. Takes no value, as all constants.


This handler takes a value and tests if it is a valid value for this $type. It will return true or false.


A handler that will take a value and coerce it into the $type. It will return a false value if the type could not be coerced.

Important Note: This handler will only be exported for types that can do type coercion. This has the advantage that a coercion to a type that cannot hasn't defined any coercions will lead to a compile-time error.


A MooseX::Types is just a normal Perl module. Unlike Moose itself, it does not install use strict and use warnings in your class by default, so this is up to you.

The only thing a library is required to do is

  use MooseX::Types -declare => \@types;

with @types being a list of types you wish to define in this library. This line will install a proper base class in your package as well as the full set of handlers for your declared types. It will then hand control over to Moose::Util::TypeConstraints' import method to export the functions you will need to declare your types.

If you want to use Moose' built-in types (e.g. for subtyping) you will want to

  use MooseX::Types::Moose @types;

to import the helpers from the shipped MooseX::Types::Moose library which can export all types that come with Moose.

You will have to define coercions for your types or your library won't export a "to_$type" coercion helper for it.

Note that you currently cannot define types containing ::, since exporting would be a problem.

You also don't need to use warnings and strict, since the definition of a library automatically exports those.


You can import the "type helpers" of a library by useing it with a list of types to import as arguments. If you want all of them, use the :all tag. For example:

  use MyLibrary      ':all';
  use MyOtherLibrary qw( TypeA TypeB );

MooseX::Types comes with a library of Moose' built-in types called MooseX::Types::Moose.


You can define your own wrapper subclasses to manipulate the behaviour of a set of library exports. Here is an example:

  package MyWrapper;
  use strict;
  use Class::C3;
  use base 'MooseX::Types::Wrapper';

  sub coercion_export_generator {
      my $class = shift;
      my $code = $class->next::method(@_);
      return sub {
          my $value = $code->(@_);
          warn "Coercion returned undef!"
              unless defined $value;
          return $value;


This class wraps the coercion generator (e.g., to_Int()) and warns if a coercion returned an undefined value. You can wrap any library with this:

  package Foo;
  use strict;
  use MyWrapper MyLibrary => [qw( Foo Bar )],
                Moose     => [qw( Str Int )];


The Moose library name is a special shortcut for MooseX::Types::Moose.

Generator methods you can overload

type_export_generator( $short, $full )

Creates a closure returning the type's Moose::Meta::TypeConstraint object.

check_export_generator( $short, $full, $undef_message )

This creates the closure used to test if a value is valid for this type.

coercion_export_generator( $short, $full, $undef_message )

This is the closure that's doing coercions.

Provided Parameters


The short, exported name of the type.


The fully qualified name of this type as Moose knows it.


A message that will be thrown when type functionality is used but the type does not yet exist.



Installs the MooseX::Types::Base class into the caller and exports types according to the specification described in "LIBRARY DEFINITION". This will continue to Moose::Util::TypeConstraints' import method to export helper functions you will need to declare your types.


Generate a type export, e.g. Int(). This will return either a Moose::Meta::TypeConstraint object, or alternatively a MooseX::Types::UndefinedType object if the type was not yet defined.


This generates a coercion handler function, e.g. to_Int($value).


Generates a constraint check closure, e.g. is_Int($value).


A library makes the types quasi-unique by prefixing their names with (by default) the library package name. If you're only using the type handler functions provided by MooseX::Types, you shouldn't ever have to use a type's actual full name.


Moose, Moose::Util::TypeConstraints, MooseX::Types::Moose


Robert 'phaylon' Sedlacek <rs@474.at>, with many thanks to the #moose cabal on irc.perl.org.


This program is free software; you can redistribute it and/or modify it under the same terms as perl itself.