NAME

Mojo::IOLoop - Minimalistic reactor for non-blocking TCP clients and servers

SYNOPSIS

  use Mojo::IOLoop;

  # Listen on port 3000
  Mojo::IOLoop->listen(
    port    => 3000,
    on_read => sub {
      my ($loop, $id, $chunk) = @_;

      # Process input
      say $chunk;

      # Got some data, time to write
      $loop->write($id, 'HTTP/1.1 200 OK');
    }
  );

  # Connect to port 3000 with TLS activated
  my $id = Mojo::IOLoop->connect(
    address    => 'localhost',
    port       => 3000,
    tls        => 1,
    on_connect => sub {
      my ($loop, $id) = @_;

      # Write request
      $loop->write($id, "GET / HTTP/1.1\r\n\r\n");
    },
    on_read => sub {
      my ($loop, $id, $chunk) = @_;

      # Process input
      say $chunk;
    }
  );

  # Add a timer
  Mojo::IOLoop->timer(5 => sub {
    my $loop = shift;
    $loop->drop($id);
  });

  # Start and stop loop
  Mojo::IOLoop->start;
  Mojo::IOLoop->stop;

DESCRIPTION

Mojo::IOLoop is a very minimalistic reactor that has been reduced to the absolute minimal feature set required to build solid and scalable non-blocking TCP clients and servers.

Optional modules EV, IO::Socket::IP and IO::Socket::SSL are supported transparently and used if installed.

A TLS certificate and key are also built right in to make writing test servers as easy as possible. Also note that for convenience the PIPE signal will be set to IGNORE when Mojo::IOLoop is loaded.

ATTRIBUTES

Mojo::IOLoop implements the following attributes.

`client_class`

  my $class = $loop->client_class;
  $loop     = $loop->client_class('Mojo::IOLoop::Client');

Class to be used for performing non-blocking socket connections with the connect method, defaults to Mojo::IOLoop::Client. Note that this attribute is EXPERIMENTAL and might change without warning!

`connect_timeout`

  my $timeout = $loop->connect_timeout;
  $loop       = $loop->connect_timeout(5);

Maximum time in seconds a connection can take to be connected before being dropped, defaults to 3.

`iowatcher`

  my $watcher = $loop->iowatcher;
  $loop       = $loop->iowatcher(Mojo::IOWatcher->new);

Low level event watcher, usually a Mojo::IOWatcher or Mojo::IOWatcher::EV object. Note that this attribute is EXPERIMENTAL and might change without warning!

`cleanup_interval`

  my $interval = $loop->cleanup_interval;
  $loop        = $loop->cleanup_interval(1);

Connection cleanup interval in seconds, defaults to 0. Note that this attribute is EXPERIMENTAL and might change without warning!

`max_accepts`

  my $max = $loop->max_accepts;
  $loop   = $loop->max_accepts(1000);

The maximum number of connections this loop is allowed to accept before shutting down gracefully without interrupting existing connections, defaults to 0. Setting the value to 0 will allow this loop to accept new connections infinitely. Note that this attribute is EXPERIMENTAL and might change without warning!

`max_connections`

  my $max = $loop->max_connections;
  $loop   = $loop->max_connections(1000);

The maximum number of parallel connections this loop is allowed to handle before stopping to accept new incoming connections, defaults to 1000. Setting the value to 0 will make this loop stop accepting new connections and allow it to shutdown gracefully without interrupting existing connections.

`on_lock`

  my $cb = $loop->on_lock;
  $loop  = $loop->on_lock(sub {...});

A locking callback that decides if this loop is allowed to accept new incoming connections, used to sync multiple server processes. The callback should return true or false. Note that exceptions in this callback are not captured.

  $loop->on_lock(sub {
    my ($loop, $blocking) = @_;

    # Got the lock, listen for new connections
    return 1;
  });

`on_unlock`

  my $cb = $loop->on_unlock;
  $loop  = $loop->on_unlock(sub {...});

A callback to free the accept lock, used to sync multiple server processes. Note that exceptions in this callback are not captured.

`resolver`

  my $resolver = $loop->resolver;
  $loop        = $loop->resolver(Mojo::IOLoop::Resolver->new);

DNS stub resolver, usually a Mojo::IOLoop::Resolver object. Note that this attribute is EXPERIMENTAL and might change without warning!

`server_class`

  my $class = $loop->server_class;
  $loop     = $loop->server_class('Mojo::IOLoop::Server');

Class to be used for accepting incoming connections with the listen method, defaults to Mojo::IOLoop::Server. Note that this attribute is EXPERIMENTAL and might change without warning!

`stream_class`

  my $class = $loop->stream_class;
  $loop     = $loop->stream_class('Mojo::IOLoop::Stream');

Class to be used for streaming handles, defaults to Mojo::IOLoop::Stream. Note that this attribute is EXPERIMENTAL and might change without warning!

