++ed by:
ESABOL OALDERS HMA TINITA SYP
46 non-PAUSE users
Author image H.Merijn Brand
and 1 contributors

NAME

Text::CSV_XS - comma-separated values manipulation routines

SYNOPSIS

 use Text::CSV_XS;

 $csv = Text::CSV_XS->new ();          # create a new object
 $csv = Text::CSV_XS->new (\%attr);    # create a new object

 $status  = $csv->combine (@columns);  # combine columns into a string
 $line    = $csv->string ();           # get the combined string

 $status  = $csv->parse ($line);       # parse a CSV string into fields
 @columns = $csv->fields ();           # get the parsed fields

 $status       = $csv->status ();      # get the most recent status
 $bad_argument = $csv->error_input (); # get the most recent bad argument
 $diag         = $csv->error_diag ();  # if an error occured, explains WHY

 $status = $csv->print ($io, $colref); # Write an array of fields
                                       # immediately to a file $io
 $colref = $csv->getline ($io);        # Read a line from file $io,
                                       # parse it and return an array
                                       # ref of fields
 $eof = $csv->eof ();                  # Indicate if last parse or
                                       # getline () hit End Of File

 $csv->types (\@t_array);              # Set column types

DESCRIPTION

Text::CSV_XS provides facilities for the composition and decomposition of comma-separated values. An instance of the Text::CSV_XS class can combine fields into a CSV string and parse a CSV string into fields.

The module accepts either strings or files as input and can utilize any user-specified characters as delimiters, separators, and escapes so it is perhaps better called ASV (anything separated values) rather than just CSV.

Embedded newlines

Important Note: The default behavior is to only accept ascii characters. This means that fields can not contain newlines. If your data contains newlines embedded in fields, or characters above 0x7e (tilde), or binary data, you *must* set binary => 1 in the call to new (). To cover the widest range of parsing options, you will always want to set binary.

But you still have the problem that you have to pass a correct line to the parse () method, which is more complicated from the usual point of usage:

 my $csv = Text::CSV_XS->new ({ binary => 1, eol => $/ });
 while (<>) {           #  WRONG!
     $csv->parse ($_);
     my @fields = $csv->fields ();

will break, as the while might read broken lines, as that doesn't care about the quoting. If you need to support embedded newlines, the way to go is either

 use IO::Handle;
 my $csv = Text::CSV_XS->new ({ binary => 1, eol => $/ });
 while (my $row = $csv->getline (*ARGV)) {
     my @fields = @$row;

or, more safely in perl 5.6 and up

 my $csv = Text::CSV_XS->new ({ binary => 1, eol => $/ });
 open my $io, "<", $file or die "$file: $!";
 while (my $row = $csv->getline ($io)) {
     my @fields = @$row;
 

SPECIFICATION

While no formal specification for CSV exists, RFC 4180 1) describes a common format and establishes "text/csv" as the MIME type registered with the IANA.

Many informal documents exist that describe the CSV format. How To: The Comma Separated Value (CSV) File Format 2) provides an overview of the CSV format in the most widely used applications and explains how it can best be used and supported.

 1) http://tools.ietf.org/html/rfc4180
 2) http://www.creativyst.com/Doc/Articles/CSV/CSV01.htm

The basic rules are as follows:

CSV is a delimited data format that has fields/columns separated by the comma character and records/rows separated by newlines. Fields that contain a special character (comma, newline, or double quote), must be enclosed in double quotes. However, if a line contains a single entry which is the empty string, it may be enclosed in double quotes. If a field's value contains a double quote character it is escaped by placing another double quote character next to it. The CSV file format does not require a specific character encoding, byte order, or line terminator format.

  • Each record is one line terminated by a line feed (ASCII/LF=0x0A) or a carriage return and line feed pair (ASCII/CRLF=0x0D 0x0A), however, line-breaks can be embedded.

  • Fields are separated by commas.

  • Allowable characters within a CSV field include 0x09 (tab) and the inclusive range of 0x20 (space) through 0x7E (tilde). In binary mode all characters are accepted, at least in quoted fields.

  • A field within CSV must be surrounded by double-quotes to contain a the separator character (comma).

