NAME

Net::OpenSSH - Perl SSH client package implemented on top of OpenSSH

SYNOPSIS

  use Net::OpenSSH;

  my $ssh = Net::OpenSSH->new($host);
  $ssh->error and
    die "Couldn't establish SSH connection: ". $ssh->error;

  $ssh->system("ls /tmp") or
    die "remote command failed: " . $ssh->error;

  my @ls = $ssh->capture("ls");
  $ssh->error and
    die "remote ls command failed: " . $ssh->error;

  my ($out, $err) = $ssh->capture2("find /root");
  $ssh->error and
    die "remote find command failed: " . $ssh->error;

  my ($rin, $pid) = $ssh->pipe_in("cat >/tmp/foo") or
    die "pipe_in method failed: " . $ssh->error;

  print $rin, "hello\n";
  close $rin;

  my ($rout, $pid) = $ssh->pipe_out("cat /tmp/foo") or
    die "pipe_out method failed: " . $ssh->error;

  while (<$rout>) { print }
  close $rout;

  my ($in, $out ,$pid) = $ssh->open2("foo");
  my ($pty, $pid) = $ssh->open2pty("foo");
  my ($in, $out, $err, $pid) = $ssh->open3("foo");
  my ($pty, $err, $pid) = $ssh->open3pty("login");

  my $sftp = $ssh->sftp();
  $sftp->error and die "SFTP failed: " . $sftp->error;

DESCRIPTION

Net::OpenSSH is a secure shell client package implemented on top of OpenSSH binary client (ssh).

Under the hood

This package is implemented around the multiplexing feature found in later versions of OpenSSH. That feature allows reuse of a previous SSH connection for running new commands (I believe that OpenSSH 4.1 is the first one to provide all the required functionality).

When a new Net::OpenSSH object is created, the OpenSSH ssh client is run in master mode, establishing a permanent (actually, for the lifetime of the object) connection to the server.

Then, every time a new operation is requested a new ssh process is started in slave mode, effectively reusing the master SSH connection to send the request to the remote side.

Net::OpenSSH Vs Net::SSH::.* modules

Why should you use Net::OpenSSH instead of any of the other Perl SSH clients available?

Well, this is my (biased) opinion:

Net::SSH::Perl is not well maintained nowadays, requires a bunch of modules (some of them very difficult to install) to be acceptably efficient and has an API that is limited in some ways.

Net::SSH2 is much better than Net::SSH::Perl, but not completely stable yet. It can be very difficult to install on some specific operative systems and its API is also limited, in the same way as Net::SSH::Perl.

Using Net::SSH::Expect, in general, is a bad idea. Handling interaction with a shell via Expect in a generic way just can not be reliably done.

Net::SSH is just a wrapper around any SSH binary commands available on the machine. It can be very slow as they establish a new SSH connection for every operation performed.

In comparison, Net::OpenSSH is a pure perl module that doesn't have any mandatory dependencies (obviously, besides requiring OpenSSH binaries).

Net::OpenSSH has a very perlish interface. Most operations are performed in a fashion very similar to that of the Perl builtins and common modules (i.e. IPC::Open2).

It is also very fast. The overhead introduced by launching a new ssh process for every operation is not appreciable (at least on my Linux box). The bottleneck is the latency intrinsic to the protocol, so Net::OpenSSH is probably as fast as an SSH client can be.

Being based on OpenSSH is also an advantage: a proved, stable, secure (to paranoic levels), interoperable and well maintained implementation of the SSH protocol is used.

On the other hand, Net::OpenSSH does not work on Windows.

Net::OpenSSH specifically requires the OpenSSH SSH client (AFAIK, the multiplexing feature is not available from any other SSH client). However, note that it will interact with any server software, not just servers running OpenSSH sshd.

For password authentication, IO::Pty has to be installed. Other modules and binaries are also required to implement specific functionality (for instance Net::SFTP::Foreign, Expect or rsync(1)).

API

