NAME

ojo - Fun one-liners with Mojo!

SYNOPSIS

  $ perl -Mojo -E 'say g("mojolicio.us")->dom->at("title")->text'

DESCRIPTION

A collection of automatically exported functions for fun Perl one-liners. Ten redirects will be followed by default, you can change this behavior with the MOJO_MAX_REDIRECTS environment variable.

  $ MOJO_MAX_REDIRECTS=0 perl -Mojo -E 'say g("example.com")->code'

Proxy detection is enabled by default, but you can disable it with the MOJO_PROXY environment variable.

  $ MOJO_PROXY=0 perl -Mojo -E 'say g("example.com")->body'

Every ojo one-liner is also a Mojolicious::Lite application.

  $ perl -Mojo -E 'get "/" => {inline => "%= time"}; app->start' get /

FUNCTIONS

ojo implements the following functions, which are automatically exported.

a

  my $app = a('/hello' => sub { $_->render(json => {hello => 'world'}) });

Create a route with "any" in Mojolicious::Lite and return the current Mojolicious::Lite object. The current controller object is also available to actions as $_. See also the Mojolicious::Lite tutorial for more argument variations.

  $ perl -Mojo -E 'a("/hello" => {text => "Hello Mojo!"})->start' daemon

b

  my $stream = b('lalala');

Turn string into a Mojo::ByteStream object.

  $ perl -Mojo -E 'b(g("mojolicio.us")->body)->html_unescape->say'

c

  my $collection = c(1, 2, 3);

Turn list into a Mojo::Collection object.

d

  my $res = d('example.com');
  my $res = d('http://example.com' => {Accept => '*/*'} => 'Hi!');

Perform DELETE request with "delete" in Mojo::UserAgent and return resulting Mojo::Message::Response object.

g

  my $res = g('example.com');
  my $res = g('http://example.com' => {Accept => '*/*'} => 'Hi!');

Perform GET request with "get" in Mojo::UserAgent and return resulting Mojo::Message::Response object.

  $ perl -Mojo -E 'say g("mojolicio.us")->dom("h1, h2, h3")->text'

h

  my $res = h('example.com');
  my $res = h('http://example.com' => {Accept => '*/*'} => 'Hi!');

Perform HEAD request with "head" in Mojo::UserAgent and return resulting Mojo::Message::Response object.

j

  my $bytes = j([1, 2, 3]);
  my $bytes = j({foo => 'bar'});
  my $value = j($bytes);

Encode Perl data structure or decode JSON with "j" in Mojo::JSON.

  $ perl -Mojo -E 'b(j({hello => "world!"}))->spurt("hello.json")'

n

  n {...};
  n {...} 100;

Benchmark block and print the results to STDERR, with an optional number of iterations, which defaults to 1.

  $ perl -Mojo -E 'n { say g("mojolicio.us")->code }'

o

  my $res = o('example.com');
  my $res = o('http://example.com' => {Accept => '*/*'} => 'Hi!');

Perform OPTIONS request with "options" in Mojo::UserAgent and return resulting Mojo::Message::Response object.

p

  my $res = p('example.com');
  my $res = p('http://example.com' => {Accept => '*/*'} => 'Hi!');

Perform POST request with "post" in Mojo::UserAgent and return resulting Mojo::Message::Response object.

r

  my $perl = r({data => 'structure'});

Dump a Perl data structure with "dumper" in Mojo::Util.

  perl -Mojo -E 'say r(g("example.com")->headers->to_hash)'

t

  my $res = t('example.com');
  my $res = t('http://example.com' => {Accept => '*/*'} => 'Hi!');

Perform PATCH request with "patch" in Mojo::UserAgent and return resulting Mojo::Message::Response object.

u

  my $res = u('example.com');
  my $res = u('http://example.com' => {Accept => '*/*'} => 'Hi!');

Perform PUT request with "put" in Mojo::UserAgent and return resulting Mojo::Message::Response object.

x

  my $dom = x('<div>Hello!</div>');

Turn HTML/XML input into Mojo::DOM object.

  $ perl -Mojo -E 'say x(b("test.html")->slurp)->at("title")->text'

SEE ALSO

Mojolicious, Mojolicious::Guides, http://mojolicio.us.

cpanm Mojolicious

perl -MCPAN -e shell
install Mojolicious