VANHOESEL / OpenTracing-Implementation-DataDog-v0.45.0 / t / OpenTracing / Implementation / DataDog / 10_component.t 

            

              
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97

              
use Test::Most;
use aliased 'OpenTracing::Implementation::DataDog::Tracer';
use JSON::MaybeXS;
use lib 't/lib';
use UserAgent::Fake;
my $global_tracer;
subtest "Setup the tracer" => sub {
     
    my $fake_user_agent;
    lives_ok {
        $fake_user_agent = UserAgent::Fake->new;
    } "Created a 'fake_user_agent'"
     
    or return;
     
    $ENV{DD_SERVICE_NAME} = 'TAP::Harness';
     
    lives_ok {
        $global_tracer = Tracer->new(
            client => {
                http_user_agent => $fake_user_agent,
                span_buffer_threshold => 4,
            },
            default_resource_name  => __FILE__,
        )
    } "Created a Tracer,"
     
    or return;
     
};
subtest "Create spans as if it is manual instrumentation" => sub {
     
    sub zero {
        my $scope = $global_tracer->start_active_span( 'zero' );
        one_a();
        one_b();
        $scope->close;
    }
     
    sub one_a {
        my $scope = $global_tracer->start_active_span( 'one_a' );
        two();
        $scope->close;
    }
     
    sub one_b {
        my $scope = $global_tracer->start_active_span( 'one_b' );
        two();
        two();
        $scope->close;
    }
     
    sub two {
        my $scope = $global_tracer->start_active_span( 'two' );
        # do nothing
        $scope->close;
    }
     
    lives_ok{ zero() } "Did run some subroutines"
     
};
subtest "Check the requests" => sub {
     
    my @requests = $global_tracer->client->http_user_agent->get_all_requests();
     
    my @structs = map {
        decode_json( $_->decoded_content )
    } @requests;
     
    cmp_deeply(
        \@structs =>
        [
            [[
                ( superhashof { name => 'two'   } ),
                ( superhashof { name => 'one_a' } ),
                ( superhashof { name => 'two'   } ),
                ( superhashof { name => 'two'   } ),
            ]],
            [[
                ( superhashof { name => 'one_b' } ),
                ( superhashof { name => 'zero'  } ),
            ]],
        ],
        "Got the right spans in the expected order"
    );
     
};
done_testing();