METHODS

Mojo::IOLoop inherits all methods from Mojo::Base and implements the following new ones.

`connect`

  my $id = Mojo::IOLoop->connect(
    address => '127.0.0.1',
    port    => 3000
  );
  my $id = $loop->connect(
    address => '127.0.0.1',
    port    => 3000
  );
  my $id = $loop->connect({
    address => '127.0.0.1',
    port    => 3000
  });

Open a TCP connection to a remote host. Note that TLS support depends on IO::Socket::SSL and IPv6 support on IO::Socket::IP.

These options are currently available:

address: Address or host name of the peer to connect to.
handle: Use an already prepared handle.
on_connect: Callback to be invoked once the connection is established.
on_close: Callback to be invoked if the connection gets closed.
on_error: Callback to be invoked if an error happens on the connection.
on_read: Callback to be invoked if new data arrives on the connection.
port: Port to connect to.
tls: Enable TLS.
tls_cert: Path to the TLS certificate file.
tls_key: Path to the TLS key file.

`connection_timeout`

  my $timeout = Mojo::IOLoop->connection_timeout($id);
  my $timeout = $loop->connection_timeout($id);
  $loop       = $loop->connection_timeout($id => 45);

Maximum amount of time in seconds a connection can be inactive before being dropped, defaults to 15.

`defer`

  Mojo::IOLoop->defer(sub {...});
  $loop->defer(sub {...});

Invoke callback on next reactor tick. Note that this method is EXPERIMENTAL and might change without warning!

`delay`

  my $delay = Mojo::IOLoop->delay;
  my $delay = $loop->delay;
  my $delay = $loop->delay(sub {...});

Get Mojo::IOLoop::Delay object to synchronize events. Note that this method is EXPERIMENTAL and might change without warning!

  # Synchronize multiple events
  my $delay = Mojo::IOLoop->delay(sub { say 'BOOM!' });
  for my $i (1 .. 10) {
    $delay->begin;
    Mojo::IOLoop->timer($i => sub {
      say 10 - $i;
      $delay->end;
    });
  }

  # Wait for events
  $delay->wait;

`drop`

  $loop = Mojo::IOLoop->drop($id)
  $loop = $loop->drop($id);

Drop anything with an id. Connections will be dropped gracefully by allowing them to finish writing all data in their write buffers.

`generate_port`

  my $port = Mojo::IOLoop->generate_port;
  my $port = $loop->generate_port;

Find a free TCP port, this is a utility function primarily used for tests.

`is_running`

  my $success = Mojo::IOLoop->is_running;
  my $success = $loop->is_running;

Check if loop is running.

  exit unless Mojo::IOLoop->is_running;

`listen`

  my $id = Mojo::IOLoop->listen(port => 3000);
  my $id = $loop->listen(port => 3000);
  my $id = $loop->listen({port => 3000});

Create a new listen socket. Note that TLS support depends on IO::Socket::SSL and IPv6 support on IO::Socket::IP.

These options are currently available:

address: Local address to listen on, defaults to all.
backlog: Maximum backlog size, defaults to SOMAXCONN.
on_accept: Callback to be invoked for each accepted connection.
on_close: Callback to be invoked if the connection gets closed.
on_error: Callback to be invoked if an error happens on the connection.
on_read: Callback to be invoked if new data arrives on the connection.
port: Port to listen on.
tls: Enable TLS.
tls_cert: Path to the TLS cert file, defaulting to a built-in test certificate.
tls_key: Path to the TLS key file, defaulting to a built-in test key.
tls_ca: Path to TLS certificate authority file or directory.

`local_info`

  my $info = $loop->local_info($id);

Get local information about a connection.

  my $address = $info->{address};

These values can be expected in the returned hash reference:

address: The local address.
port: The local port.

`on_close`

  $loop = $loop->on_close($id => sub {...});

Callback to be invoked if the connection gets closed.

`on_error`

  $loop = $loop->on_error($id => sub {...});

Callback to be invoked if an error happens on the connection.

`on_read`

  $loop = $loop->on_read($id => sub {...});

Callback to be invoked if new data arrives on the connection.

  $loop->on_read($id => sub {
    my ($loop, $id, $chunk) = @_;

    # Process chunk
  });

`one_tick`

  Mojo::IOLoop->one_tick;
  $loop->one_tick;
  $loop->one_tick('0.25');
  $loop->one_tick(0);

Run reactor for roughly one tick and try not to block longer than the given amount of time in seconds.

`recurring`

  my $id = Mojo::IOLoop->recurring(0 => sub {...});
  my $id = $loop->recurring(3 => sub {...});

Create a new recurring timer, invoking the callback repeatedly after a given amount of seconds. This for example allows you to run multiple reactors next to each other.

  my $loop2 = Mojo::IOLoop->new(timeout => 0);
  Mojo::IOLoop->recurring(0 => sub { $loop2->one_tick });

