The Perl and Raku Conference 2025: Greenville, South Carolina - June 27-29 Learn more

BAREFOOT / Date-Easy-0.01_01-TRIAL / lib / Date / Easy / Datetime.pm 

            

              
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
—
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145

              
package Date::Easy::Datetime;
use strict;
use warnings;
use autodie;
our $VERSION = '0.01_01'; # TRIAL VERSION
use Exporter;
use parent 'Exporter';
our @EXPORT_OK = qw< datetime now >;
our %EXPORT_TAGS = ( all => \@EXPORT_OK );
use parent 'Time::Piece';
use Carp;
use Time::Local;
# this can be modified (preferably using `local`) to use GMT/UTC as the default
# or you can pass a value to `import` via your `use` line
our $DEFAULT_ZONE = 'local';
my %ZONE_FLAG = ( local => 1, UTC => 0, GMT => 0 );
sub import
{
        my @args;
        exists $ZONE_FLAG{$_} ? $DEFAULT_ZONE = $_ : push @args, $_ foreach @_;
        @_ = @args;
        goto &Exporter::import;
}
##############################
# FUNCTIONS (*NOT* METHODS!) #
##############################
sub datetime
{
        my $zonespec = @_ % 2 == 0 ? shift : $DEFAULT_ZONE;
        my $datetime = shift;
        if ( $datetime =~ /^-?\d+$/ )
        {
                return Date::Easy::Datetime->new($zonespec, $datetime);
        }
        else
        {
                my $t = _str2time($datetime, $zonespec);
                $t = _parsedate($datetime, $zonespec) unless defined $t;
                croak("Illegal datetime: $datetime") unless defined $t;
                return Date::Easy::Datetime->new( $zonespec, $t );
        }
        die("reached unreachable code");
}
sub now () { Date::Easy::Datetime->new }
sub _str2time
{
        require Date::Parse;
        my ($time, $zone) = @_;
        return Date::Parse::str2time($time, $zone eq 'local' ? () : $zone);
}
sub _parsedate
{
        require Time::ParseDate;
        my ($time, $zone) = @_;
        return scalar Time::ParseDate::parsedate($time, $zone eq 'local' ? () : (GMT => 1));
}
#######################
# REGULAR CLASS STUFF #
#######################
sub new
{
        my $class = shift;
        my $zonespec = @_ == 2 || @_ == 7 ? shift : $DEFAULT_ZONE;
        croak("Unrecognized timezone specifier") unless exists $ZONE_FLAG{$zonespec};
        my $t;
        if (@_ == 0)
        {
                $t = time;
        }
        elsif (@_ == 6)
        {
                my ($y, $m, $d, $H, $M, $S) = @_;
                --$m;                                                                           # timelocal/timegm will expect month as 0..11
                $t = $zonespec eq 'local' ? timelocal($S, $M, $H, $d, $m, $y) : timegm($S, $M, $H, $d, $m, $y);
        }
        elsif (@_ == 1)
        {
                $t = shift;
        }
        else
        {
                croak("Illegal number of arguments to datetime()");
        }
        return scalar $class->_mktime($t, $ZONE_FLAG{$zonespec});
}
sub is_local {  shift->[Time::Piece::c_islocal] }
sub is_gmt   { !shift->[Time::Piece::c_islocal] }
*is_utc = \&is_gmt;
1;
# ABSTRACT: easy datetime class
# COPYRIGHT
__END__
=pod
=head1 NAME
Date::Easy::Datetime - easy datetime class
=head1 VERSION
This document describes version 0.01_01 of Date::Easy::Datetime.
=head1 AUTHOR
Buddy Burden <barefootcoder@gmail.com>
=head1 COPYRIGHT AND LICENSE
This software is Copyright (c) 2016 by Buddy Burden.
This is free software, licensed under:
  The Artistic License 2.0 (GPL Compatible)
=cut