From Code to Community: Sponsoring The Perl and Raku Conference 2025 Learn more

TOBYINK / Type-Tiny-2.007_008 / t / 20-modules / Type-Params / v2-named.t 

            

              
—
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113

              
=pod
=encoding utf-8
=head1 PURPOSE
Named parameter tests for modern Type::Params v2 API.
=head1 AUTHOR
Toby Inkster E<lt>tobyink@cpan.orgE<gt>.
=head1 COPYRIGHT AND LICENCE
This software is copyright (c) 2022-2025 by Toby Inkster.
This is free software; you can redistribute it and/or modify it under
the same terms as the Perl 5 programming language system itself.
=cut
use strict;
use warnings;
use Test::More;
use Test::Requires '5.020';
use Test::Fatal;
use Test::TypeTiny;
use Type::Params qw( ArgsObject );
use Types::Common qw( HashRef );
BEGIN {
        package Local::MyPackage;
         
        our $LAST;
         
        use strict;
        use warnings;
         
        use feature 'state';
        use experimental 'signatures';
         
        use Types::Standard -types;
        use Type::Params -sigs;
         
        signature_for myfunc => (
                method => Object | Str,
                named  => [ arr => ArrayRef, int => Int ],
        );
         
        sub myfunc ( $self, $arg ) {
                $LAST = $arg;
                return $arg->arr->[ $arg->int ];
        }
         
        sub myfunc2 {
                state $signature = signature(
                        method => 1,
                        named  => [ arr => ArrayRef, int => Int ],
                );
                my ( $self, $arg ) = &$signature;
                 
                $LAST = $arg;
                return $arg->arr->[ $arg->int ];
        }
};
my $o   = bless {} => 'Local::MyPackage';
my @arr = ( 'a' .. 'z' );
{
        local $Local::MyPackage::LAST;
        is $o->myfunc( arr => \@arr, int => 2 ),  'c', 'myfunc (happy path)';
        should_pass $Local::MyPackage::LAST, $_ for ArgsObject, ArgsObject['Local::MyPackage::myfunc'];
        should_fail $Local::MyPackage::LAST, $_ for HashRef, ArgsObject['Local::MyPackage::myfunc2'];
}
{
        local $Local::MyPackage::LAST;
        is $o->myfunc2( arr => \@arr, int => 4 ), 'e', 'myfunc2 (happy path)';
        should_pass $Local::MyPackage::LAST, $_ for ArgsObject, ArgsObject['Local::MyPackage::myfunc2'];
        should_fail $Local::MyPackage::LAST, $_ for HashRef, ArgsObject['Local::MyPackage::myfunc'];
}
{
        my $e = exception {
                $o->myfunc( arr => \@arr, int => undef );
        };
        like $e, qr/Undef did not pass type constraint "Int"/, 'myfunc (type exception)'
}
{
        my $e = exception {
                $o->myfunc2( arr => \@arr, int => undef );
        };
        like $e, qr/Undef did not pass type constraint "Int"/, 'myfunc2 (type exception)'
}
{
        my $e = exception {
                $o->myfunc( arr => \@arr, int => 6, 'debug' );
        };
        like $e, qr/Wrong number of parameters/, 'myfunc (param count exception)'
}
{
        my $e = exception {
                $o->myfunc2( arr => \@arr, int => 8, 'debug' );
        };
        like $e, qr/Wrong number of parameters/, 'myfunc2 (param count exception)'
}
done_testing;