NAME

HTML::Make::Calendar - Make an HTML calendar

SYNOPSIS

    use HTML::Make::Calendar 'calendar';
    my $cal = calendar ();
    print $cal->text ();
    my $oldcal = calendar (year => 1966, month => 3);
    print $oldcal->text ();
    

The output HTML looks like this:

January 2021
Mo	Tu	We	Th	Fr	Sa	Su
				1	2	3
4	5	6	7	8	9	10
11	12	13	14	15	16	17
18	19	20	21	22	23	24
25	26	27	28	29	30	31

March 1966
Mo	Tu	We	Th	Fr	Sa	Su
	1	2	3	4	5	6
7	8	9	10	11	12	13
14	15	16	17	18	19	20
21	22	23	24	25	26	27
28	29	30	31

(This example is included as synopsis.pl in the distribution.)

VERSION

This documents version 0.01 of HTML-Make-Calendar corresponding to git commit 0a44bc7f4d5e94e6c7729395bd3083814175fb90 released on Sun Mar 14 09:01:16 2021 +0900.

DESCRIPTION

This module constructs HTML calendars.

FUNCTIONS

calendar

    my $out = calendar (year => 2010, month => 10);

Make the calendar. The return value is an HTML::Make object. To get the actual HTML, call its text method:

    use HTML::Make::Calendar 'calendar';
    my $out = calendar (year => 2021, month => 1);
    print $out->text ();

The output HTML looks like this:

January 2021
Mo	Tu	We	Th	Fr	Sa	Su
				1	2	3
4	5	6	7	8	9	10
11	12	13	14	15	16	17
18	19	20	21	22	23	24
25	26	27	28	29	30	31

(This example is included as calendar.pl in the distribution.)

The possible arguments are

cdata

Callback data, see "dayc".

day_html

Override the HTML element used to make the "day" cells. The default is td. If you override this then you also need to override the parent elements, otherwise HTML::Make will fuss about compatibility.

dayc

Day callback which fills in the "day" cell of the calendar. If this is omitted, a default element is added. The day callback is called with three arguments, first "cdata", your data, second the date as a hash reference with arguments year, month and dom (day of month, a number from 1 to 31), and third the HTML element to attach the return value to, representing the cell of the calendar, like this:

    &{$dayc} ($cdata, {year => 2020, month => 12, dom => 21}, $td);

where $td is an HTML::Make object.

daynames

Specify the names of the days. See "Japanese calendar" for an example.

first

The first day of the week. The default is 1 for Monday. Specify 7 to start on Sunday:

    use HTML::Make::Calendar 'calendar';
    my $cal = calendar (first => 7);
    print $cal->text ();
    

The output HTML looks like this:

January 2021
Su	Mo	Tu	We	Th	Fr	Sa
					1	2
3	4	5	6	7	8	9
10	11	12	13	14	15	16
17	18	19	20	21	22	23
24	25	26	27	28	29	30
31

(This example is included as first.pl in the distribution.)

Any other day of the week may also be used, for example specify 3 to start the weeks on Wednesdays.

month

The month, as a number from 1 to 12. If the month is omitted, the current month is used as given by "Today" in Date::Calc.

month_html

The HTML element used to make a month of the calendar. The default is table. You don't need to supply < and >, just the alphabetic part of the HTML element, as with the parent module HTML::Make.

monthc

Callback for month and year name. See "Japanese calendar" for an example.

week_html

The HTML element used to make a week of the calendar. The default is tr. You don't need to supply < and >, just the alphabetic part of the HTML element, as with the parent module HTML::Make.

weekless

Set to a true value to not use weeks. If you switch off weeks, the return value is the HTML elements but not subdivided into week blocks but whose parent is the month. This is for people who want to style their calendars with CSS, such as a CSS grid, rather than using HTML tables.

year

The year, as a four-digit number like 2020. If the year is omitted, the current year is used, as given by "Today" in Date::Calc.

Phases of the moon

