# -*- mode: perl; -*-
use strict;
use warnings;
use Test::More tests => 54713;
###############################################################################
# Read and load configuration file and backend library.
use Config::Tiny ();
my $config_file = 'xt/author/lib.ini';
my $config = Config::Tiny -> read('xt/author/lib.ini')
  or die Config::Tiny -> errstr();
# Read the library to test.
our $LIB = $config->{_}->{lib};
die "No library defined in file '$config_file'"
  unless defined $LIB;
die "Invalid library name '$LIB' in file '$config_file'"
  unless $LIB =~ /^[A-Za-z]\w*(::\w+)*\z/;
# Read the reference type(s) the library uses.
our $REF = $config->{_}->{ref};
die "No reference type defined in file '$config_file'"
  unless defined $REF;
die "Invalid reference type '$REF' in file '$config_file'"
  unless $REF =~ /^[A-Za-z]\w*(::\w+)*\z/;
# Load the library.
eval "require $LIB";
die $@ if $@;
###############################################################################
my $scalar_util_ok = eval { require Scalar::Util; };
Scalar::Util -> import('refaddr') if $scalar_util_ok;
diag "Skipping some tests since Scalar::Util is not installed."
  unless $scalar_util_ok;
can_ok($LIB, '_rsft');
my @data;
# Small numbers.
for (my $x = 0; $x <= 100 ; ++ $x) {
    for (my $n = 0; $n <= 5 ; ++ $n) {
        for (my $b = 2; $b <= 16 ; ++ $b) {
            my $y = int($x / ($b ** $n));
            push @data, [ $x, $n, $b, $y ];
        }
    }
}
# Add data in data file.
(my $datafile = $0) =~ s/\.t/.dat/;
open DATAFILE, $datafile or die "$datafile: can't open file for reading: $!";
while (<DATAFILE>) {
    s/\s+\z//;
    next if /^#/ || ! /\S/;
    push @data, [ split /:/ ];
}
close DATAFILE or die "$datafile: can't close file after reading: $!";
# List context.
for (my $i = 0 ; $i <= $#data ; ++ $i) {
    my ($in0, $in1, $in2, $out0) = @{ $data[$i] };
    my ($x, $y, @got);
    my $test = qq|\$x = $LIB->_new("$in0"); |
             . qq|\$y = $LIB->_new("$in1"); |
             . qq|\@got = $LIB->_rsft(\$x, \$y, $in2);|;
    diag("\n$test\n\n") if $ENV{AUTHOR_DEBUGGING};
    eval $test;
    is($@, "", "'$test' gives emtpy \$\@");
    subtest "_rsft() in list context: $test", sub {
        plan tests => 8;
        cmp_ok(scalar @got, '==', 1,
               "'$test' gives one output arg");
        is(ref($got[0]), $REF,
           "'$test' output arg is a $REF");
        is($LIB->_check($got[0]), 0,
           "'$test' output is valid");
        is($LIB->_str($got[0]), $out0,
           "'$test' output arg has the right value");
      SKIP: {
            skip "Scalar::Util not available", 1 unless $scalar_util_ok;
            isnt(refaddr($got[0]), refaddr($y),
                 "'$test' output arg is not the second input arg");
        }
        is(ref($x), $REF,
           "'$test' first input arg is still a $REF");
        is(ref($y), $REF,
           "'$test' second input arg is still a $REF");
        is($LIB->_str($y), $in1,
           "'$test' second input arg is unmodified");
    };
}
# Scalar context.
for (my $i = 0 ; $i <= $#data ; ++ $i) {
    my ($in0, $in1, $in2, $out0) = @{ $data[$i] };
    my ($x, $y, $got);
    my $test = qq|\$x = $LIB->_new("$in0"); |
             . qq|\$y = $LIB->_new("$in1"); |
             . qq|\$got = $LIB->_rsft(\$x, \$y, $in2);|;
    diag("\n$test\n\n") if $ENV{AUTHOR_DEBUGGING};
    eval $test;
    is($@, "", "'$test' gives emtpy \$\@");
    subtest "_rsft() in scalar context: $test", sub {
        plan tests => 7;
        is(ref($got), $REF,
           "'$test' output arg is a $REF");
        is($LIB->_check($got), 0,
           "'$test' output is valid");
        is($LIB->_str($got), $out0,
           "'$test' output arg has the right value");
      SKIP: {
            skip "Scalar::Util not available", 1 unless $scalar_util_ok;
            isnt(refaddr($got), refaddr($y),
                 "'$test' output arg is not the second input arg");
        }
        is(ref($x), $REF,
           "'$test' first input arg is still a $REF");
        is(ref($y), $REF,
           "'$test' second input arg is still a $REF");
        is($LIB->_str($y), $in1,
           "'$test' second input arg is unmodified");
    };
}