Note that the loop timeout can be changed dynamically at any time to adjust responsiveness.

`remote_info`

  my $info = $loop->remote_info($id);

Get remote information about a connection.

  my $address = $info->{address};

These values can be expected in the returned hash reference:

address: The remote address.
port: The remote port.

`singleton`

  my $loop = Mojo::IOLoop->singleton;

The global Mojo::IOLoop singleton, used to access a single shared loop instance from everywhere inside the process.

  # Many methods also allow you to take shortcuts
  Mojo::IOLoop->timer(2 => sub { Mojo::IOLoop->stop });
  Mojo::IOLoop->start;

`start`

  Mojo::IOLoop->start;
  $loop->start;

Start the loop, this will block until stop is called.

`start_tls`

  $loop->start_tls($id => (
    tls_cert => '/foo/client.cert',
    tls_key  => '/foo/client.key'
  ));
  $loop->start_tls($id => {
    tls_cert => '/foo/client.cert',
    tls_key  => '/foo/client.key'
  });

Start new TLS connection inside old connection. Note that TLS support depends on IO::Socket::SSL.

These options are currently available:

on_connect: Callback to be invoked once the connection is established.
on_close: Callback to be invoked if the connection gets closed.
on_error: Callback to be invoked if an error happens on the connection.
on_read: Callback to be invoked if new data arrives on the connection.
tls_cert: Path to the TLS certificate file.
tls_key: Path to the TLS key file.

`stop`

  Mojo::IOLoop->stop;
  $loop->stop;

Stop the loop immediately, this will not interrupt any existing connections and the loop can be restarted by running start again.

`stream`

  my $stream = Mojo::IOLoop->stream($id);
  my $stream = $loop->stream($id);
  my $id     = $loop->stream($stream, on_read => sub {...});
  my $id     = $loop->stream($stream, {on_read => sub {...}});

Get Mojo::IOLoop::Stream object for id or turn object into a connection. Note that this method is EXPERIMENTAL and might change without warning!

  my $stream = Mojo::IOLoop::Stream->new($handle);
  Mojo::IOLoop->stream($stream, on_read => sub {
    my ($loop, $id, $chunk) = @_;
    $loop->write($id => "echo: $chunk");
  });

These options are currently available:

on_close: Callback to be invoked if the connection gets closed.
on_error: Callback to be invoked if an error happens on the connection.
on_read: Callback to be invoked if new data arrives on the connection.

`test`

  my $success = $loop->test($id);

Test for errors and garbage bytes on the connection. Note that this method is EXPERIMENTAL and might change without warning!

`timer`

  my $id = Mojo::IOLoop->timer(5 => sub {...});
  my $id = $loop->timer(5 => sub {...});
  my $id = $loop->timer(0.25 => sub {...});

Create a new timer, invoking the callback after a given amount of seconds.

`write`

  $loop->write($id => 'Hello!');
  $loop->write($id => 'Hello!', sub {...});

Write data to connection, the optional drain callback will be invoked once all data has been written.

DEBUGGING

You can set the MOJO_IOLOOP_DEBUG environment variable to get some advanced diagnostics information printed to STDERR.

  MOJO_IOLOOP_DEBUG=1

	Global
`s`	Focus search bar
`?`	Bring up this help dialog

	GitHub
`g` `p`	Go to pull requests
`g` `i`	go to github issues (only if github is preferred repository)

	POD
`g` `a`	Go to author
`g` `c`	Go to changes
`g` `i`	Go to issues
`g` `d`	Go to dist
`g` `r`	Go to repository/SCM
`g` `s`	Go to source
`g` `b`	Go to file browse

	Search terms
module: (e.g. module:Plugin)
distribution: (e.g. distribution:Dancer auth)
author: (e.g. author:SONGMU Redis)
version: (e.g. version:1.00)

NAME

SYNOPSIS

DESCRIPTION

ATTRIBUTES

client_class

connect_timeout

iowatcher

cleanup_interval

max_accepts

max_connections

on_lock

on_unlock

resolver

server_class

stream_class

METHODS

connect

connection_timeout

defer

delay

drop

generate_port

is_running

listen

local_info

on_close

on_error

on_read

one_tick

recurring

remote_info

singleton

start

start_tls

stop

stream

test

timer

write

DEBUGGING

SEE ALSO

Module Install Instructions

`client_class`

`connect_timeout`

`iowatcher`

`cleanup_interval`

`max_accepts`

`max_connections`

`on_lock`

`on_unlock`

`resolver`

`server_class`

`stream_class`

`connect`

`connection_timeout`

`defer`

`delay`

`drop`

`generate_port`

`is_running`

`listen`

`local_info`

`on_close`

`on_error`

`on_read`

`one_tick`

`recurring`

`remote_info`

`singleton`

`start`

`start_tls`

`stop`

`stream`

`test`

`timer`

`write`