From Code to Community: Sponsoring The Perl and Raku Conference 2025 Learn more

VVU / wubot-0.3.3-TRIAL / lib / App / Wubot / Plugin / Directory.pm 

            

              
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
—
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98

              
package App::Wubot::Plugin::Directory;
use Moose;
our $VERSION = '0.3.3'; # VERSION
use App::Wubot::Logger;
with 'App::Wubot::Plugin::Roles::Cache';
with 'App::Wubot::Plugin::Roles::Plugin';
sub check {
    my ( $self, $inputs ) = @_;
    my $config = $inputs->{config};
    my $cache  = $inputs->{cache};
    my $directory = $config->{path};
    unless ( -d $directory ) {
        my $subject = "Error: directory not found: $directory";
        $self->logger->error( $self->key . ": $subject" );
        return { cache => $cache, react => { subject => $subject } };
    }
    my @react;
    my $dir_h;
    opendir( $dir_h, $directory ) or die "Can't opendir $directory: $!";
  ENTRY:
    while ( defined( my $entry = readdir( $dir_h ) ) ) {
        next unless $entry;
        if ( $entry eq "." || $entry eq ".." ) { next }
        # if we've already seen this item, move along
        if ( $self->cache_is_seen( $cache, $entry ) ) {
            $self->logger->trace( "Already seen: ", $entry );
            # touch cache time on this subject
            $self->cache_mark_seen( $cache, $entry );
            next ENTRY;
        }
        # this item is still in the directory
        $self->cache_mark_seen( $cache, $entry );
        push @react, { file => $entry, subject => "New: $entry" };
    }
    $self->cache_expire( $cache );
    return { cache => $cache, react => \@react };
}
__PACKAGE__->meta->make_immutable;
1;
__END__
=head1 NAME
App::Wubot::Plugin::Directory - monitor a directory for new files
=head1 VERSION
version 0.3.3
=head1 SYNOPSIS
  ~/wubot/config/plugins/Directory/scifri.yaml
  ---
  path: /Users/wu/Music/iTunes/iTunes Media/Podcasts/Science Friday Audio Podcast
  delay: 15m
=head1 DESCRIPTION
This plugin monitors a directory for newly added files.  When a new
file is found, the message sent will contain the fields:
  file: {filename}
  subject: New: {filename}
=head1 SUBROUTINES/METHODS
=over 8
=item check( $inputs )
The standard monitor check() method.
=back