/ 
Meow-0.18
River stage zero No dependents
/ Meow

NAME

Meow - Object ฅ^•ﻌ•^ฅ Orientation

VERSION

Version 0.18

SYNOPSIS

This module is experimental. Many basic features do not yet exist.

package Cat;

use Meow;
use Basic::Types::XS qw/Str Num/;

ro name => Str;

rw age => Default(Num, 0);

1;

...

package Siberian;

use Meow;

extends qw/Cat/;

1;

...

my $cat = Siberian->new(
	name => 'Simba',
	age => 10
);

$cat->name; # Simba;
$cat->age; # 10;

$cat->age(11);

DESCRIPTION

Meow provides a fast, minimalist object system in XS, supporting:

  • Read-write (rw) and read-only (ro) attributes

  • Attribute specification with a Type, Default, Coerce, Trigger, and Builder

  • Multiple inheritance via extends

  • Perl-style constructor (new)

EXPORTS

rw $name, $spec

Defines a read-write attribute.

ro $name, $spec

Defines a read-only attribute.

Default $spec, $value

Sets a default value for an attribute.

Coerce $spec, $coderef

Sets a coercion coderef for an attribute.

Trigger $spec, $coderef

Sets a trigger coderef to be called when the attribute is set.

Builder $spec, $coderef

Sets a builder coderef for lazy attribute construction.

extends @parents

Adds one or more parent classes to @ISA and copies their attribute specs.

new %args

Constructs a new object, applying defaults, coercions, triggers, and builders as specified.

BENCHMARK

{
	package Foo::Mouse;

	use Mouse;
	use Types::Standard qw/Str Num/;

	has one => (
		is => 'ro',
		isa => Str,
		default => sub { 100 },
	);

	has two => (
		is => 'ro',
		isa => Num,
		default => sub { 200 },
	);

	1;
}

{
	package Foo::Extends::Mouse;

	use Mouse;
	extends qw/Foo::Mouse/;

	1;
}


{
	package Foo::Moo;

	use Moo;
	use Types::Standard qw/Str Num/;

	has one => (
		is => 'ro',
		isa => Str,
		default => sub { 100 },
	);

	has two => (
		is => 'ro',
		isa => Num,
		default => sub { 200 },
	);

	1;
}

{
	package Foo::Extends::Moo;

	use Moo;
	extends qw/Foo::Moo/;

	1;
}

{
	package Foo::Meow;
	use Meow;
	use Basic::Types::XS qw/Str Num/;

	ro one => Default(Str, 100);

	ro two => Default(Num, 200);

	1;
}


{
	package Foo::Extends::Meow;

	use Meow;
	extends qw/Foo::Meow/;

	1;
}

{
	package Foo::Marlin;
	use Types::Common -lexical, qw/Int/;
	use Marlin
		'one' => { isa => Int, default => 100 },
		'two' => { isa => Int, default => 200 };

	1;
}


{
	package Foo::Extends::Marlin;

	use Marlin
		-extends => [qw/Foo::Marlin/];

	1;
}


my $r = timethese(5000000, {
	'Moo' => sub {
		my $foo = Foo::Extends::Moo->new();
		$foo->one;
		$foo->two;
	},
	'Meow' => sub {
		my $foo = Foo::Extends::Meow->new();
		$foo->one;
		$foo->two;
	},
	'Mouse' => sub {
		my $foo = Foo::Extends::Mouse->new();
		$foo->one;
		$foo->two;
	},
	'Marlin' => sub {
		my $foo = Foo::Extends::Marlin->new();
		$foo->one;
		$foo->two;
	}
});

cmpthese $r;

...

Benchmark: timing 5000000 iterations of Cor, Marlin, Meow, Moo, Mouse...
       Cor:  0 wallclock secs ( 1.72 usr +  0.00 sys =  1.72 CPU) @ 2906976.74/s (n=5000000)
    Marlin:  0 wallclock secs ( 1.06 usr +  0.02 sys =  1.08 CPU) @ 4629629.63/s (n=5000000)
      Meow:  1 wallclock secs ( 1.08 usr +  0.00 sys =  1.08 CPU) @ 4629629.63/s (n=5000000)
       Moo:  6 wallclock secs ( 5.79 usr +  0.03 sys =  5.82 CPU) @ 859106.53/s (n=5000000)
     Mouse:  4 wallclock secs ( 3.12 usr +  0.01 sys =  3.13 CPU) @ 1597444.09/s (n=5000000)
	    Rate    Moo  Mouse    Cor Marlin   Meow
Moo     859107/s     --   -46%   -70%   -81%   -81%
Mouse  1597444/s    86%     --   -45%   -65%   -65%
Cor    2906977/s   238%    82%     --   -37%   -37%
Marlin 4629630/s   439%   190%    59%     --    -0%
Meow   4629630/s   439%   190%    59%     0%     --

Note: Type::Tiny::XS is installed and so is the other optional XS dependancies for Moo.

The limitation is now my hardware with Marlin and Meow.

Benchmark: running Cor, Marlin, Meow for at least 5 CPU seconds...
       Cor:  5 wallclock secs ( 5.13 usr +  0.02 sys =  5.15 CPU) @ 2886788.16/s (n=14866959)
    Marlin:  5 wallclock secs ( 5.01 usr +  0.11 sys =  5.12 CPU) @ 4523074.80/s (n=23158143)
      Meow:  5 wallclock secs ( 5.16 usr +  0.02 sys =  5.18 CPU) @ 4558344.59/s (n=23612225)

AUTHOR

LNATION, <email at lnation.org>

BUGS

Please report any bugs or feature requests to bug-meow at rt.cpan.org, or through the web interface at https://rt.cpan.org/NoAuth/ReportBug.html?Queue=Meow. I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.

SUPPORT

You can find documentation for this module with the perldoc command.

perldoc Meow

You can also look for information at:

ACKNOWLEDGEMENTS

LICENSE AND COPYRIGHT

This software is Copyright (c) 2025 by LNATION.

This is free software, licensed under:

The Artistic License 2.0 (GPL Compatible)