The Perl Toolchain Summit 2025 Needs You: You can help 🙏 Learn more

PERLER / HTML-FormFu-0.09003_01 / lib / HTML / FormFu / Constraint / Regex.pm 

            

              
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
—
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98

              
package HTML::FormFu::Constraint::Regex;
use Moose;
extends 'HTML::FormFu::Constraint';
use Regexp::Common;
has common => ( is => 'rw', traits  => ['Chained'] );
has regex  => ( is => 'rw', traits  => ['Chained'] );
sub constrain_value {
    my ( $self, $value ) = @_;
    return 1 if !defined $value || $value eq '';
    my $regex;
    if ( defined $self->regex ) {
        $regex = $self->regex;
    }
    elsif ( defined $self->common ) {
        my @common
            = ref $self->common
            ? @{ $self->common }
            : $self->common;
        $regex = shift @common;
        $regex = $RE{$regex};
        for (@common) {
            $regex = $regex->{ ref $_ ? join( $;, %$_ ) : $_ };
        }
    }
    else {
        $regex = qr/.*/;
    }
    my $ok = $value =~ $regex;
    return $self->not ? !$ok : $ok;
}
__PACKAGE__->meta->make_immutable;
1;
__END__
=head1 NAME
HTML::FormFu::Constraint::Regex - Regex Constraint
=head1 DESCRIPTION
Regular expression-based constraint.
=head1 METHODS
=head2 regex
Arguments: $regex
Arguments: $string
=head2 common
Arguments: \@parts
Used to build a L<Regexp::Common> regex.
The following definition is equivalent to 
C<< $RE{URI}{HTTP}{-scheme => 'https?'} >>
    type: Regex
    common: 
      - URI
      - HTTP
      - { '-scheme': 'https?' }
=head1 SEE ALSO
Is a sub-class of, and inherits methods from L<HTML::FormFu::Constraint>
L<HTML::FormFu>
=head1 AUTHOR
Carl Franks C<cfranks@cpan.org>
Based on the original source code of L<HTML::Widget::Constraint::Regex>, by 
Sebastian Riedel, C<sri@oook.de>.
=head1 LICENSE
This library is free software, you can redistribute it and/or modify it under
the same terms as Perl itself.
=cut