NAME

App::GitFind::PathClassMicro.pm - Only the bits of Path::Class used in App::GitFind

SYNOPSIS

This combines pieces of Path::Class::Entity, Path::Class::File, and Path::Class::Dir by Ken Williams. Those are licensed under the same terms as Perl itself. This file is licensed under the Artistic license, and these modifications are believed to be permissible under clause 3(a) of the Artistic License. This file is available for use and modification under the terms of the Artistic License.

Modifications: This file was modified by Christopher White <cxw@cpan.org> to combine files and remove functions I don't use in App::GitFind.

The remainder of the documentation comes from the individual modules. Multiple packages are combined in this file.

NAME

App::GitFind::PathClassMicro::Entity - Base class for files and directories

VERSION

version 0.37

DESCRIPTION

This class is the base class for App::GitFind::PathClassMicro::File and App::GitFind::PathClassMicro::Dir, it is not used directly by callers.

AUTHOR

Ken Williams, kwilliams@cpan.org

SEE ALSO

Path::Class

NAME

App::GitFind::PathClassMicro::File - Objects representing files

VERSION

version 0.37

SYNOPSIS

  use App::GitFind::PathClassMicro;  # Exports file() by default

  my $file = file('foo', 'bar.txt');  # App::GitFind::PathClassMicro::File object
  my $file = App::GitFind::PathClassMicro::File->new('foo', 'bar.txt'); # Same thing

  # Stringifies to 'foo/bar.txt' on Unix, 'foo\bar.txt' on Windows, etc.
  print "file: $file\n";

  if ($file->is_absolute) { ... }
  if ($file->is_relative) { ... }

  my $v = $file->volume; # Could be 'C:' on Windows, empty string
                         # on Unix, 'Macintosh HD:' on Mac OS

  $file->cleanup; # Perform logical cleanup of pathname
  $file->resolve; # Perform physical cleanup of pathname

  my $dir = $file->dir;  # A App::GitFind::PathClassMicro::Dir object

  my $abs = $file->absolute; # Transform to absolute path
  my $rel = $file->relative; # Transform to relative path

DESCRIPTION

The App::GitFind::PathClassMicro::File class contains functionality for manipulating file names in a cross-platform way.

METHODS

$file = App::GitFind::PathClassMicro::File->new( <dir1>, <dir2>, ..., <file> )
$file = file( <dir1>, <dir2>, ..., <file> )

Creates a new App::GitFind::PathClassMicro::File object and returns it. The arguments specify the path to the file. Any volume may also be specified as the first argument, or as part of the first argument. You can use platform-neutral syntax:

  my $file = file( 'foo', 'bar', 'baz.txt' );

or platform-native syntax:

  my $file = file( 'foo/bar/baz.txt' );

or a mixture of the two:

  my $file = file( 'foo/bar', 'baz.txt' );

All three of the above examples create relative paths. To create an absolute path, either use the platform native syntax for doing so:

  my $file = file( '/var/tmp/foo.txt' );

or use an empty string as the first argument:

  my $file = file( '', 'var', 'tmp', 'foo.txt' );

If the second form seems awkward, that's somewhat intentional - paths like /var/tmp or \Windows aren't cross-platform concepts in the first place, so they probably shouldn't appear in your code if you're trying to be cross-platform. The first form is perfectly fine, because paths like this may come from config files, user input, or whatever.

$file->stringify

This method is called internally when a App::GitFind::PathClassMicro::File object is used in a string context, so the following are equivalent:

  $string = $file->stringify;
  $string = "$file";
$file->volume

Returns the volume (e.g. C: on Windows, Macintosh HD: on Mac OS, etc.) of the object, if any. Otherwise, returns the empty string.

$file->basename

Returns the name of the file as a string, without the directory portion (if any).

$file->components

Returns a list of the directory components of this file, followed by the basename.

Note: unlike $dir->components, this method currently does not accept any arguments to select which elements of the list will be returned. It may do so in the future. Currently it throws an exception if such arguments are present.

$file->is_dir

Returns a boolean value indicating whether this object represents a directory. Not surprisingly, App::GitFind::PathClassMicro::File objects always return false, and App::GitFind::PathClassMicro::Dir objects always return true.

$file->is_absolute

Returns true or false depending on whether the file refers to an absolute path specifier (like /usr/local/foo.txt or \Windows\Foo.txt).