Several of the methods in this package accept as first argument an optional reference to a hash containing parameters (\%opts). For instance, these two method calls are equivalent:

  my $out1 = $ssh->capture(@cmd);
  my $out2 = $ssh->capture({}, @cmd);

Error handling

Most methods return undef (or an empty list) to indicate failure.

The error method can always be used to explicitly check for errors. For instace:

  my ($output, $errput) = $ssh->capture2({timeout => 1}, "find /");
  $ssh->error and die "ssh failed: " . $ssh->error;

Net::OpenSSH methods

These are the methods provided by the package:

  *** Note that this is an early release, the ***
  *** module API has not yet stabilized!!!    ***

Net::OpenSSH->new($host, %opts)

Creates a new SSH master connection

$host can be a hostname or an IP address. It may also contain the name of the user, her password and the TCP port number where the server is listening:

   my $ssh1 = Net::OpenSSH->new('jack@foo.bar.com');
   my $ssh2 = Net::OpenSSH->new('jack:secret@foo.bar.com:10022');
   my $ssh3 = Net::OpenSSH->new('jsmith@2001:db8::1428:57ab'); # IPv6

IPv6 addresses may optionally be enclosed in brackets:

   my $ssh4 = Net::OpenSSH->new('jsmith@[::1]:1022');

This method always succeeds in returning a new object. Error checking has to be performed explicitly afterwards:

  my $ssh = Net::OpenSSH->new($host, %opts);
  $ssh->error and die "Can't ssh to $host: " . $ssh->error;

If you have problems getting Net::OpenSSH to connect to the remote host read the troubleshotting chapter near the end of this document.

Accepted options:

user => $user_name

port => $port

TCP port number where the server is running

passwd => $passwd

password => $passwd

User password for logins on the remote side

Note that using password authentication in automated scripts is a very bad idea. When possible, you should use public key authentication instead.

ctl_dir => $path

Directory where the SSH master control socket will be created.

This directory and its parents must be writable only by the current effective user or root, otherwise the connection will be aborted to avoid insecure operation.

By default ~/.libnet-openssh-perl is used.

ssh_cmd => $cmd

Name or full path to OpenSSH ssh binary. For instance:

  my $ssh = Net::OpenSSH->new($host, ssh_cmd => '/opt/OpenSSH/bin/ssh');

scp_cmd => $cmd

Name or full path to OpenSSH scp binary.

By default it is inferred from the ssh one.

rsync_cmd => $cmd

Name or full path to rsync binary. Defaults to rsync.

timeout => $timeout

Maximum acceptable time that can elapse without network traffic or any other event happening on methods that are not immediate (for instance, when establishing the master SSH connection or inside capture method).

strict_mode => 0

By default, the connection will be aborted if the path to the socket used for multiplexing is found to be non-secure (for instance, when any of the parent directories is writable by other users).

This option can be used to disable that feature. Use with care!!!

async => 1

By default, the constructor waits until the multiplexing socket is available. That option can be used to defer the waiting until the socket is actually used.

For instance, the following code connects to several remote machines in parallel:

  my (%ssh, %ls);
  # multiple connections are stablished in parallel:
  for my $host (@hosts) {
      $ssh{$host} = Net::OpenSSH->new($host, async => 1);
  }
  # then to run some command in all the hosts (sequentially):
  for my $host (@hosts) {
      $ssh{$host}->system('ls /');
  }

master_opts => [...]

Additional options to pass to the ssh command when establishing the master connection. For instance:

  my $ssh = Net::OpenSSH->new($host,
      master_opts => [-o => "ProxyCommand corkscrew httpproxy 8080 $host"]);

default_stdin_fh => $fh

default_stdout_fh => $fh

default_stderr_fh => $fh

Default I/O streams for open_ex and derived methods (currently, that means any method but pipe_in and pipe_out and I plan to remove those exceptions soon!).

