—

              
##############################################################################
#      $URL: http://perlcritic.tigris.org/svn/perlcritic/branches/Perl-Critic-PPI-1.204/lib/Perl/Critic/Policy/TestingAndDebugging/RequireUseStrict.pm $
#     $Date: 2009-07-22 10:19:39 -0700 (Wed, 22 Jul 2009) $
#   $Author: clonezone $
# $Revision: 3435 $
##############################################################################
package Perl::Critic::Policy::TestingAndDebugging::RequireUseStrict;
use 5.006001;
use strict;
use warnings;
use Readonly;
use Perl::Critic::Utils qw{ :severities $EMPTY };
use base 'Perl::Critic::Policy';
our $VERSION = '1.101_003';
#-----------------------------------------------------------------------------
Readonly::Scalar my $DESC => q{Code before strictures are enabled};
Readonly::Scalar my $EXPL => [ 429 ];
#-----------------------------------------------------------------------------
sub supported_parameters {
    return (
        {
            name            => 'equivalent_modules',
            description     =>
                q<The additional modules to treat as equivalent to "strict".>,
            default_string  => $EMPTY,
            behavior        => 'string list',
            list_always_present_values =>
                [ qw< strict Moose Moose::Role Moose::Util::TypeConstraints > ],
        },
    );
}
sub default_severity     { return $SEVERITY_HIGHEST   }
sub default_themes       { return qw( core pbp bugs ) }
sub applies_to           { return 'PPI::Document'     }
sub default_maximum_violations_per_document { return 1; }
#-----------------------------------------------------------------------------
sub violates {
    my ( $self, undef, $doc ) = @_;
    # Find the first 'use strict' statement
    my $strict_stmnt = $doc->find_first( $self->_generate_is_use_strict() );
    my $strict_line  = $strict_stmnt ? $strict_stmnt->location()->[0] : undef;
    # Find all statements that aren't 'use', 'require', or 'package'
    my $stmnts_ref = $doc->find( \&_isnt_include_or_package );
    return if not $stmnts_ref;
    # If the 'use strict' statement is not defined, or the other
    # statement appears before the 'use strict', then it violates.
    my @viols = ();
    for my $stmnt ( @{ $stmnts_ref } ) {
        last if $stmnt->isa('PPI::Statement::End');
        last if $stmnt->isa('PPI::Statement::Data');
        my $stmnt_line = $stmnt->location()->[0];
        if ( (! defined $strict_line) || ($stmnt_line < $strict_line) ) {
            push @viols, $self->violation( $DESC, $EXPL, $stmnt );
        }
    }
    return @viols;
}
sub _generate_is_use_strict {
    my ($self) = @_;
    return sub {
        my (undef, $elem) = @_;
        return 0 if !$elem->isa('PPI::Statement::Include');
        return 0 if $elem->type() ne 'use';
        # We only want file-scoped pragmas
        my $parent = $elem->parent();
        return 0 if !$parent->isa('PPI::Document');
        if ( my $pragma = $elem->pragma() ) {
            return 1 if $self->{_equivalent_modules}{$pragma};
        }
        elsif ( my $module = $elem->module() ) {
            return 1 if $self->{_equivalent_modules}{$module};
        }
        return 0;
    };
}
sub _isnt_include_or_package {
    my (undef, $elem) = @_;
    return 0 if ! $elem->isa('PPI::Statement');
    return 0 if $elem->isa('PPI::Statement::Package');
    return 0 if $elem->isa('PPI::Statement::Include');
    return 1;
}
1;
__END__
#-----------------------------------------------------------------------------
HideShow 63 lines of Pod
=pod
=head1 NAME
Perl::Critic::Policy::TestingAndDebugging::RequireUseStrict - Always C<use strict>.
=head1 AFFILIATION
This Policy is part of the core L<Perl::Critic|Perl::Critic>
distribution.
=head1 DESCRIPTION
Using strictures is probably the single most effective way to improve
the quality of your code.  This policy requires that the C<'use
strict'> statement must come before any other statements except
C<package>, C<require>, and other C<use> statements.  Thus, all the
code in the entire package will be affected.
There are special exemptions for L<Moose|Moose>,
L<Moose::Role|Moose::Role>, and
L<Moose::Util::TypeConstraints|Moose::Util::TypeConstraints> because
they enforces strictness; e.g.  C<'use Moose'> is treated as
equivalent to C<'use strict'>.
The maximum number of violations per document for this policy defaults
to 1.
=head1 CONFIGURATION
If you take make use of things like
L<Moose::Exporter|Moose::Exporter>, you can create your own modules
that import the L<strict|strict> pragma into the code that is
C<use>ing them.  There is an option to add to the default set of
pragmata and modules in your F<.perlcriticrc>: C<equivalent_modules>.
    [TestingAndDebugging::RequireUseStrict]
    equivalent_modules = MooseX::My::Sugar
=head1 SEE ALSO
L<Perl::Critic::Policy::TestingAndDebugging::ProhibitNoStrict|Perl::Critic::Policy::TestingAndDebugging::ProhibitNoStrict>
=head1 AUTHOR
Jeffrey Ryan Thalhammer <thaljef@cpan.org>
=head1 COPYRIGHT
Copyright (c) 2005-2009 Jeffrey Ryan Thalhammer.  All rights reserved.
This program is free software; you can redistribute it and/or modify it under
the same terms as Perl itself.  The full text of this license can be found in
the LICENSE file included with this module
=cut
##############################################################################
# Local Variables:
#   mode: cperl
#   cperl-indent-level: 4
#   fill-column: 78
#   indent-tabs-mode: nil
#   c-indentation-style: bsd
# End:
# ex: set ts=8 sts=4 sw=4 tw=78 ft=perl expandtab shiftround :