Though this is the most clear and restrictive definition, Text::CSV_XS is way more liberal than this, and allows extension:

  • Line termination by a single carriage return is accepted by default

  • The separation-, escape-, and escape- characters can be any ASCII character in the range from 0x20 (space) to 0x7E (tilde). Characters outside this range may or may not work as expected. Multibyte characters, like U+060c (ARABIC COMMA), U+FF0C (FULLWIDTH COMMA), U+241B (SYMBOL FOR ESCAPE), U+2424 (SYMBOL FOR NEWLINE), U+FF02 (FULLWIDTH QUOTATION MARK), and U+201C (LEFT DOUBLE QUOTATION MARK) (to give some examples of what might look promising) are therefor not allowed.

  • A field within CSV must be surrounded by double-quotes to contain an embedded double-quote, represented by a pair of consecutive double-quotes. In binary mode you may additionally use the sequence "0 for representation of a NULL byte.

  • Several violations of the above specification may be allowed by passing options to the object creator.

FUNCTIONS

version ()

(Class method) Returns the current module version.

new (\%attr)

(Class method) Returns a new instance of Text::CSV_XS. The objects attributes are described by the (optional) hash ref \%attr. Currently the following attributes are available:

eol

An end-of-line string to add to rows, usually undef (nothing, default), "\012" (Line Feed) or "\015\012" (Carriage Return, Line Feed). Cannot be longer than 7 (ASCII) characters.

If both $/ and eol equal "\015", parsing lines that end on only a Carriage Return without Line Feed, will be parsed correct. Line endings, whether in $/ or eol, other than undef, "\n", "\r\n", or "\r" are not (yet) supported for parsing.

sep_char

The char used for separating fields, by default a comma. (,). Limited to a single-byte character, usually in the range from 0x20 (space) to 0x7e (tilde).

The separation character can not be equal to the quote character. The separation character can not be equal to the escape character.

allow_whitespace

When this option is set to true, whitespace (TAB's and SPACE's) surrounding the separation character is removed when parsing. So lines like:

  1 , "foo" , bar , 3 , zapp

are now correctly parsed, even though it violates the CSV specs. Note that all whitespace is stripped from start and end of each field. That would make is more a feature than a way to be able to parse bad CSV lines, as

 1,   2.0,  3,   ape  , monkey

will now be parsed as

 ("1", "2.0", "3", "ape", "monkey")

even if the original line was perfectly sane CSV.

quote_char