This example demonstrates the use of "dayc" and "cdata" by adding the phase of the moon to your calendar. It requires Astro::MoonPhase (not included with this distribution).

    use utf8;
    use HTML::Make::Calendar 'calendar';
    use Astro::MoonPhase;
    use Date::Calc 'Date_to_Time';
    my @moons = qw!🌑 🌒 🌓 🌔 🌕 🌖 🌗 🌘!;
    my $cal = calendar (dayc => \&daymoon, cdata => \@moons);
    print $cal->text ();
    exit;
    
    sub daymoon
    {
        my ($moons, $date, $element) = @_;
        my $epochtime = Date_to_Time ($date->{year}, $date->{month},
                                      $date->{dom}, 0, 0, 0);
        my ($phase) = phase ($epochtime);
        my $text = $moons->[int (8*$phase)] . " <b>$date->{dom}</b>";
        $element->add_text ($text);
    }
    

The output HTML looks like this:

March 2021
Mo	Tu	We	Th	Fr	Sa	Su
🌕 1	🌕 2	🌖 3	🌖 4	🌖 5	🌖 6	🌗 7
🌗 8	🌗 9	🌘 10	🌘 11	🌘 12	🌘 13	🌑 14
🌑 15	🌑 16	🌑 17	🌒 18	🌒 19	🌒 20	🌒 21
🌓 22	🌓 23	🌓 24	🌓 25	🌔 26	🌔 27	🌔 28
🌕 29	🌕 30	🌕 31

(This example is included as moon.pl in the distribution.)

Daily menu

This example demonstrates the use of "dayc" and "cdata", and how to add your own HTML into the cells of the calendar.

    use utf8;
    use FindBin '$Bin';
    use HTML::Make::Calendar 'calendar';
    my @foods = split '', <<EOF;
    🍇🍈🍉🍊🍋🍌🍍🥭🍎🍏🍐🍑🍒🍓🥝🍅🥝
    🍅🥒🥬🥦🧄🧅🍄🥜🌰🍘🍙🍚🍛🍜🍝🍠🍢
    🍣🍤🍥🥮🍡🥟🥠🥡🦪🍦🍧🍨🍩🍪🎂🍰🧁
    EOF
    @foods = grep {!/\s/} @foods;
    my $cal = calendar (cdata => \@foods, dayc => \&add_food);
    print $cal->text ();
    exit;
    
    sub add_food
    {
        my ($foods, $date, $element) = @_;
        my $today = 
        $element->push ('span', text => $date->{dom});
        my $menu = HTML::Make->new ('ol');
        for (1..3) {
            my $food = $foods->[int (rand (@$foods))];
            $menu->push ('li', text => $food);
        }
        $element->push ($menu);
    }

The output HTML looks like this:

January 2021
Mo	Tu	We	Th	Fr	Sa	Su
				1 🍍 🍅 🍅	2 🧄 🎂 🌰	3 🍌 🍅 🧄
4 🍪 🧅 🍑	5 🍎 🥦 🍇	6 🍛 🍅 🦪	7 🍓 🍅 🍠	8 🍑 🍝 🍒	9 🍇 🍐 🥝	10 🥠 🍌 🍥
11 🥜 🥜 🍌	12 🍑 🍙 🦪	13 🥮 🍑 🍜	14 🍚 🧁 🍄	15 🍜 🦪 🍚	16 🌰 🍩 🍈	17 🥟 🍦 🌰
18 🍝 🍄 🥮	19 🍅 🍡 🍍	20 🍍 🍋 🍝	21 🥭 🍤 🍢	22 🍜 🍤 🍣	23 🧁 🍒 🍅	24 🍧 🍘 🎂
25 🍰 🍒 🍤	26 🍓 🍑 🍠	27 🍍 🍄 🍧	28 🥠 🍣 🍒	29 🧄 🍓 🧁	30 🥒 🧅 🥡	31 🧄 🥟 🍇

(This example is included as menu.pl in the distribution.)

Japanese calendar

