The Perl Toolchain Summit 2025 Needs You: You can help 🙏 Learn more

LEONT / Dist-Build-0.018 / lib / Dist / Build / DynamicPrereqs.pm 

            

              
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
—
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99

              
package Dist::Build::DynamicPrereqs;
$Dist::Build::DynamicPrereqs::VERSION = '0.018';
use strict;
use warnings;
use parent 'ExtUtils::Builder::Planner::Extension';
sub add_methods {
        my ($self, $planner) = @_;
        $planner->add_delegate('evaluate_dynamic_prereqs', sub {
                my ($planner, %options) = @_;
                my $meta = $options{meta} // $planner->meta;
                if (my $dynamic = $meta->custom('x_dynamic_prereqs')) {
                        require CPAN::Requirements::Dynamic;
                        $options{config}        //= $planner->config;
                        $options{pureperl_only} //= $planner->pureperl_only;
                        my $dynamic_parser = CPAN::Requirements::Dynamic->new(%options);
                        my $prereq = $dynamic_parser->evaluate($dynamic);
                        $planner->add_meta({ prereqs => $prereq->as_string_hash });
                }
        });
        $planner->add_delegate('add_prereq', sub {
                my ($planner, $module, $version, %options) = @_;
                $version   //= 0;
                my $phase    = $options{phase}    // 'runtime';
                my $relation = $options{relation} // 'requires';
                $planner->add_meta({ prereqs => { $phase => { $relation => { $module => $version }}}});
        });
}
1;
# ABSTRACT: Support dynamic prerequisites in Dist::Build
__END__
=pod
=encoding UTF-8
=head1 NAME
Dist::Build::DynamicPrereqs - Support dynamic prerequisites in Dist::Build
=head1 VERSION
version 0.018
=head1 SYNOPSIS
 load_module("Dist::Build::DynamicPrereqs");
 evaluate_dynamic_prereqs();
=head1 DESCRIPTION
This extension adds support for configure-time dynamic prerequisites to C<Dist::Build>.
=head1 DELEGATES
This adds the following delegates to the planner:
=head2 evaluate_dynamic_prereqs()
This evaluates the dynamic prerequisites (as L<CPAN::Requirements::Dynamic|CPAN::Requirements::Dynamic>) in the metadata, and adds them to the prerequisites.
=head2 add_prereq($module, $version = 0, %args)
This adds a specific prerequisite. It takes the following (optional) named arguments:
=over 4
=item * phase
A CPAN::Meta requirement phase: runtime (default), build or test
=item * relation
A CPAN::Meta requirement relation: requires (default, recommends or suggests
=back
=head1 AUTHOR
Leon Timmermans <fawaka@gmail.com>
=head1 COPYRIGHT AND LICENSE
This software is copyright (c) 2024 by Leon Timmermans.
This is free software; you can redistribute it and/or modify it under
the same terms as the Perl 5 programming language system itself.
=cut