++ed by:
AWNCORP CARWASH DAVIDO DRAEGTUN EGOR

12 PAUSE user(s)
5 non-PAUSE user(s).

Mario Roy

NAME

MCE::Map - Parallel map model similar to the native map function

VERSION

This document describes MCE::Map version 1.514

SYNOPSIS

   ## Exports mce_map, mce_map_f, and mce_map_s
   use MCE::Map;

   ## Array or array_ref
   my @a = mce_map { $_ * $_ } 1..10000;
   my @b = mce_map { $_ * $_ } [ 1..10000 ];

   ## File_path, glob_ref, or scalar_ref
   my @c = mce_map_f { chomp; $_ } "/path/to/file";
   my @d = mce_map_f { chomp; $_ } $file_handle;
   my @e = mce_map_f { chomp; $_ } \$scalar;

   ## Sequence of numbers (begin, end [, step, format])
   my @f = mce_map_s { $_ * $_ } 1, 10000, 5;
   my @g = mce_map_s { $_ * $_ } [ 1, 10000, 5 ];

   my @h = mce_map_s { $_ * $_ } {
      begin => 1, end => 10000, step => 5, format => undef
   };

DESCRIPTION

This module provides a parallel map implementation via Many-core Engine. MCE incurs a small overhead due to passing of data. Therefore, a fast code block will likely run faster using the native map function in Perl. The overhead quickly diminishes as the complexity of the code block increases.

   my @m1 =     map { $_ * $_ } 1..1000000;               ## 0.251 secs
   my @m2 = mce_map { $_ * $_ } 1..1000000;               ## 0.525 secs

Chunking, enabled by default, greatly reduces the overhead behind the scene. The time for mce_map below also includes the time for data exchanges between the manager and worker processes. More parallelization will be seen when the code block requires additional CPU time code-wise.

   sub calc {
      sqrt $_ * sqrt $_ / 1.3 * 1.5 / 3.2 * 1.07
   }

   my @m1 =     map { calc } 1..1000000;                  ## 0.756 secs
   my @m2 = mce_map { calc } 1..1000000;                  ## 0.623 secs

The mce_map_s function will provide better times, useful when the input data is simply a range of numbers. Workers generate sequences mathematically among themselves without any interaction from the manager process. Two arguments are required for mce_map_s (begin, end). Step defaults to 1 if begin is smaller than end, otherwise -1.

   my @m3 = mce_map_s { calc } 1, 1000000;                ## 0.517 secs

Although this document is about MCE::Map, the MCE::Stream module can write results immediately without waiting for all chunks to complete. This is made possible by passing the reference of the array (in this case @m4 and @m5).

   use MCE::Stream;

   sub calc {
      sqrt $_ * sqrt $_ / 1.3 * 1.5 / 3.2 * 1.07
   }

   my @m4; mce_stream \@m4, sub { calc }, 1..1000000;

      ## Completes in 0.436 secs. That is amazing considering the
      ## overhead for passing data between the manager and worker.

   my @m5; mce_stream_s \@m5, sub { calc }, 1, 1000000;

      ## Completed in 0.301 secs. Like with mce_map_s, specifying a
      ## sequence specification turns out to be faster due to lesser
      ## overhead for the manager process.

OVERRIDING DEFAULTS

The following list 5 options which may be overridden when loading the module.

   use Sereal qw(encode_sereal decode_sereal);

   use MCE::Map
         max_workers => 4,                    ## Default 'auto'
         chunk_size  => 100,                  ## Default 'auto'
         tmp_dir     => "/path/to/app/tmp",   ## $MCE::Signal::tmp_dir
         freeze      => \&encode_sereal,      ## \&Storable::freeze
         thaw        => \&decode_sereal       ## \&Storable::thaw
   ;

There is a simpler way to enable Sereal with MCE 1.5. The following will attempt to use Sereal if available, otherwise will default back to using Storable for serialization.

   use MCE::Map Sereal => 1;

   ## Serialization is through Sereal if available.
   my @m2 = mce_map { $_ * $_ } 1..10000;

CUSTOMIZING MCE

init

The init function accepts a hash of MCE options. The gather option, if specified, will be set to undef due to being used internally by the module.

   use MCE::Map;

   MCE::Map::init {
      chunk_size => 1, max_workers => 4,

      user_begin => sub {
         print "## ", MCE->wid, " started\n";
      },

      user_end => sub {
         print "## ", MCE->wid, " completed\n";
      }
   };

   my @a = mce_map { $_ * $_ } 1..100;

   print "\n", "@a", "\n";

   -- Output

   ## 2 started
   ## 1 started
   ## 3 started
   ## 4 started
   ## 1 completed
   ## 4 completed
   ## 2 completed
   ## 3 completed

   1 4 9 16 25 36 49 64 81 100 121 144 169 196 225 256 289 324 361
   400 441 484 529 576 625 676 729 784 841 900 961 1024 1089 1156
   1225 1296 1369 1444 1521 1600 1681 1764 1849 1936 2025 2116 2209
   2304 2401 2500 2601 2704 2809 2916 3025 3136 3249 3364 3481 3600
   3721 3844 3969 4096 4225 4356 4489 4624 4761 4900 5041 5184 5329
   5476 5625 5776 5929 6084 6241 6400 6561 6724 6889 7056 7225 7396
   7569 7744 7921 8100 8281 8464 8649 8836 9025 9216 9409 9604 9801
   10000

API DOCUMENTATION

mce_map { code } list

Input data can be defined using a list or passing a reference to an array.

   my @a = mce_map { $_ * 2 } 1..1000;
   my @b = mce_map { $_ * 2 } [ 1..1000 ];
mce_map_f { code } file

The fastest of these is the /path/to/file. Workers communicate the next offset position among themselves without any interaction from the manager process.

   my @c = mce_map_f { chomp; $_ . "\r\n" } "/path/to/file";
   my @d = mce_map_f { chomp; $_ . "\r\n" } $file_handle;
   my @e = mce_map_f { chomp; $_ . "\r\n" } \$scalar;
mce_map_s { code } sequence

Sequence can be defined as a list, an array reference, or a hash reference. The functions require both begin and end values to run. Step and format are optional. The format is passed to sprintf (% may be omitted below).

   my ($beg, $end, $step, $fmt) = (10, 20, 0.1, "%4.1f");

   my @f = mce_map_s { $_ } $beg, $end, $step, $fmt;
   my @g = mce_map_s { $_ } [ $beg, $end, $step, $fmt ];

   my @h = mce_map_s { $_ } {
      begin => $beg, end => $end, step => $step, format => $fmt
   };
mce_map { code } iterator

An iterator reference can by specified for input data. Iterators are described under "SYNTAX for INPUT_DATA" at MCE::Core.

   my @a = mce_map { $_ * 2 } make_iterator(10, 30, 2);

MANUAL SHUTDOWN

finish

MCE workers remain persistent as much as possible after running. Shutdown occurs when the script exits. One can manually shutdown MCE by simply calling finish after running. This resets the MCE instance.

   use MCE::Map;

   MCE::Map::init {
      chunk_size => 20, max_workers => 'auto'
   };

   my @a = mce_map { ... } 1..100;

   MCE::Map::finish;

INDEX

MCE

AUTHOR

Mario E. Roy, <marioeroy AT gmail DOT com>

LICENSE

This program is free software; you can redistribute it and/or modify it under the terms of either: the GNU General Public License as published by the Free Software Foundation; or the Artistic License.

See http://dev.perl.org/licenses/ for more information.




Hosting generously
sponsored by Bytemark