++ed by:
PERLANCAR DELON ARJONES SIMUL RICHE

122 PAUSE users
156 non-PAUSE users.

Sebastian Riedel

NAME

Mojo::Collection - Collection

SYNOPSIS

  # Manipulate collections
  use Mojo::Collection;
  my $collection = Mojo::Collection->new(qw(just works));
  unshift @$collection, 'it';
  $collection->map(sub { ucfirst })->each(sub {
    my ($word, $count) = @_;
    say "$count: $word";
  });

  # Use the alternative constructor
  use Mojo::Collection 'c';
  c(qw(a b c))->join('/')->url_escape->say;

DESCRIPTION

Mojo::Collection is a container for collections.

FUNCTIONS

Mojo::Collection implements the following functions.

c

  my $collection = c(1, 2, 3);

Construct a new array-based Mojo::Collection object.

METHODS

Mojo::Collection inherits all methods from Mojo::Base and implements the following new ones.

new

  my $collection = Mojo::Collection->new(1, 2, 3);

Construct a new array-based Mojo::Collection object.

each

  my @elements = $collection->each;
  $collection  = $collection->each(sub {...});

Evaluate callback for each element in collection. The element will be the first argument passed to the callback and is also available as $_.

  $collection->each(sub {
    my ($e, $count) = @_;
    say "$count: $e";
  });

first

  my $first = $collection->first;
  my $first = $collection->first(qr/foo/);
  my $first = $collection->first(sub {...});

Evaluate regular expression or callback for each element in collection and return the first one that matched the regular expression, or for which the callback returned true. The element will be the first argument passed to the callback and is also available as $_.

  my $five = $collection->first(sub { $_ == 5 });

grep

  my $new = $collection->grep(qr/foo/);
  my $new = $collection->grep(sub {...});

Evaluate regular expression or callback for each element in collection and create a new collection with all elements that matched the regular expression, or for which the callback returned true. The element will be the first argument passed to the callback and is also available as $_.

  my $interesting = $collection->grep(qr/mojo/i);

join

  my $stream = $collection->join("\n");

Turn collection into Mojo::ByteStream.

  $collection->join("\n")->say;

map

  my $new = $collection->map(sub {...});

Evaluate callback for each element in collection and create a new collection from the results. The element will be the first argument passed to the callback and is also available as $_.

  my $doubled = $collection->map(sub { $_ * 2 });

pluck

  my $new = $collection->pluck($method);
  my $new = $collection->pluck($method, @args);

Call method on each element in collection and create a new collection from the results.

  # Equal to but more convenient than
  my $new = $collection->map(sub { $_->$method(@args) });

reverse

  my $new = $collection->reverse;

Create a new collection with all elements in reverse order.

slice

  my $new = $collection->slice(4 .. 7);

Create a new collection with all selected elements.

shuffle

  my $new = $collection->shuffle;

Create a new collection with all elements in random order.

size

  my $size = $collection->size;

Number of elements in collection.

sort

  my $new = $collection->sort;
  my $new = $collection->sort(sub {...});

Sort elements based on return value of callback and create a new collection from the results.

  my $insensitive = $collection->sort(sub { uc(shift) cmp uc(shift) });

uniq

  my $new = $collection->uniq;

Create a new collection without duplicate elements.

ELEMENTS

Direct array reference access to elements is also possible.

  say $collection->[23];
  say for @$collection;

SEE ALSO

Mojolicious, Mojolicious::Guides, http://mojolicio.us.