# -*- mode: perl; -*-
use strict;
use warnings;
use Test::More tests => 2997;
###############################################################################
# Read and load configuration file and backend library.
use Config::Tiny ();
my $config_file = 'xt/author/lib.ini';
my $config = Config::Tiny -> read('xt/author/lib.ini')
  or die Config::Tiny -> errstr();
# Read the library to test.
our $LIB = $config->{_}->{lib};
die "No library defined in file '$config_file'"
  unless defined $LIB;
die "Invalid library name '$LIB' in file '$config_file'"
  unless $LIB =~ /^[A-Za-z]\w*(::\w+)*\z/;
# Read the reference type(s) the library uses.
our $REF = $config->{_}->{ref};
die "No reference type defined in file '$config_file'"
  unless defined $REF;
die "Invalid reference type '$REF' in file '$config_file'"
  unless $REF =~ /^[A-Za-z]\w*(::\w+)*\z/;
# Load the library.
eval "require $LIB";
die $@ if $@;
###############################################################################
can_ok($LIB, '_new');
use lib 't';
use Math::BigInt::Lib::TestUtil qw< randstr >;
# Generate test data.
my @data;
push @data, 0 .. 250;                   # small integers
for (my $n = 3 ; $n <= 250 ; ++ $n) {
    push @data, "1" . ("0" x 3);        # powers of 10
}
for (my $n = 1 ; $n <= 250 ; ++ $n) {
    push @data, randstr($n, 10);        # random big integer
}
# List context.
for (my $i = 0 ; $i <= $#data ; ++ $i) {
    my $in0  = $data[$i];
    my $out0 = $in0;
    my ($x, @got);
    my $test = qq|\@got = $LIB->_new("$in0"); |;
    diag("\n$test\n\n") if $ENV{AUTHOR_DEBUGGING};
    eval $test;
    is($@, "", "'$test' gives emtpy \$\@");
    subtest "_new() in list context: $test", sub {
        plan tests => 4,
        cmp_ok(scalar @got, '==', 1,
               "'$test' gives one output arg");
        is(ref($got[0]), $REF,
           "'$test' first output arg is a $REF");
        is($LIB->_check($got[0]), 0,
           "'$test' output is valid");
        is($LIB->_str($got[0]), $out0,
           "'$test' output arg has the right value");
    };
}
# Scalar context.
for (my $i = 0 ; $i <= $#data ; ++ $i) {
    my $in0  = $data[$i];
    my $out0 = $in0;
    my ($x, $got);
    my $test = qq|\$got = $LIB->_new("$in0"); |;
    diag("\n$test\n\n") if $ENV{AUTHOR_DEBUGGING};
    eval $test;
    is($@, "", "'$test' gives emtpy \$\@");
    subtest "_new() in scalar context: $test", sub {
        plan tests => 3,
        is(ref($got), $REF,
           "'$test' first output arg is a $REF");
        is($LIB->_check($got), 0,
           "'$test' output is valid");
        is($LIB->_str($got), $out0,
           "'$test' output arg has the right value");
    };
}