This example shows making a Japanese calendar using "daynames" as well as "monthc" to put the month name into Japanese. It uses Calendar::Japanese::Holiday, Date::Qreki, Lingua::JA::Numbers, and Lingua::JA::FindDates to make various bits of information typically found on Japanese calendars.

    use utf8;
    use HTML::Make::Calendar 'calendar';
    use Date::Qreki 'rokuyou_unicode';
    use Calendar::Japanese::Holiday;
    use Lingua::JA::Numbers 'num2ja';
    use Lingua::JA::FindDates 'seireki_to_nengo';
    my @daynames = (qw!月 火 水 木 金 土 日!);
    my $calendar = calendar (daynames => \@daynames,
                             monthc => \&jmonth,
                             dayc => \&jday, first => 7);
    print $calendar->text ();
    exit;
    
    sub jday
    {
        my (undef, $date, $element) = @_;
        my @jdate = ($date->{year}, $date->{month}, $date->{dom});
        my $name = isHoliday (@jdate);
        my $rokuyou = rokuyou_unicode (@jdate);
        $element->push ('span', text => num2ja ($date->{dom}));
        $element->push ('br');
        $element->push ('span', text => $rokuyou, attr => {class => 'rokuyou'});
        if ($name) {
            $element->push ('br');
            $element->push ('b', text => $name);
            $element->add_class ('holiday');
        }
    }
    
    sub jmonth
    {
        my (undef, $date, $element) = @_;
        my $month = $date->{month} . '月';
        my $year = seireki_to_nengo ("$date->{year}年");
        my $ym = "$year$month";
        $ym =~ s/([0-9]+)/num2ja($1)/ge;
        $element->add_text ($ym);
    }

The output HTML looks like this:

令和三年三月
日	月	火	水	木	金	土
	一 赤口	二 先勝	三 友引	四 先負	五 仏滅	六 大安
七 赤口	八 先勝	九 友引	十 先負	十一 仏滅	十二 大安	十三 友引
十四 先負	十五 仏滅	十六 大安	十七 赤口	十八 先勝	十九 友引	二十 先負 春分の日
二十一 仏滅	二十二 大安	二十三 赤口	二十四 先勝	二十五 友引	二十六 先負	二十七 仏滅
二十八 大安	二十九 赤口	三十 先勝	三十一 友引

(This example is included as japanese.pl in the distribution.)

DEFAULT HTML ELEMENTS AND CSS CLASSES

The elements of the calendar have the following default HTML elements and CSS default style names:

calendar

The default HTML element for calendar (the calendar itself) is <table> with class calendar.

month

The default HTML element for month (a month) is <table> with class cal-month.

week

The default HTML element for week (a week) is <tr> with class cal-week.

day

The default HTML element for day (a day) is <td> with class cal-day as well as class cal-mon, cal-tue, etc.

dow

The default HTML element for dow (the day of the week (Monday, Tuesday, etc.)) is <th> with class cal-dow.

TERMINOLOGY

dow = day of the week (Monday, Tuesday, etc.)

dom = day of the month (1 to 31)

wom = week of the month (corresponds to the rows of the calendar)

DEPENDENCIES

Date::Calc

Date::Calc supplies the date information for the calendar.

HTML::Make

HTML::Make is used to generate the HTML for the calendar.

Table::Readable

Table::Readable is used to read a table of HTML element and CSS class defaults.

SCRIPT

See html-cal in the distribution.

SEE ALSO

Other CPAN modules

Calendar::List

Calendar::Schedule

Calendar::Simple

Date::Calendar

Includes a script cal2html for making HTML.

HTML::Calendar::Monthly

Fork of "HTML::Calendar::Simple". The documentation is largely copy-pasted from that with some alterations.

HTML::Calendar::Simple

HTML::CalendarMonth

HTML::CalendarMonthSimple

SVG::Calendar

Other HTML calendar generators

Python

The defaults of HTML calendar are somewhat based on Python's calendar.HTMLCalendar.

AUTHOR

Ben Bullock, <bkb@cpan.org>

COPYRIGHT & LICENCE

This package and associated files are copyright (C) 2021 Ben Bullock.

You can use, copy, modify and redistribute this package and associated files under the Perl Artistic Licence or the GNU General Public Licence.

cpanm HTML::Make::Calendar

perl -MCPAN -e shell
install HTML::Make::Calendar