For instance:

  open my $stderr_fh, '>>', '/tmp/$host.err' or die ...;
  open my $stdout_fh, '>>', '/tmp/$host.log' or die ...;

  my $ssh = Net::OpenSSH->new($host, default_stderr_fh => $stderr_fh,
                                     default_stdout_fh => $stdout_fh);
  $ssh->error and die "SSH connection failed: " . $ssh->error;

  $ssh->scp_put("/foo/bar*", "/tmp")
    or die "scp failed: " . $ssh->error;

master_stdout_fh => $fh

master_stderr_fh => $fh

Redirect corresponding stdio streams to given filehandles.

master_stdout_discard => $bool

master_stderr_discard => $bool

Discard corresponding stdio streams.

$ssh->error

Returns the error condition for the last performed operation.

The returned value is a dualvar as $! (see "$!" in perlvar) that renders an informative message when used in string context or an error number in numeric context (error codes appear in Net::OpenSSH::Constants).

$ssh->get_user

$ssh->get_host

$ssh->get_port

Return the corresponding SSH login parameters.

$ssh->get_ctl_path

Returns the path to the socket where OpenSSH listens for new multiplexed connections.

($in, $out, $err, $pid) = $ssh->open_ex(\%opts, @cmd)

Note: this is a low level method that, probably, you don't need to use!

That method starts the command @cmd on the remote machine creating new pipes for the IO channels as specified on the %opts hash.

Returns four values, the first three correspond to the local side of the pipes created (they can be undef) and the fourth to the PID of the new SSH slave process. An empty list is returned on failure.

Note that waitpid has to be used afterwards to reap the slave SSH process.

Accepted options:

stdin_pipe => 1

Creates a new pipe and connects the reading side to the stdin stream of the remote process. The writing side is returned as the first value.

stdin_pty => 1

Similar to stdin_pipe, but instead of a regular pipe it uses a pseudo-tty (pty).

Note that on some OSs (i.e. HP-UX, AIX), ttys are not reliable. They can overflow when large chunks are written or when data is written faster than it is read.

stdin_fh => $fh

Duplicates $fh and uses it as the stdin stream of the remote process.

stdin_discard => 1

Uses /dev/null as the remote process stdin stream.

stdout_pipe => 1

Creates a new pipe and connects the writting side to the stdout stream of the remote process. The reading side is returned as the second value.

stdout_pty => 1

Connects the stdout stream of the remote process to the pseudo-pty. This option requires stdin_pty to be also set.

stdout_fh => $fh

Duplicates $fh and uses it as the stdout stream of the remote process.

stdout_discard => 1

Uses /dev/null as the remote process stdout stream.

stderr_pipe => 1

Creates a new pipe and connects the writting side to the stderr stream of the remote process. The reading side is returned as the third value.

stderr_fh => $fh

Duplicates $fh and uses it as the stderr stream of the remote process.

stderr_to_stdout => 1

Makes stderr point to stdout.

tty => $bool

Tells the remote process that it is connected to a tty.

close_slave_pty => 0

When a pseudo pty is used for the stdin stream, the slave side is automatically closed on the parent process after forking the ssh command.

This option dissables that feature, so that the slave pty can be accessed on the parent process as $pty->slave. It will have to be explicitly closed (see IO::Pty)

quote_args => $bool

See "Shell quoting" below.

Usage example:

  # similar to IPC::Open2 open2 function:
  my ($in_pipe, $out_pipe, undef, $pid) = 
      $ssh->open_ex( { stdin_pipe => 1,
                       stdout_pipe => 1 },
                     @cmd )
      or die "open_ex failed: " . $ssh->error;
  # do some IO through $in/$out
  # ...
  waitpid($pid);

$ssh->system(\%opts, @cmd)

Runs the command @cmd on the remote machine.

Returns true on sucess, undef otherwise.

The error status is set to OSSH_SLAVE_CMD_FAILED when the remote command exits with a non zero code (the code is available from $?, see "$?" in perlvar).

