From Code to Community: Sponsoring The Perl and Raku Conference 2025 Learn more

ELLIOTJS / Perl-Critic-1.101_002 / lib / Perl / Critic / Policy / TestingAndDebugging / ProhibitProlongedStrictureOverride.pm 

            

              
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
—
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124

              
##############################################################################
#      $URL: http://perlcritic.tigris.org/svn/perlcritic/branches/Perl-Critic-PPI-1.204/lib/Perl/Critic/Policy/TestingAndDebugging/ProhibitProlongedStrictureOverride.pm $
#     $Date: 2009-07-21 08:50:56 -0700 (Tue, 21 Jul 2009) $
#   $Author: clonezone $
# $Revision: 3404 $
##############################################################################
package Perl::Critic::Policy::TestingAndDebugging::ProhibitProlongedStrictureOverride;
use 5.006001;
use strict;
use warnings;
use Readonly;
use Perl::Critic::Utils qw{ :severities };
use base 'Perl::Critic::Policy';
our $VERSION = '1.101_001';
#-----------------------------------------------------------------------------
Readonly::Scalar my $DESC => q{Don't turn off strict for large blocks of code};
Readonly::Scalar my $EXPL => [ 433 ];
#-----------------------------------------------------------------------------
sub supported_parameters {
    return (
        {
            name            => 'statements',
            description     => 'The maximum number of statements in a no strict block.',
            default_string  => '3',
            behavior        => 'integer',
            integer_minimum => 1,
        },
    );
}
sub default_severity { return $SEVERITY_HIGH            }
sub default_themes   { return qw( core pbp bugs )       }
sub applies_to       { return 'PPI::Statement::Include' }
#-----------------------------------------------------------------------------
sub violates {
    my ($self, $elem, $doc) = @_;
    return if $elem->type ne 'no';
    return if $elem->module ne 'strict';
    my $sib = $elem->snext_sibling;
    my $nstatements = 0;
    while ($nstatements++ <= $self->{_statements}) {
        return if !$sib;
        return if $sib->isa('PPI::Statement::Include') &&
            $sib->type eq 'use' &&
            $sib->module eq 'strict';
       $sib = $sib->snext_sibling;
    }
    return $self->violation( $DESC, $EXPL, $elem );
}
1;
#-----------------------------------------------------------------------------
__END__
=pod
=head1 NAME
Perl::Critic::Policy::TestingAndDebugging::ProhibitProlongedStrictureOverride - Don't turn off strict for large blocks of code.
=head1 AFFILIATION
This Policy is part of the core L<Perl::Critic|Perl::Critic>
distribution.
=head1 DESCRIPTION
Every agrees that C<use strict> is the first step to writing
maintainable code in Perl.  However, sometimes C<strict> is a little
too strict.  In those cases, you can turn it off briefly with a C<no
strict> directive.
This policy checks that C<no strict> is only in effect for a small
number of statements.
=head1 CONFIGURATION
The default number of statements allowed per C<no strict> is three.
To override this number, put the following in your F<.perlcriticrc>:
    [TestingAndDebugging::ProhibitProlongedStrictureOverride]
    statements = 5
=head1 AUTHOR
Chris Dolan <cdolan@cpan.org>
=head1 COPYRIGHT
Copyright (c) 2006-2009 Chris Dolan.
This program is free software; you can redistribute it and/or modify
it under the same terms as Perl itself.
=cut
# Local Variables:
#   mode: cperl
#   cperl-indent-level: 4
#   fill-column: 78
#   indent-tabs-mode: nil
#   c-indentation-style: bsd
# End:
# ex: set ts=8 sts=4 sw=4 tw=78 ft=perl expandtab shiftround :