$file->is_relative

Returns true or false depending on whether the file refers to a relative path specifier (like lib/foo.txt or .\Foo.txt).

$file->cleanup

Performs a logical cleanup of the file path. For instance:

  my $file = file('/foo//baz/./foo.txt')->cleanup;
  # $file now represents '/foo/baz/foo.txt';
$dir->resolve

Performs a physical cleanup of the file path. For instance:

  my $file = file('/foo/baz/../foo.txt')->resolve;
  # $file now represents '/foo/foo.txt', assuming no symlinks

This actually consults the filesystem to verify the validity of the path.

$dir = $file->dir

Returns a App::GitFind::PathClassMicro::Dir object representing the directory containing this file.

$dir = $file->parent

A synonym for the dir() method.

$abs = $file->absolute

Returns a App::GitFind::PathClassMicro::File object representing $file as an absolute path. An optional argument, given as either a string or a App::GitFind::PathClassMicro::Dir object, specifies the directory to use as the base of relativity - otherwise the current working directory will be used.

$rel = $file->relative

Returns a App::GitFind::PathClassMicro::File object representing $file as a relative path. An optional argument, given as either a string or a App::GitFind::PathClassMicro::Dir object, specifies the directory to use as the base of relativity - otherwise the current working directory will be used.

$foreign = $file->as_foreign($type)

Returns a App::GitFind::PathClassMicro::File object representing $file as it would be specified on a system of type $type. Known types include Unix, Win32, Mac, VMS, and OS2, i.e. anything for which there is a subclass of File::Spec.

Any generated objects (subdirectories, files, parents, etc.) will also retain this type.

$foreign = App::GitFind::PathClassMicro::File->new_foreign($type, @args)

Returns a App::GitFind::PathClassMicro::File object representing a file as it would be specified on a system of type $type. Known types include Unix, Win32, Mac, VMS, and OS2, i.e. anything for which there is a subclass of File::Spec.

The arguments in @args are the same as they would be specified in new().

$fh = $file->open($mode, $permissions)