Example:

  $ssh->system('ls -R /')
    or die "ls failed: " . $ssh->error";

As for system builtin, SIGINT and SIGQUIT signals are blocked (see "system" in perlfunc).

Accepted options:

stdin_data => $input

stdin_data => \@input

Sends the given data to the stdin stream while capturing the output on stdout.

timeout => $timeout

The operation is aborted after $timeout seconds elapsed without network activity.

As the Secure Shell protocol does not support signalling remote processes, in order to abort the remote process its input and output channels are closed. Unfortunately this aproach does not work in some cases.

async => 1

Does not wait for the child process to exit. The PID of the new process is returned.

Note that when this option is combined with stdin_data, the given data will be transferred to the remote side before returning control to the caller.

See also the spawn method documentation below.

stdin_fh => $fh

stdin_discard => $bool

stdout_fh => $fh

stdout_discard => $bool

stderr_fh => $fh

stderr_discard => $bool

stderr_to_stdout => $bool

tty => $bool

See the open_ex method documentation for an explanation of these options.

$output = $ssh->capture(\%opts, @cmd);

@output = $ssh->capture(\%opts, @cmd);

This method is conceptually equivalent to the perl backquote operator (i.e. `ls`): it runs the command on the remote machine and captures its output.

In scalar context returns the output as a scalar. In list context returns the output broken into lines (it honors $/, see "$/" in perlvar).

When an error happens while capturing (for instance, the operation times out), the partial captured output will be returned. Error conditions have to be explicitly checked using the error method. For instance:

  my $output = $ssh->capture({ timeout => 10 },
                             "echo hello; sleep 20; echo bye");
  $ssh->error and
      warn "operation didn't complete successfully: ". $ssh->error;
  print $output;

Accepted options:

stdin_data => $input
stdin_data => \@input
timeout => $timeout: See the system method documentation for an explanation of these options.
stdin_fh => $fh
stdin_discard => $bool
stderr_fh => $fh
stderr_discard => $bool
stderr_to_stdout => $bool
tty => $bool: See the open_ex method documentation for an explanation of these options.

($output, $errput) = $ssh->capture2(\%opts, @cmd)

captures the output sent to both stdout and stderr by @cmd on the remote machine.

The accepted options are:

stdin_data => $input
stdin_data => \@input
timeout => $timeout: See the system method documentation for an explanation of these options.
stdin_fh => $fh
stdin_discard => $bool
tty => $bool: See the open_ex method documentation for an explanation of these options.

($in, $pid) = $ssh->pipe_in(\%opts, @cmd)

This method is similar to the following Perl open call

  $pid = open $in, '|-', @cmd

but running @cmd on the remote machine (see "open" in perlfunc).

No options are currently accepted.

There is no need to perform a waitpid on the returned PID as it will be done automatically by perl when $in is closed.

Example:

  my ($in, $pid) = $ssh->pipe_in('cat >/tmp/fpp')
      or die "pipe_in failed: " . $ssh->error;
  print $in $_ for @data;
  close $in or die "close failed";

($out, $pid) = $ssh->pipe_out(\%opts, @cmd)

Reciprocal to previous method, it is equivalent to

  $pid = open $out, '-|', @cmd

running @cmd on the remote machine.

No options are currently accepted.

($in, $out, $pid) = $ssh->open2(\%opts, @cmd)

($pty, $pid) = $ssh->open2pty(\%opts, @cmd)

($in, $out, $err, $pid) = $ssh->open3(\%opts, @cmd)

($pty, $err, $pid) = $ssh->open3pty(\%opts, @cmd)

Shortcuts around open_ex method.

$pid = $ssh->spawn(\%opts, @_)

Another open_ex shortcut, it launches a new remote process in the background and returns its PID.

For instance, you can run some command on several host in parallel with the following code:

  my %conn = map { $_ => Net::OpenSSH->new($_) } @hosts;
  my @pid;
  for my $host (@hosts) {
      open my($fh), '>', "/tmp/out-$host.txt"
        or die "unable to create file: $!;
      push @pid, $conn{$host}->spawn({stdout_fh => $fh}, $cmd);
  }

  waitpid($_, 0) for @pid;

