# -*- mode: perl; -*-
use strict;
use warnings;
use Test::More tests => 1597;
###############################################################################
# Read and load configuration file and backend library.
use Config::Tiny ();
my $config_file = 'xt/author/lib.ini';
my $config = Config::Tiny -> read('xt/author/lib.ini')
  or die Config::Tiny -> errstr();
# Read the library to test.
our $LIB = $config->{_}->{lib};
die "No library defined in file '$config_file'"
  unless defined $LIB;
die "Invalid library name '$LIB' in file '$config_file'"
  unless $LIB =~ /^[A-Za-z]\w*(::\w+)*\z/;
# Read the reference type(s) the library uses.
our $REF = $config->{_}->{ref};
die "No reference type defined in file '$config_file'"
  unless defined $REF;
die "Invalid reference type '$REF' in file '$config_file'"
  unless $REF =~ /^[A-Za-z]\w*(::\w+)*\z/;
# Load the library.
eval "require $LIB";
die $@ if $@;
###############################################################################
my $scalar_util_ok = eval { require Scalar::Util; };
Scalar::Util -> import('refaddr') if $scalar_util_ok;
diag "Skipping some tests since Scalar::Util is not installed."
  unless $scalar_util_ok;
can_ok($LIB, '_copy');
use lib 't';
use Math::BigInt::Lib::TestUtil qw< randstr >;
# Generate test data.
my @data;
for (my $x = 0 ; $x <= 100 ; ++ $x) {
    push @data, [ $x ];
}
for (my $n = 3 ; $n <= 300 ; ++ $n) {
    my $x = randstr($n, 10);            # random $n-digit integer
    push @data, [ $x ];
}
# List context.
for (my $i = 0 ; $i <= $#data ; ++ $i) {
    my ($in0) = @{ $data[$i] };
    my $out0 = $in0;
    my ($x, @got);
    my $test = qq|\$x = $LIB->_new("$in0"); |
             . qq|\@got = $LIB->_copy(\$x);|;
    diag("\n$test\n\n") if $ENV{AUTHOR_DEBUGGING};
    eval $test;
    is($@, "", "'$test' gives emtpy \$\@");
    subtest "_copy() in list context: $test", sub {
        plan tests => 5;
        cmp_ok(scalar @got, "==", 1,
               "'$test' gives one output arg");
        is(ref($got[0]), $REF,
           "'$test' output arg is a $REF");
        is($LIB->_check($got[0]), 0,
           "'$test' output is valid");
        is($LIB->_str($got[0]), $out0,
           "'$test' output arg has the right value");
      SKIP: {
            skip "Scalar::Util not available", 1 unless $scalar_util_ok;
            isnt(refaddr($got[0]), refaddr($x),
                 "'$test' output arg is not the input arg");
        }
    };
}
# Scalar context.
for (my $i = 0 ; $i <= $#data ; ++ $i) {
    my ($in0) = @{ $data[$i] };
    my $out0 = $in0;
    my ($x, $got);
    my $test = qq|\$x = $LIB->_new("$in0"); |
             . qq|\$got = $LIB->_copy(\$x);|;
    diag("\n$test\n\n") if $ENV{AUTHOR_DEBUGGING};
    eval $test;
    is($@, "", "'$test' gives emtpy \$\@");
    subtest "_copy() in scalar context: $test", sub {
        plan tests => 4;
        is(ref($got), $REF,
           "'$test' output arg is a $REF");
        is($LIB->_check($got), 0,
           "'$test' output is valid");
        is($LIB->_str($got), $out0,
           "'$test' output arg has the right value");
      SKIP: {
            skip "Scalar::Util not available", 1 unless $scalar_util_ok;
            isnt(refaddr($got), refaddr($x),
                 "'$test' output arg is not the input arg");
        }
    };
}