Passes the given arguments, including $file, to IO::File->new (which in turn calls IO::File->open and returns the result as an IO::File object. If the opening fails, undef is returned and $! is set.

$fh = $file->openr()

A shortcut for

 $fh = $file->open('r') or croak "Can't read $file: $!";
$fh = $file->openw()

A shortcut for

 $fh = $file->open('w') or croak "Can't write to $file: $!";
$fh = $file->opena()

A shortcut for

 $fh = $file->open('a') or croak "Can't append to $file: $!";
$file->touch

Sets the modification and access time of the given file to right now, if the file exists. If it doesn't exist, touch() will make it exist, and - YES! - set its modification and access time to now.

$file->slurp()

In a scalar context, returns the contents of $file in a string. In a list context, returns the lines of $file (according to how $/ is set) as a list. If the file can't be read, this method will throw an exception.

If you want chomp() run on each line of the file, pass a true value for the chomp or chomped parameters:

  my @lines = $file->slurp(chomp => 1);

You may also use the iomode parameter to pass in an IO mode to use when opening the file, usually IO layers (though anything accepted by the MODE argument of open() is accepted here). Just make sure it's a reading mode.

  my @lines = $file->slurp(iomode => ':crlf');
  my $lines = $file->slurp(iomode => '<:encoding(UTF-8)');

The default iomode is r.

Lines can also be automatically split, mimicking the perl command-line option -a by using the split parameter. If this parameter is used, each line will be returned as an array ref.

    my @lines = $file->slurp( chomp => 1, split => qr/\s*,\s*/ );

The split parameter can only be used in a list context.

$file->spew( $content );

The opposite of "slurp", this takes a list of strings and prints them to the file in write mode. If the file can't be written to, this method will throw an exception.

The content to be written can be either an array ref or a plain scalar. If the content is an array ref then each entry in the array will be written to the file.

You may use the iomode parameter to pass in an IO mode to use when opening the file, just like "slurp" supports.

  $file->spew(iomode => '>:raw', $content);

The default iomode is w.

$file->spew_lines( $content );

Just like spew, but, if $content is a plain scalar, appends $/ to it, or, if $content is an array ref, appends $/ to each element of the array.

Can also take an iomode parameter like spew. Again, the default iomode is w.

$file->traverse(sub { ... }, @args)

Calls the given callback on $file. This doesn't do much on its own, but see the associated documentation in App::GitFind::PathClassMicro::Dir.

$file->remove()

This method will remove the file in a way that works well on all platforms, and returns a boolean value indicating whether or not the file was successfully removed.

remove() is better than simply calling Perl's unlink() function, because on some platforms (notably VMS) you actually may need to call unlink() several times before all versions of the file are gone - the remove() method handles this process for you.

$st = $file->stat()

Invokes File::stat::stat() on this file and returns a File::stat object representing the result.

MODIFIED: returns an arrayref of stat() results.

$st = $file->lstat()

Same as stat(), but if $file is a symbolic link, lstat() stats the link instead of the file the link points to.

MODIFIED: returns an arrayref of lstat() results.

$class = $file->dir_class()

Returns the class which should be used to create directory objects.

Generally overridden whenever this class is subclassed.

$copy = $file->copy_to( $dest );

Copies the $file to $dest. It returns a App::GitFind::PathClassMicro::File object when successful, undef otherwise.

$moved = $file->move_to( $dest );

Moves the $file to $dest, and updates $file accordingly.

It returns $file is successful, undef otherwise.

AUTHOR

Ken Williams, kwilliams@cpan.org

SEE ALSO

Path::Class, Path::Class::Dir, File::Spec

sub tempfile { my $self = shift; return File::Temp::tempfile(@_, DIR => $self->stringify); }

NAME

App::GitFind::PathClassMicro::Dir - Objects representing directories

VERSION

version 0.37

SYNOPSIS

  use App::GitFind::PathClassMicro;  # Exports dir() by default

  my $dir = dir('foo', 'bar');       # App::GitFind::PathClassMicro::Dir object
  my $dir = App::GitFind::PathClassMicro::Dir->new('foo', 'bar');  # Same thing

  # Stringifies to 'foo/bar' on Unix, 'foo\bar' on Windows, etc.
  print "dir: $dir\n";

  if ($dir->is_absolute) { ... }
  if ($dir->is_relative) { ... }

  my $v = $dir->volume; # Could be 'C:' on Windows, empty string
                        # on Unix, 'Macintosh HD:' on Mac OS

  $dir->cleanup; # Perform logical cleanup of pathname
  $dir->resolve; # Perform physical cleanup of pathname

  my $file = $dir->file('file.txt'); # A file in this directory
  my $subdir = $dir->subdir('george'); # A subdirectory
  my $parent = $dir->parent; # The parent directory, 'foo'

  my $abs = $dir->absolute; # Transform to absolute path
  my $rel = $abs->relative; # Transform to relative path
  my $rel = $abs->relative('/foo'); # Relative to /foo

  print $dir->as_foreign('Mac');   # :foo:bar:
  print $dir->as_foreign('Win32'); #  foo\bar

  # Iterate with IO::Dir methods:
  my $handle = $dir->open;
  while (my $file = $handle->read) {
    $file = $dir->file($file);  # Turn into App::GitFind::PathClassMicro::File object
    ...
  }

  # Iterate with App::GitFind::PathClassMicro methods:
  while (my $file = $dir->next) {
    # $file is a App::GitFind::PathClassMicro::File or App::GitFind::PathClassMicro::Dir object
    ...
  }

DESCRIPTION

The App::GitFind::PathClassMicro::Dir class contains functionality for manipulating directory names in a cross-platform way.

METHODS

$dir = App::GitFind::PathClassMicro::Dir->new( <dir1>, <dir2>, ... )
$dir = dir( <dir1>, <dir2>, ... )

Creates a new App::GitFind::PathClassMicro::Dir object and returns it. The arguments specify names of directories which will be joined to create a single directory object. A volume may also be specified as the first argument, or as part of the first argument. You can use platform-neutral syntax:

  my $dir = dir( 'foo', 'bar', 'baz' );

or platform-native syntax:

  my $dir = dir( 'foo/bar/baz' );

or a mixture of the two:

  my $dir = dir( 'foo/bar', 'baz' );

All three of the above examples create relative paths. To create an absolute path, either use the platform native syntax for doing so:

  my $dir = dir( '/var/tmp' );

or use an empty string as the first argument:

  my $dir = dir( '', 'var', 'tmp' );

If the second form seems awkward, that's somewhat intentional - paths like /var/tmp or \Windows aren't cross-platform concepts in the first place (many non-Unix platforms don't have a notion of a "root directory"), so they probably shouldn't appear in your code if you're trying to be cross-platform. The first form is perfectly natural, because paths like this may come from config files, user input, or whatever.

As a special case, since it doesn't otherwise mean anything useful and it's convenient to define this way, App::GitFind::PathClassMicro::Dir->new() (or dir()) refers to the current directory (File::Spec->curdir). To get the current directory as an absolute path, do dir()->absolute.

Finally, as another special case dir(undef) will return undef, since that's usually an accident on the part of the caller, and returning the root directory would be a nasty surprise just asking for trouble a few lines later.

$dir->stringify

This method is called internally when a App::GitFind::PathClassMicro::Dir object is used in a string context, so the following are equivalent:

  $string = $dir->stringify;
  $string = "$dir";
$dir->volume

Returns the volume (e.g. C: on Windows, Macintosh HD: on Mac OS, etc.) of the directory object, if any. Otherwise, returns the empty string.

$dir->basename

Returns the last directory name of the path as a string.

$dir->is_dir

Returns a boolean value indicating whether this object represents a directory. Not surprisingly, App::GitFind::PathClassMicro::File objects always return false, and App::GitFind::PathClassMicro::Dir objects always return true.

$dir->is_absolute

Returns true or false depending on whether the directory refers to an absolute path specifier (like /usr/local or \Windows).

$dir->is_relative

Returns true or false depending on whether the directory refers to a relative path specifier (like lib/foo or ./dir).

$dir->cleanup

Performs a logical cleanup of the file path. For instance:

  my $dir = dir('/foo//baz/./foo')->cleanup;
  # $dir now represents '/foo/baz/foo';
$dir->resolve

Performs a physical cleanup of the file path. For instance:

  my $dir = dir('/foo//baz/../foo')->resolve;
  # $dir now represents '/foo/foo', assuming no symlinks

This actually consults the filesystem to verify the validity of the path.

$file = $dir->file( <dir1>, <dir2>, ..., <file> )

Returns a App::GitFind::PathClassMicro::File object representing an entry in $dir or one of its subdirectories. Internally, this just calls App::GitFind::PathClassMicro::File->new( @_ ).

$subdir = $dir->subdir( <dir1>, <dir2>, ... )

Returns a new App::GitFind::PathClassMicro::Dir object representing a subdirectory of $dir.

$parent = $dir->parent

Returns the parent directory of $dir. Note that this is the logical parent, not necessarily the physical parent. It really means we just chop off entries from the end of the directory list until we cain't chop no more. If the directory is relative, we start using the relative forms of parent directories.

The following code demonstrates the behavior on absolute and relative directories:

  $dir = dir('/foo/bar');
  for (1..6) {
    print "Absolute: $dir\n";
    $dir = $dir->parent;
  }

  $dir = dir('foo/bar');
  for (1..6) {
    print "Relative: $dir\n";
    $dir = $dir->parent;
  }

  ########### Output on Unix ################
  Absolute: /foo/bar
  Absolute: /foo
  Absolute: /
  Absolute: /
  Absolute: /
  Absolute: /
  Relative: foo/bar
  Relative: foo
  Relative: .
  Relative: ..
  Relative: ../..
  Relative: ../../..
@list = $dir->children

Returns a list of App::GitFind::PathClassMicro::File and/or App::GitFind::PathClassMicro::Dir objects listed in this directory, or in scalar context the number of such objects. Obviously, it is necessary for $dir to exist and be readable in order to find its children.

Note that the children are returned as subdirectories of $dir, i.e. the children of foo will be foo/bar and foo/baz, not bar and baz.

Ordinarily children() will not include the self and parent entries . and .. (or their equivalents on non-Unix systems), because that's like I'm-my-own-grandpa business. If you do want all directory entries including these special ones, pass a true value for the all parameter:

  @c = $dir->children(); # Just the children
  @c = $dir->children(all => 1); # All entries

In addition, there's a no_hidden parameter that will exclude all normally "hidden" entries - on Unix this means excluding all entries that begin with a dot (.):

  @c = $dir->children(no_hidden => 1); # Just normally-visible entries
$abs = $dir->absolute

Returns a App::GitFind::PathClassMicro::Dir object representing $dir as an absolute path. An optional argument, given as either a string or a App::GitFind::PathClassMicro::Dir object, specifies the directory to use as the base of relativity - otherwise the current working directory will be used.

$rel = $dir->relative

Returns a App::GitFind::PathClassMicro::Dir object representing $dir as a relative path. An optional argument, given as either a string or a App::GitFind::PathClassMicro::Dir object, specifies the directory to use as the base of relativity - otherwise the current working directory will be used.

$boolean = $dir->subsumes($other)

Returns true if this directory spec subsumes the other spec, and false otherwise. Think of "subsumes" as "contains", but we only look at the specs, not whether $dir actually contains $other on the filesystem.

The $other argument may be a App::GitFind::PathClassMicro::Dir object, a App::GitFind::PathClassMicro::File object, or a string. In the latter case, we assume it's a directory.

  # Examples:
  dir('foo/bar' )->subsumes(dir('foo/bar/baz'))  # True
  dir('/foo/bar')->subsumes(dir('/foo/bar/baz')) # True
  dir('foo/..')->subsumes(dir('foo/../bar))      # True
  dir('foo/bar' )->subsumes(dir('bar/baz'))      # False
  dir('/foo/bar')->subsumes(dir('foo/bar'))      # False
  dir('foo/..')->subsumes(dir('bar'))            # False! Use C<contains> to resolve ".."
$boolean = $dir->contains($other)

Returns true if this directory actually contains $other on the filesystem. $other doesn't have to be a direct child of $dir, it just has to be subsumed after both paths have been resolved.

$foreign = $dir->as_foreign($type)

Returns a App::GitFind::PathClassMicro::Dir object representing $dir as it would be specified on a system of type $type. Known types include Unix, Win32, Mac, VMS, and OS2, i.e. anything for which there is a subclass of File::Spec.

Any generated objects (subdirectories, files, parents, etc.) will also retain this type.

$foreign = App::GitFind::PathClassMicro::Dir->new_foreign($type, @args)

Returns a App::GitFind::PathClassMicro::Dir object representing $dir as it would be specified on a system of type $type. Known types include Unix, Win32, Mac, VMS, and OS2, i.e. anything for which there is a subclass of File::Spec.

The arguments in @args are the same as they would be specified in new().

@list = $dir->dir_list([OFFSET, [LENGTH]])

Returns the list of strings internally representing this directory structure. Each successive member of the list is understood to be an entry in its predecessor's directory list. By contract, App::GitFind::PathClassMicro->new( $dir->dir_list ) should be equivalent to $dir.

The semantics of this method are similar to Perl's splice or substr functions; they return LENGTH elements starting at OFFSET. If LENGTH is omitted, returns all the elements starting at OFFSET up to the end of the list. If LENGTH is negative, returns the elements from OFFSET onward except for -LENGTH elements at the end. If OFFSET is negative, it counts backward OFFSET elements from the end of the list. If OFFSET and LENGTH are both omitted, the entire list is returned.

In a scalar context, dir_list() with no arguments returns the number of entries in the directory list; dir_list(OFFSET) returns the single element at that offset; dir_list(OFFSET, LENGTH) returns the final element that would have been returned in a list context.

$dir->components

Identical to dir_list(). It exists because there's an analogous method dir_list() in the App::GitFind::PathClassMicro::File class that also returns the basename string, so this method lets someone call components() without caring whether the object is a file or a directory.

(REMOVED) $fh = $dir->open()

Passes $dir to IO::Dir->open and returns the result as an IO::Dir object. If the opening fails, undef is returned and $! is set.

(REMOVED) $dir->mkpath($verbose, $mode)

Passes all arguments, including $dir, to File::Path::mkpath() and returns the result (a list of all directories created).

(REMOVED) $dir->rmtree($verbose, $cautious)

Passes all arguments, including $dir, to File::Path::rmtree() and returns the result (the number of files successfully deleted).

$dir->remove()

Removes the directory, which must be empty. Returns a boolean value indicating whether or not the directory was successfully removed. This method is mainly provided for consistency with App::GitFind::PathClassMicro::File's remove() method.

(REMOVED) $dir->tempfile(...)

An interface to File::Temp's tempfile() function. Just like that function, if you call this in a scalar context, the return value is the filehandle and the file is unlinked as soon as possible (which is immediately on Unix-like platforms). If called in a list context, the return values are the filehandle and the filename.

The given directory is passed as the DIR parameter.

Here's an example of pretty good usage which doesn't allow race conditions, won't leave yucky tempfiles around on your filesystem, etc.:

  my $fh = $dir->tempfile;
  print $fh "Here's some data...\n";
  seek($fh, 0, 0);
  while (<$fh>) { do something... }

Or in combination with a fork:

  my $fh = $dir->tempfile;
  print $fh "Here's some more data...\n";
  seek($fh, 0, 0);
  if ($pid=fork()) {
    wait;
  } else {
    something($_) while <$fh>;
  }
$dir_or_file = $dir->next()

A convenient way to iterate through directory contents. The first time next() is called, it will open() the directory and read the first item from it, returning the result as a App::GitFind::PathClassMicro::Dir or App::GitFind::PathClassMicro::File object (depending, of course, on its actual type). Each subsequent call to next() will simply iterate over the directory's contents, until there are no more items in the directory, and then the undefined value is returned. For example, to iterate over all the regular files in a directory:

  while (my $file = $dir->next) {
    next unless -f $file;
    my $fh = $file->open('r') or die "Can't read $file: $!";
    ...
  }

If an error occurs when opening the directory (for instance, it doesn't exist or isn't readable), next() will throw an exception with the value of $!.

$dir->traverse( sub { ... }, @args )

Calls the given callback for the root, passing it a continuation function which, when called, will call this recursively on each of its children. The callback function should be of the form:

  sub {
    my ($child, $cont, @args) = @_;
    # ...
  }

For instance, to calculate the number of files in a directory, you can do this:

  my $nfiles = $dir->traverse(sub {
    my ($child, $cont) = @_;
    return sum($cont->(), ($child->is_dir ? 0 : 1));
  });

or to calculate the maximum depth of a directory:

  my $depth = $dir->traverse(sub {
    my ($child, $cont, $depth) = @_;
    return max($cont->($depth + 1), $depth);
  }, 0);

You can also choose not to call the callback in certain situations:

  $dir->traverse(sub {
    my ($child, $cont) = @_;
    return if -l $child; # don't follow symlinks
    # do something with $child
    return $cont->();
  });
$dir->traverse_if( sub { ... }, sub { ... }, @args )

traverse with additional "should I visit this child" callback. Particularly useful in case examined tree contains inaccessible directories.

Canonical example:

  $dir->traverse_if(
    sub {
       my ($child, $cont) = @_;
       # do something with $child
       return $cont->();
    },
    sub {
       my ($child) = @_;
       # Process only readable items
       return -r $child;
    });

Second callback gets single parameter: child. Only children for which it returns true will be processed by the first callback.

Remaining parameters are interpreted as in traverse, in particular traverse_if(callback, sub { 1 }, @args is equivalent to traverse(callback, @args).

$dir->recurse( callback => sub {...} )

Iterates through this directory and all of its children, and all of its children's children, etc., calling the callback subroutine for each entry. This is a lot like what the File::Find module does, and of course File::Find will work fine on App::GitFind::PathClassMicro objects, but the advantage of the recurse() method is that it will also feed your callback routine App::GitFind::PathClassMicro objects rather than just pathname strings.

The recurse() method requires a callback parameter specifying the subroutine to invoke for each entry. It will be passed the App::GitFind::PathClassMicro object as its first argument.

recurse() also accepts two boolean parameters, depthfirst and preorder that control the order of recursion. The default is a preorder, breadth-first search, i.e. depthfirst => 0, preorder => 1. At the time of this writing, all combinations of these two parameters are supported except depthfirst => 0, preorder => 0.

callback is normally not required to return any value. If it returns special constant App::GitFind::PathClassMicro::Entity::PRUNE() (more easily available as $item->PRUNE), no children of analyzed item will be analyzed (mostly as if you set $File::Find::prune=1). Of course pruning is available only in preorder, in postorder return value has no effect.

$st = $file->stat()

Invokes File::stat::stat() on this directory and returns a File::stat object representing the result.

MODIFIED: returns an arrayref of stat() results.

$st = $file->lstat()

Same as stat(), but if $file is a symbolic link, lstat() stats the link instead of the directory the link points to.

MODIFIED: returns an arrayref of lstat() results.

$class = $file->file_class()

Returns the class which should be used to create file objects.

Generally overridden whenever this class is subclassed.

AUTHOR

Ken Williams, kwilliams@cpan.org

SEE ALSO

Path::Class, Path::Class::File, File::Spec