$ssh->scp_get(\%opts, $remote1, $remote2,..., $local_dir_or_file)

$ssh->scp_put(\%opts, $local, $local2,..., $remote_dir_or_file)

These two methods are wrappers around the scp command that allow transfers of files to/from the remote host using the existing SSH master connection.

When transferring several files, the target argument must point to an existing directory. If only one file is to be transferred, the target argument can be a directory or a file name or can be ommited. For instance:

  $ssh->scp_get({glob => 1}, '/var/tmp/foo*', '/var/tmp/bar*', '/tmp');
  $ssh->scp_put('/etc/passwd');

Both scp_get and scp_put methods return a true value when all the files are transferred correctly, otherwise they return undef.

Accepted options:

quiet => 0

By default, scp is called with the quiet flag -q enabled in order to suppress progress information. This option allows reenabling the progress indication bar.

recursive => 1

Copy files and directories recursively.

glob => 1

Allow expansion of shell metacharacters in the sources list so that wildcards can be used to select files.

glob_flags => $flags

Second argument passed to File::Glob bsd_glob function. Only available for scp_put method.

copy_attrs => 1

Copies modification and access times and modes from the original files.

bwlimit => $Kbits

Limits the used bandwith, specified in Kbit/s.

async => 1

Doesn't wait for the scp command to finish. When this option is used, the method returns the PID of the child scp process.

For instance, it is possible to transfer files to several hosts in parallel as follows:

  use Errno;
  my (%pid, %ssh);
  for my $host (@hosts) {
    $ssh{$host} = Net::OpenSSH->new($host, async => 1);
  }
  for my $host (@hosts) {
    $pid{$host} = $ssh{$host}->scp_put({async => 1}, $local_fn, $remote_fn)
      or warn "scp_put to $host failed: " . $ssh{$host}->error . "\n";
  }
  for my $host (@hosts) {
    if (my $pid = $pid{$host}) {
      if (waitpit($pid, 0) > 0) {
        my $exit = ($? >> 8);
        $exit and warn "transfer of file to $host failed ($exit)\n";
      }
      else {
        redo if ($! == EINTR);
        warn "waitpid($pid) failed: $!\n";
      }
    }
  }

stdout_fh => $fh

stderr_fh => $fh

stderr_to_stdout => 1

These options are passed unchanged to method open_ex, allowing capture of the output of the scp program.

Note that scp will not generate progress reports unless its stdout stream is attached to a tty.

$ssh->rsync_get(\%opts, $remote1, $remote2,..., $local_dir_or_file)

$ssh->rsync_put(\%opts, $local1, $local2,..., $remote_dir_or_file)

These methods use rsync over SSH to transfer files from/to the remote machine.

They accept the same set of options as the SCP ones.

Any unrecognized option will be passed as an argument to the rsync command. Underscores can be used instead of dashes in rsync option names.

For instance:

  $ssh->rsync_get({exclude => '*~',
                   verbose => 1,
                   safe_links => 1},
                  '/remote/dir', '/local/dir');

$sftp = $ssh->sftp(%sftp_opts)

Creates a new Net::SFTP::Foreign object for SFTP interaction that runs through the ssh master connection.

@call = $ssh->make_remote_command(%opts, @cmd)

$call = $ssh->make_remote_command(\%opts, @cmd)

This method returns the arguments required to execute a command on the remote machine via SSH. For instance:

  my @call = $ssh->make_remote_command(ls => "/var/log");
  system @call;

In scalar context, returns the arguments quoted and joined into one string:

  my $remote = $ssh->make_remote_comand("cd /tmp/ && tar xf -");
  system "tar cf - . | $remote";

$ssh->wait_for_master($async)

When the connection has been established by calling the constructor with the async option, this call allows to advance the process.

