The Perl and Raku Conference 2025: Greenville, South Carolina - June 27-29 Learn more

ELLIOTJS / Perl-Critic-1.095_001 / lib / Perl / Critic / Policy / InputOutput / ProhibitBacktickOperators.pm 

            

              
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
—
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153

              
##############################################################################
#      $URL: http://perlcritic.tigris.org/svn/perlcritic/trunk/distributions/Perl-Critic/lib/Perl/Critic/Policy/InputOutput/ProhibitBacktickOperators.pm $
#     $Date: 2009-01-18 17:32:26 -0600 (Sun, 18 Jan 2009) $
#   $Author: clonezone $
# $Revision: 3007 $
##############################################################################
package Perl::Critic::Policy::InputOutput::ProhibitBacktickOperators;
use 5.006001;
use strict;
use warnings;
use Readonly;
use Perl::Critic::Utils qw{ :severities is_in_void_context };
use base 'Perl::Critic::Policy';
our $VERSION = '1.095_001';
#-----------------------------------------------------------------------------
Readonly::Scalar my $EXPL => q{Use IPC::Open3 instead};
Readonly::Scalar my $DESC => q{Backtick operator used};
Readonly::Scalar my $VOID_EXPL => q{Assign result to a variable or use system() instead};
Readonly::Scalar my $VOID_DESC => q{Backtick operator used in void context};
#-----------------------------------------------------------------------------
sub supported_parameters {
    return (
        {
            name        => 'only_in_void_context',
            description => 'Allow backticks everywhere except in void contexts.',
            behavior    => 'boolean',
        },
    );
}
sub default_severity { return $SEVERITY_MEDIUM }
sub default_themes   { return qw(core maintenance)   }
sub applies_to       { return qw(PPI::Token::QuoteLike::Backtick
                                 PPI::Token::QuoteLike::Command ) }
#-----------------------------------------------------------------------------
sub violates {
    my ( $self, $elem, undef ) = @_;
    if ( $self->{_only_in_void_context} ) {
        return if not is_in_void_context( $elem );
        return $self->violation( $VOID_DESC, $VOID_EXPL, $elem );
    }
    return $self->violation( $DESC, $EXPL, $elem );
}
1;
__END__
#-----------------------------------------------------------------------------
=pod
=for stopwords perlipc
=head1 NAME
Perl::Critic::Policy::InputOutput::ProhibitBacktickOperators - Discourage stuff like C<@files = `ls $directory`>.
=head1 AFFILIATION
This Policy is part of the core L<Perl::Critic|Perl::Critic>
distribution.
=head1 DESCRIPTION
Backticks are super-convenient, especially for CGI programs, but I
find that they make a lot of noise by filling up STDERR with messages
when they fail.  I think its better to use IPC::Open3 to trap all the
output and let the application decide what to do with it.
    use IPC::Open3 'open3';
    $SIG{CHLD} = 'IGNORE';
    @output = `some_command`;                      #not ok
    my ($writer, $reader, $err);
    open3($writer, $reader, $err, 'some_command'); #ok;
    @output = <$reader>;  #Output here
    @errors = <$err>;     #Errors here, instead of the console
=head1 CONFIGURATION
Alternatively, if you do want to use backticks, you can restrict
checks to void contexts by adding the following to your
F<.perlcriticrc> file:
    [InputOutput::ProhibitBacktickOperators]
    only_in_void_context = 1
The purpose of backticks is to capture the output of an external
command.  Use of them in a void context is likely a bug.  If the
output isn't actually required, C<system()> should be used.  Otherwise
assign the result to a variable.
    `some_command`;                      #not ok
    $output = `some_command`;            #ok
    @output = `some_command`;            #ok
=head1 NOTES
This policy also prohibits the generalized form of backticks seen as
C<qx{}>.
See L<perlipc|perlipc> for more discussion on using C<wait()> instead
of C<$SIG{CHLD} = 'IGNORE'>.
You might consider using the C<capture()> function from the
L<IPC::System::Simple|IPC::System::Simple> module for a safer way of
doing what backticks do, especially on Windows.  The module also has a
safe wrapper around C<system()>.
=head1 AUTHOR
Jeffrey Ryan Thalhammer <thaljef@cpan.org>
=head1 COPYRIGHT
Copyright (c) 2005-2009 Jeffrey Ryan Thalhammer.  All rights reserved.
This program is free software; you can redistribute it and/or modify
it under the same terms as Perl itself.  The full text of this license
can be found in the LICENSE file included with this module.
=cut
# Local Variables:
#   mode: cperl
#   cperl-indent-level: 4
#   fill-column: 78
#   indent-tabs-mode: nil
#   c-indentation-style: bsd
# End:
# ex: set ts=8 sts=4 sw=4 tw=78 ft=perl expandtab shiftround :