# -*- mode: perl; -*-
use strict;
use warnings;
use Test::More tests => 81;
###############################################################################
# Read and load configuration file and backend library.
use Config::Tiny ();
my $config_file = 'xt/author/lib.ini';
my $config = Config::Tiny -> read('xt/author/lib.ini')
  or die Config::Tiny -> errstr();
# Read the library to test.
our $LIB = $config->{_}->{lib};
die "No library defined in file '$config_file'"
  unless defined $LIB;
die "Invalid library name '$LIB' in file '$config_file'"
  unless $LIB =~ /^[A-Za-z]\w*(::\w+)*\z/;
# Load the library.
eval "require $LIB";
die $@ if $@;
###############################################################################
can_ok($LIB, '_is_two');
# Generate test data.
my @data;
for (my $x = 0 ; $x <= 10 ; ++ $x) {
    push @data, [ $x, $x == 2 ];
}
for (my $e = 2 ; $e <= 10 ; ++ $e) {
    my $x = "1" . ("0" x $e);
    push @data, [ $x, $x == 2 ];
}
# List context.
for (my $i = 0 ; $i <= $#data ; ++ $i) {
    my ($in0, $out0) = @{ $data[$i] };
    my ($x, @got);
    my $test = qq|\$x = $LIB->_new("$in0"); |
             . qq|\@got = $LIB->_is_two(\$x);|;
    diag("\n$test\n\n") if $ENV{AUTHOR_DEBUGGING};
    eval $test;
    is($@, "", "'$test' gives emtpy \$\@");
    subtest "_is_two() in list context: $test", sub {
        plan tests => 3,
        cmp_ok(scalar @got, "==", 1,
               "'$test' gives one output arg");
        is(ref($got[0]), "",
           "'$test' output arg is a scalar");
        ok($got[0] && $out0 || !$got[0] && !$out0,
           "'$test' output arg has the right value");
    };
}
# Scalar context.
for (my $i = 0 ; $i <= $#data ; ++ $i) {
    my ($in0, $out0) = @{ $data[$i] };
    my ($x, $got);
    my $test = qq|\$x = $LIB->_new("$in0"); |
             . qq|\$got = $LIB->_is_two(\$x);|;
    diag("\n$test\n\n") if $ENV{AUTHOR_DEBUGGING};
    eval $test;
    is($@, "", "'$test' gives emtpy \$\@");
    subtest "_is_two() in scalar context: $test", sub {
        plan tests => 2,
        is(ref($got), "",
           "'$test' output arg is a scalar");
        ok($got && $out0 || !$got && !$out0,
           "'$test' output arg has the right value");
    };
}