If $async is true, it will perform any work that can be done inmediately without waiting (for instance, entering the password or checking for the existence of the multiplexing socket) and then return. If a false value is given, it will finalize the connection process and wait until the multiplexing socket is available.

It returns a true value after the connection has been succesfully established. False is returned if the connection process fails or if it has not yet completed ($ssh->error can be used to distinguish between those cases).

$ssh->shell_quote(@args)

Returns the list of arguments quoted so that they will be restored to their original form when parsed by the remote shell.

In scalar context returns the list of arguments quoted and joined.

Usually this task is done automatically by the module. See "Shell quoting" below.

$ssh->shell_quote_glob(@args)

This method is like the previous shell_quote but leaves wildcard characters unquoted.

Shell quoting

By default, when invoking remote commands, this module tries to mimic perl system builtin in regard to argument processing. Quoting "system" in perlfunc:

  Argument processing varies depending on the number of arguments.  If
  there is more than one argument in LIST, or if LIST is an array with
  more than one value, starts the program given by the first element
  of the list with arguments given by the rest of the list.  If there
  is only one scalar argument, the argument is checked for shell
  metacharacters, and if there are any, the entire argument is passed
  to the system's command shell for parsing (this is "/bin/sh -c" on
  Unix platforms, but varies on other platforms).

Take for example Net::OpenSSH system method:

  $ssh->system("ls -l *");
  $ssh->system('ls', '-l', '/');

The first call passes the argument unchanged to ssh, so that it is executed in the remote side through the shell which interprets shell metacharacters.

The second call escapes especial shell characters so that, effectively, it is equivalent to calling the command directly and not through the shell.

Under the hood, as the Secure Shell protocol does not provide for this mode of operation and always spawns a new shell where it runs the given command, Net::OpenSSH quotes any shell metacharacters in the comand list.

All the methods that invoke a remote command (system, open_ex, etc.) accept the option quote_args that allows to force/disable shell quoting.

For instance:

  $ssh->system({quote_args => 1}, "/path with spaces/bin/foo");

will correctly handle the spaces in the program path.

The shell quoting mechanism implements some extensions (for instance, performing redirections to /dev/null on the remote side) that can be dissabled with the option quote_args_extended:

  $ssh->system({ stderr_discard => 1,
                 quote_args => 1, quote_args_extended => 0 },
               @cmd);

The option quote_args can also be used to disable quoting when more than one argument is passed. For instance, to get some pattern expanded by the remote shell:

  $ssh->system({quote_args => 0}, 'ls', '-l', "/tmp/files_*.dat");

The method shell_quote can be used to selectively quote some arguments and leave others untouched:

  $ssh->system({quote_args => 0},
               $ssh->shell_quote('ls', '-l'),
               "/tmp/files_*.dat");

When the glob option is set in scp and rsync file transfer methods, an alternative quoting method that knows about file wildcards and passes them unquoted is used. The set of wildcards recognized currently is the one supported by bash(1).

As shell quoting is a tricky matter, I expect bugs to appear in this area. You can see how ssh is called, and the quoting used setting the corresponding debug flag:

  $Net::OpenSSH::debug |= 16;

Also, the current implementation expects a shell compatible with Unix sh in the remote side. It will not work if for instance, the remote machine runs Windows, VMS or it is a router.

I plan to add support for different quoting mechanisms in the future... if you need it now, just ask for it!!!

Troubleshooting

Usually, Net::OpenSSH works out of the box, but when it fails, some users have a hard time finding the root of the problem. This mini troubleshooting guide shows how to find it.

1 - check the error message

Add in your script, after the Net::OpenSSH constructor call, an error check:

  $ssh = Net::OpenSSH->new(...);
  $ssh->error and die "SSH connection failed: " . $ssh->error;

The error message will tell what has gone wrong.

2 - OpenSSH version

Ensure that you have a version of ssh recent enough:

  $ ssh -V
  OpenSSH_5.1p1 Debian-5, OpenSSL 0.9.8g 19 Oct 2007

