AKHUETTEL / Lab-Measurement-3.930 / t / 00-load.t 

            

              
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122

              
#!perl
# Check that our perl modules compile without error.
use 5.010;
use strict;
use warnings;
use File::Find;
use Module::Load;
use Test::More;
use File::Spec::Functions 'abs2rel';
# Create file list
my @files;
sub installed {
    my $module = shift;
    eval {
        autoload $module;
        1;
    } or return;
    return 1;
}
File::Find::find(
    {
        wanted => sub { -f $_ && /\.pm$/ and push @files, $_ },
        no_chdir => 1
    },
    'lib'
);
@files = map { abs2rel( $_, 'lib' ) } @files;
# Do not keep backslashes in filenames, as they confuse require:
# perl uses slashes in %INC for modules which are 'used'.
# With backslashes the same module could be loaded twice.
@files = map {s(\\)(/)gr} @files;
# Skip modules with special dependencies.
sub skip_modules {
    my @to_be_skipped = @_;
    for my $skip (@to_be_skipped) {
        @files = grep {
            my $file = $_;
            index( $file, $skip ) == -1;
        } @files;
    }
}
# this module is designed to fail
skip_modules('Lab/Measurement.pm');
diag("checking installed modules");
my %depencencies = (
    #    'PDL' => ['Lab/Data/PDL.pm'],
    'PDL::Graphics::Gnuplot' => [
        qw{
            Lab/Moose/Plot.pm
            Lab/Moose/DataFile/Gnuplot.pm
            Lab/Moose/Instrument/DisplayXY.pm
            Lab/Moose/Instrument/SpectrumAnalyzer.pm
            Lab/Moose/Instrument/HP8596E.pm
            Lab/Moose/Instrument/Rigol_DSA815.pm
            Lab/Moose/Instrument/HPE4400B.pm
            }
    ],
    'PDL::IO::CSV'        => ['Lab/Moose/Instrument/NanonisTramea.pm'],
    'Math::Round' => ['Lab/Moose/Instrument/Rigol_DG5000.pm'],
    'LinuxGpib' => ['LinuxGPIB'],
    'Lab::VISA' => [
        qw{
            VISA
            Lab/Moose/Connection/VISA
            }
    ],
    'Lab::Zhinst' => ['Zhinst'],
    'Lab::VXI11' => ['Moose/Connection/VXI11.pm'],
    'USB::TMC' => ['Moose/Connection/USB.pm'],
);
for my $module ( keys %depencencies ) {
    if ( installed($module) ) {
        diag("using $module");
    }
    else {
        diag("not using $module");
        skip_modules( @{ $depencencies{$module} } );
    }
}
eval {
    load 'sys/ioctl.ph';
    diag("using sys/ioctl.ph");
    load 'linux/usb/tmc.ph';
    diag("using linux/usb/tmc.ph");
    1;
} or do {
    diag("not using sys/ioctl.ph");
    diag("not using linux/usb/tmc.ph");
    skip_modules('Lab/Bus/USBtmc.pm');
};
plan tests => scalar @files;
for my $file (@files) {
    diag("trying to load $file ...");
    is( require $file, 1, "load $file" );
}