The char used for quoting fields containing blanks, by default the double quote character ("). A value of undef suppresses quote chars. (For simple cases only). Limited to a single-byte character, usually in the range from 0x20 (space) to 0x7e (tilde).

The quote character can not be equal to the separation character.

allow_loose_quotes

By default, parsing fields that have quote_char characters inside an unquoted field, like

 1,foo "bar" baz,42

would result in a parse error. Though it is still bad practice to allow this format, we cannot help there are some vendors that make their applications spit out lines styled like this.

escape_char

The character used for escaping certain characters inside quoted fields. Limited to a single-byte character, usually in the range from 0x20 (space) to 0x7e (tilde).

The escape_char defaults to being the literal double-quote mark (") in other words, the same as the default quote_char. This means that doubling the quote mark in a field escapes it:

  "foo","bar","Escape ""quote mark"" with two ""quote marks""","baz"

If you change the default quote_char without changing the default escape_char, the escape_char will still be the quote mark. If instead you want to escape the quote_char by doubling it, you will need to change the escape_char to be the same as what you changed the quote_char to.

The escape character can not be equal to the separation character.

allow_loose_escapes

By default, parsing fields that have escape_char characters that escape characters that do not need to be escaped, like:

 my $csv = Text::CSV_XS->new ({ escape_char => "\\" });
 $csv->parse (qq{1,"my bar\'s",baz,42});

would result in a parse error. Though it is still bad practice to allow this format, this option enables you to treat all escape character sequences equal.

binary

If this attribute is TRUE, you may use binary characters in quoted fields, including line feeds, carriage returns and NULL bytes. (The latter must be escaped as "0.) By default this feature is off.

types

A set of column types; this attribute is immediately passed to the types method below. You must not set this attribute otherwise, except for using the types method. For details see the description of the types method below.

always_quote

By default the generated fields are quoted only, if they need to, for example, if they contain the separator. If you set this attribute to a TRUE value, then all fields will be quoted. This is typically easier to handle in external applications. (Poor creatures who aren't using Text::CSV_XS. :-)

keep_meta_info

By default, the parsing of input lines is as simple and fast as possible. However, some parsing information - like quotation of the original field - is lost in that process. Set this flag to true to be able to retrieve that information after parsing with the methods meta_info (), is_quoted (), and is_binary () described below. Default is false.

verbatim

This is a quite controversial attribute to set, but it makes hard things possible.

The basic thought behind this is to tell the parser that the normally special characters newline (NL) and Carriage Return (CR) will not be special when this flag is set, and be dealt with as being ordinary binary characters. This will ease working with data with embedded newlines.

When verbatim is used with getline (), getline auto-chomp's every line.

Imagine a file format like

  M^^Hans^Janssen^Klas 2\n2A^Ja^11-06-2007#\r\n

where, the line ending is a very specific "#\r\n", and the sep_char is a ^ (caret). None of the fields is quoted, but embedded binary data is likely to be present. With the specific line ending, that shouldn't be too hard to detect.

By default, Text::CSV_XS' parse function however is instructed to only know about "\n" and "\r" to be legal line endings, and so has to deal with the embedded newline as a real end-of-line, so it can scan the next line if binary is true, and the newline is inside a quoted field. With this attribute however, we can tell parse () to parse the line as if \n is just nothing more than a binary character.

For parse () this means that the parser has no idea about line ending anymore, and getline () chomps line endings on reading.

To sum it up,

 $csv = Text::CSV_XS->new ();

is equivalent to

 $csv = Text::CSV_XS->new ({
     quote_char          => '"',
     escape_char         => '"',
     sep_char            => ',',
     eol                 => '',
     always_quote        => 0,
     binary              => 0,
     keep_meta_info      => 0,
     allow_loose_quotes  => 0,
     allow_loose_escapes => 0,
     allow_whitespace    => 0,
     verbatim            => 0,
     });

For all of the above mentioned flags, there is an accessor method available where you can inquire for the current value, or change the value

 my $quote = $csv->quote_char;
 $csv->binary (1);

It is unwise to change these settings halfway through writing CSV data to a stream. If however, you want to create a new stream using the available CSV object, there is no harm in changing them.

combine
 $status = $csv->combine (@columns);

This object function constructs a CSV string from the arguments, returning success or failure. Failure can result from lack of arguments or an argument containing an invalid character. Upon success, string () can be called to retrieve the resultant CSV string. Upon failure, the value returned by string () is undefined and error_input () can be called to retrieve an invalid argument.

print
 $status = $csv->print ($io, $colref);

Similar to combine, but it expects an array ref as input (not an array!) and the resulting string is not really created, but immediately written to the $io object, typically an IO handle or any other object that offers a print method. Note, this implies that the following is wrong:

 open FILE, ">", "whatever";
 $status = $csv->print (\*FILE, $colref);

The glob \*FILE is not an object, thus it doesn't have a print method. The solution is to use an IO::File object or to hide the glob behind an IO::Wrap object. See IO::File(3) and IO::Wrap(3) for details.

For performance reasons the print method doesn't create a result string. In particular the $csv->string (), $csv->status (), $csv-fields ()> and $csv->error_input () methods are meaningless after executing this method.

string
 $line = $csv->string ();

This object function returns the input to parse () or the resultant CSV string of combine (), whichever was called more recently.

parse
 $status = $csv->parse ($line);

This object function decomposes a CSV string into fields, returning success or failure. Failure can result from a lack of argument or the given CSV string is improperly formatted. Upon success, fields () can be called to retrieve the decomposed fields . Upon failure, the value returned by fields () is undefined and error_input () can be called to retrieve the invalid argument.

You may use the types () method for setting column types. See the description below.

getline
 $colref = $csv->getline ($io);

This is the counterpart to print, like parse is the counterpart to combine: It reads a row from the IO object $io using $io->getline () and parses this row into an array ref. This array ref is returned by the function or undef for failure.

The $csv->string (), $csv->fields () and $csv->status () methods are meaningless, again.

eof
 $eof = $csv->eof ();

If parse () or getline () was used with an IO stream, this method will return true (1) if the last call hit end of file, otherwise it will return false (''). This is useful to see the difference between a failure and end of file.

types
 $csv->types (\@tref);

This method is used to force that columns are of a given type. For example, if you have an integer column, two double columns and a string column, then you might do a

 $csv->types ([Text::CSV_XS::IV (),
               Text::CSV_XS::NV (),
               Text::CSV_XS::NV (),
               Text::CSV_XS::PV ()]);

Column types are used only for decoding columns, in other words by the parse () and getline () methods.

You can unset column types by doing a

 $csv->types (undef);

or fetch the current type settings with

 $types = $csv->types ();
IV

Set field type to integer.

NV

Set field type to numeric/float.

PV

Set field type to string.

fields
 @columns = $csv->fields ();

This object function returns the input to combine () or the resultant decomposed fields of parse (), whichever was called more recently.

meta_info
 @flags = $csv->meta_info ();

This object function returns the flags of the input to combine () or the flags of the resultant decomposed fields of parse (), whichever was called more recently.

For each field, a meta_info field will hold flags that tell something about the field returned by the fields () method or passed to the combine () method. The flags are bitwise-or'd like:

0x0001

The field was quoted.

0x0002

The field was binary.

See the is_*** () methods below.

is_quoted
  my $quoted = $csv->is_quoted ($column_idx);

Where $column_idx is the (zero-based) index of the column in the last result of parse ().

This returns a true value if the data in the indicated column was enclosed in quote_char quotes. This might be important for data where ,20070108, is to be treated as a numeric value, and where ,"20070108", is explicitly marked as character string data.

is_binary
  my $binary = $csv->is_binary ($column_idx);

Where $column_idx is the (zero-based) index of the column in the last result of parse ().

This returns a true value if the data in the indicated column contained any byte in the range [\x00-\x08,\x10-\x1F,\x7F-\xFF]

status
 $status = $csv->status ();

This object function returns success (or failure) of combine () or parse (), whichever was called more recently.

error_input
 $bad_argument = $csv->error_input ();

This object function returns the erroneous argument (if it exists) of combine () or parse (), whichever was called more recently.

error_diag
 $csv->error_diag ();
 $error_code  = 0  + $csv->error_diag ();
 $error_str   = "" . $csv->error_diag ();
 ($cde, $str) =      $csv->error_diag ();

If (and only if) an error occured, this function returns the diagnostics of that error.

If called in void context, it will print the internal error code and the associated error message to STDERR.

If called in list context, it will return the error code and the error message in that order.

If called in scalar context, it will return the diagnostics in a single scalar, a-la $!. It will contain the error code in numeric context, and the diagnostics message in string context.

INTERNALS

Combine (...)
Parse (...)

The arguments to these two internal functions are deliberately not described or documented to enable the module author(s) to change it when they feel the need for it and using them is highly discouraged as the API may change in future releases.

EXAMPLES

An example for creating CSV files:

  use Text::CSV_XS;

  my $csv = Text::CSV_XS->new;

  open my $csv_fh, ">", "hello.csv" or die "hello.csv: $!";

  my @sample_input_fields = (
      'You said, "Hello!"',   5.67,
      '"Surely"',   '',   '3.14159');
  if ($csv->combine (@sample_input_fields)) {
      my $string = $csv->string;
      print $csv_fh "$string\n";
      }
  else {
      my $err = $csv->error_input;
      print "combine () failed on argument: ", $err, "\n";
      }
  close $csv_fh;

An example for parsing CSV lines:

  use Text::CSV_XS;

  my $csv = Text::CSV_XS->new ({ keep_meta_info => 1, binary => 1 });

  my $sample_input_string =
      qq{"I said, ""Hi!""",Yes,"",2.34,,"1.09","\x{20ac}",};
  if ($csv->parse ($sample_input_string)) {
      my @field = $csv->fields;
      foreach my $col (0 .. $#field) {
          my $quo = $csv->is_quoted ($col) ? $csv->{quote_char} : "";
          printf "%2d: %s%s%s\n", $col, $quo, $field[$col], $quo;
          }
      }
  else {
      my $err = $csv->error_input;
      print STDERR "parse () failed on argument: ", $err, "\n";
      $csv->error_diag ();
      }

TODO

More Errors & Warnings

At current, it is hard to tell where or why an error occured (if at all). New extensions ought to be clear and concise in reporting what error occurred where and why, and possibly also tell a remedy to the problem. error_diag is a (very) good start, but there is more work to be done here.

Basic calls should croak or warn on illegal parameters. Errors should be documented.

If ->new () fails, there should be a way to obtain the reason why. Currently it is almost impossible to make new () fail, but in the future there should be a (default) option to have it fail when unsupported options are passed.

eol

Discuss an option to make the eol honor the $/ setting. Maybe

  my $csv = Text::CSV_XS->new ({ eol => $/ });

is already enough, and new options only make things less opaque.

setting meta info

Future extensions might include extending the meta_info (), is_quoted (), and is_binary () to accept setting these flags for fields, so you can specify which fields are quoted in the combine ()/string () combination.

  $csv->meta_info (0, 1, 1, 3, 0, 0);
  $csv->is_quoted (3, 1);
parse returning undefined fields

Adding an option that enables the parser to distinguish between empty fields and undefined fields, like

  $csv->always_quote (1);
  $csv->allow_undef (1);
  $csv->parse (qq{,"",1,"2",,""});
  my @fld = $csv->fields ();

Then would return (undef, "", "1", "2", undef, "") in @fld, instead of the current ("", "", "1", "2", "", "").

combined methods

Requests for adding means (methods) that combine combine () and string () in a single call will not be honored. Likewise for parse () and fields (). Given the trouble with embedded newlines, using getline () and print () instead is the prefered way to go.

Unicode

Make parse () and combine () do the right thing for Unicode (UTF-8) if requested. See t/50_utf8.t. More complicated, but evenly important, also for getline () and print ().

Probably the best way to do this is to make a subclass Text::CSV_XS::Encoded that can be passed the required encoding and then behaves transparently (but slower).

Double double quotes

There seem to be applications around that write their dates like

   1,4,""12/11/2004"",4,1

If we would support that, probably through allow_double_quoted Definitely belongs in t/65_allow.t

Parse the whole file at once

Implement a new methods that enables the parsing of a complete file at once, returning a lis of hashes. Possible extension to this could be to enable a column selection on the call:

   my @AoH = $csv->parse_file ($filename, { cols => [ 1, 4..8, 12 ]});

Returning something like

   [ { fields => [ 1, 2, "foo", 4.5, undef, "", 8 ],
       flags  => [ ... ],
       errors => [ ... ],
       },
     { fields => [ ... ],
       .
       .
       },
     ]
EBCDIC

The hard-coding of characters and character ranges makes this module unusable on EBCDIC system. Using some #ifdef structure could enable these again without loosing speed. Testing would be the hard part.

Release plan

No guarantees, but this is what I have in mind right now:

0.33
 - croak / carp
 - error cause for failing new ()
 - return undef
 - DIAGNOSTICS setction in pod to *describe* the errors (see below)
0.34
 - allow_double_quoted
 - Text::CSV_XS::Encoded (maybe)
0.35
 - csv2csv - a script to regenerate a CSV file to follow standards
 - EBCDIC support

DIAGNOSTICS

Still under construction ...

If an error occured, $csv->error_diag () can be used to get more information on the cause of the failure. Note that for speed reasons, the internal value is never cleared on success, so using the value returned by error_diag () in normal cases - when no error occured - may cause unexpected results.

Currently these errors are available:

1001 "sep_char is equal to quote_char or escape_char"
2010 "ECR - QUO char inside quotes followed by CR not part of EOL"
2011 "ECR - Characters after end of quoted field"
2012 "EOF - End of data in parsing input stream"
2021 "EIQ - NL char inside quotes, binary off"
2022 "EIQ - CR char inside quotes, binary off"
2023 "EIQ - QUO ..."
2024 "EIQ - EOF cannot be escaped, not even inside quotes"
2025 "EIQ - Loose unescaped escape"
2026 "EIQ - Binary character inside quoted field, binary off"
2027 "EIQ - Quoted field not terminated"
2030 "EIF - NL char inside unquoted verbatim, binary off"
2031 "EIF - CR char is first char of field, not part of EOL"
2032 "EIF - CR char inside unquoted, not part of EOL"
2033 "EIF - QUO, QUO != ESC, binary off"
2034 "EIF - Loose unescaped quote"
2035 "EIF - Escaped EOF in unquoted field"
2036 "EIF - ESC error"
2037 "EIF - Binary character in unquoted field, binary off"
2110 "ECB - Binary character in Combine, binary off"

SEE ALSO

perl(1), IO::File(3), L{IO::Handle(3)>, IO::Wrap(3), Text::CSV(3), Text::CSV_PP(3). and Spreadsheet::Read(3).

AUTHORS and MAINTAINERS

Alan Citterman <alan@mfgrtl.com> wrote the original Perl module. Please don't send mail concerning Text::CSV_XS to Alan, as he's not involved in the C part which is now the main part of the module.

Jochen Wiedmann <joe@ispsoft.de> rewrote the encoding and decoding in C by implementing a simple finite-state machine and added the variable quote, escape and separator characters, the binary mode and the print and getline methods. See ChangeLog releases 0.10 through 0.23.

H.Merijn Brand <h.m.brand@xs4all.nl> cleaned up the code, added the field flags methods, wrote the major part of the test suite, completed the documentation, fixed some RT bugs. See ChangeLog releases 0.25 and on.

COPYRIGHT AND LICENSE

Copyright (C) 2007-2008 H.Merijn Brand for PROCURA B.V. Copyright (C) 1998-2001 Jochen Wiedmann. All rights reserved. Portions Copyright (C) 1997 Alan Citterman. All rights reserved.

This library is free software; you can redistribute it and/or modify it under the same terms as Perl itself.