OpenSSH version 4.1 was the first to support the multiplexing feature and is the minimal required by the module to work. I advise you to use the latest OpenSSH (currently 5.1) or at least a more recent version.

The ssh_cmd constructor option lets you select the ssh binary to use. For instance:

  $ssh = Net::OpenSSH->new($host,
                           ssh_cmd => "/opt/OpenSSH/5.1/bin/ssh")

3 - run ssh from the command line

Check you can connect to the remote host using the same parameters you are passing to Net::OpenSSH. In particular, ensure that you are running ssh as the same local user.

If you are running your script from a webserver, the user would probably be www, apache or something alike.

Common problems are:

Not having the remote host public key in the known_hosts file.
Wrong permissions for the ~/.ssh directory or its contents.
Incorrect settings for public key authentication.

4 - security checks on the multiplexing socket

Net::OpenSSH performs some security checks on the directory where the multiplexing socket is going to be placed to ensure that it can not be accessed by other users.

The default location for the multiplexing socket is under ~/.libnet-openssh-perl. It can be changed using the ctl_dir and ctl_path constructor arguments.

The requirements for that directory and all its parents are:

They have to be owned by the user executing the script or by root
Their permission masks have to be 0755 or more restrictive, so nobody else has permissions to perform write operations on them.

The constructor option strict_mode disables these security checks, but you should not use it unless you understand its implications.

BUGS AND SUPPORT

SCP and rsync file transfer support is still highly experimental.

Does not work on Windows. OpenSSH multiplexing feature requires passing file handles through sockets but that is not supported by Windows.

Doesn't work on VMS either... well, actually, it probably doesn't work on anything not resembling a modern Linux/Unix OS.

Tested on Linux and NetBSD with OpenSSH 5.1p1

To report bugs or give me some feedback, send an email to the address that appear below or use the CPAN bug tracking system at http://rt.cpan.org.

Post questions related to module usage in PerlMonks http://perlmoks.org/ (that I read frequently). This module is becoming increasingly popular and I am unable to cope with all the request for help I get by email!

TODO

- add expect method

- passphrase handling

- integrate with IPC::PerlSSH

- better timeout handling in system and capture methods

- add support for more target OSs (quoting, OpenVMS, Windows & others)

- add tests for scp and rsync methods

- make pipe_in and pipe_out methods open_ex based

- add scp_cat and similar methods

- write some kind of parallel queue manager module

Send your feature requests, ideas or any feedback, please!

COPYRIGHT AND LICENSE

This library is free software; you can redistribute it and/or modify it under the same terms as Perl itself, either Perl version 5.10.0 or, at your option, any later version of Perl 5 you may have available.

To install Net::OpenSSH, copy and paste the appropriate command in to your terminal.

cpanm

cpanm Net::OpenSSH

CPAN shell

perl -MCPAN -e shell
install Net::OpenSSH

For more information on module installation, please visit the detailed CPAN module installation guide.

	Global
`s`	Focus search bar
`?`	Bring up this help dialog

	GitHub
`g` `p`	Go to pull requests
`g` `i`	go to github issues (only if github is preferred repository)

	POD
`g` `a`	Go to author
`g` `c`	Go to changes
`g` `i`	Go to issues
`g` `d`	Go to dist
`g` `r`	Go to repository/SCM
`g` `s`	Go to source
`g` `b`	Go to file browse

	Search terms
module: (e.g. module:Plugin)
distribution: (e.g. distribution:Dancer auth)
author: (e.g. author:SONGMU Redis)
version: (e.g. version:1.00)

NAME

SYNOPSIS

DESCRIPTION

Under the hood

Net::OpenSSH Vs Net::SSH::.* modules

API

Error handling

Net::OpenSSH methods

Shell quoting

Troubleshooting

SEE ALSO

BUGS AND SUPPORT

TODO

COPYRIGHT AND LICENSE

Module Install Instructions