The Perl and Raku Conference 2025: Greenville, South Carolina - June 27-29 Learn more

TELS / Image-Info-1.26 / lib / Image / Info / PNG.pm 

            

              
1
2
3
4
5
6
—
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170

              
package Image::Info::PNG;
# Copyright 1999-2000, Gisle Aas.
#
# This library is free software; you can redistribute it and/or
# modify it under the same terms as Perl itself.
=begin register
MAGIC: /^\x89PNG\x0d\x0a\x1a\x0a/
Information from IHDR, PLTE, gAMA, pHYs, tEXt, tIME chunks are
extracted.  The sequence of chunks are also given by the C<PNG_Chunks>
key.
=end register
=cut
use strict;
# Test for Compress::Zlib (for reading zTXt chunks)
my $have_zlib = 0;
eval {
    require Compress::Zlib;
    $have_zlib++;
};
sub my_read
{
    my($source, $len) = @_;
    my $buf;
    my $n = read($source, $buf, $len);
    die "read failed: $!" unless defined $n;
    die "short read ($len/$n)" unless $n == $len;
    $buf;
}
sub process_file
{
    my($info, $fh) = @_;
    my $signature = my_read($fh, 8);
    die "Bad PNG signature"
        unless $signature eq "\x89PNG\x0d\x0a\x1a\x0a";
    $info->push_info(0, "file_media_type" => "image/png");
    $info->push_info(0, "file_ext" => "png");
    my @chunks;
    while (1) {
        my($len, $type) = unpack("Na4", my_read($fh, 8));
        if (@chunks) {
            my $last = $chunks[-1];
            $last =~ s/\s(\d+)$//;
            my $count = $1 || 1;
            if ($last eq $type) {
                $count++;
                $chunks[-1] = "$type $count";
            }
            else {
                push(@chunks, $type);
            }
        }
        else {
            push(@chunks, $type);
        }
        last if $type eq "IEND";
        my $data = my_read($fh, $len + 4);
        my $crc = unpack("N", substr($data, -4, 4, ""));
        if ($type eq "IHDR" && $len == 13) {
            my($w, $h, $depth, $ctype, $compression, $filter, $interlace) =
                unpack("NNCCCCC", $data);
            $ctype = {
                      0 => "Gray",
                      2 => "RGB",
                      3 => "Indexed-RGB",
                      4 => "GrayA",
                      6 => "RGBA",
                     }->{$ctype} || "PNG-$ctype";
            $compression = "Deflate" if $compression == 0;
            $filter = "Adaptive" if $filter == 0;
            $interlace = "Adam7" if $interlace == 1;
            $info->push_info(0, "width", $w);
            $info->push_info(0, "height", $h);
            $info->push_info(0, "SampleFormat", "U$depth");
            $info->push_info(0, "color_type", $ctype);
            $info->push_info(0, "Compression", $compression);
            $info->push_info(0, "PNG_Filter", $filter);
            $info->push_info(0, "Interlace", $interlace)
                if $interlace;
        }
        elsif ($type eq "PLTE") {
            my @table;
            while (length $data) {
                push(@table, sprintf("#%02x%02x%02x",
                                     unpack("C3", substr($data, 0, 3, ""))));
            }
            $info->push_info(0, "ColorPalette" => \@table);
        }
        elsif ($type eq "gAMA" && $len == 4) {
            $info->push_info(0, "Gamma", unpack("N", $data)/100_000);
        }
        elsif ($type eq "pHYs" && $len == 9) {
            my $res;
            my($res_x, $res_y, $unit) = unpack("NNC", $data);
            if (0 && $unit == 1) {
                # convert to dpi
                $unit = "dpi";
                for ($res_x, $res_y) {
                    $_ *= 0.0254;
                }
            }
            $res = ($res_x == $res_y) ? $res_x : "$res_x/$res_y";
            if ($unit) {
                if ($unit == 1) {
                    $res .= " dpm";
                }
                else {
                    $res .= " png-unit-$unit";
                }
            }
            $info->push_info(0, "resolution" => $res)
        }
        elsif ($type eq "tEXt") {
            my($key, $val) = split(/\0/, $data, 2);
            # XXX should make sure $key is not in conflict with any
            # other key we might generate
            $info->push_info(0, $key, $val);
        }
        elsif ($type eq "zTXt" && $have_zlib) {
                my($key, $val) = split(/\0/, $data, 2);
                my($method,$ctext) = split(//, $val, 2);
                if ($method == 0) {
                    $info->push_info(0, $key, Compress::Zlib::uncompress($ctext));
                } else {
                    $info->push_info(0, "Chunk-$type" => $data);
                }
        }
        elsif ($type eq "tIME" && $len == 7) {
            $info->push_info(0, "LastModificationTime",
                             sprintf("%04d-%02d-%02d %02d:%02d:%02d",
                                     unpack("nC5", $data)));
        }
        elsif ($type eq "sBIT") {
            $info->push_info(0, "SignificantBits" => unpack("C*", $data));
        }
        elsif ($type eq "IDAT") {
            # ignore
        }
        else {
            $info->push_info(0, "Chunk-$type" => $data);
        }
    }
    $info->push_info(0, "PNG_Chunks", @chunks);
    unless ($info->get_info(0, "resolution")) {
        $info->push_info(0, "resolution", "1/1");
    }
}
1;