NAME

ClearCase::Argv - ClearCase-specific subclass of Argv

SYNOPSIS

    # OO interface
    use ClearCase::Argv;
    ClearCase::Argv->dbglevel(1);
    # Note how the command, flags, and arguments are separated ...
    my $describe = ClearCase::Argv->new('desc', [qw(-fmt %c)], ".");
    # Run the basic "ct describe" command.
    $describe->system;
    # Run it with with stderr turned off.
    $describe->stderr(0)->system;
    # Run it without the flags.
    $describe->system(-);
    # Create label type XX iff it doesn't exist
    ClearCase::Argv->new(qw(mklbtype -nc XX))
            if ClearCase::Argv->new(qw(lstype lbtype:XX))->stderr(0)->qx;

    # Functional interface
    use ClearCase::Argv qw(ctsystem ctexec ctqx);
    ctsystem('pwv');
    my @lsco = ctqx(qw(lsco -avobs -s));
    # Similar to OO example: create label type XX iff it doesn't exist
    ctsystem(qw(mklbtype XX)) if !ctqx({stderr=>0}, "lstype lbtype:XX");

There are more examples in the ./examples subdir that comes with this module. Also, the test script is designed as a demo and benchmark and is a good source for cut-and-paste code.

DESCRIPTION

ClearCase::Argv is a subclass of Argv for use with ClearCase. It exists to provide an abstraction layer over cleartool. A program written to this interface can be told to send commands to ClearCase via the standard technique of executing cleartool or via the ClearCase::CtCmd or IPC::ClearTool modules (see) by flipping a switch.

To that end it provides a couple of special methods ctcmd and ipc_cleartool. The ctcmd method can be used to cause cleartool commands to be run in the current process space using ClearCase::CtCmd. Similarly, ipc_cleartool will send commands to a cleartool co-process using the IPC::ClearTool module. The ClearCase::CtCmd and IPC::ClearTool modules must be installed for these methods to work. See their docs for details on what they do, and see ALTERNATE EXECUTION INTERFACES below for how to invoke them.

As ClearCase::Argv is in other ways identical to its base class, see perldoc Argv for substantial further documentation.

OVERRIDDEN METHODS

A few methods of the base class Argv are overridden with modified semantics. These include:

• prog

  ClearCase::Argv->prog prepends the word cleartool to each command line when in standard (not ClearCase::CtCmd or IPC::ClearTool) mode.

• quote

  The cleartool "shell" has its own quoting rules. Therefore, when using ClearCase::CtCmd or IPC::ClearTool modes, command-line quoting must be adjusted to fit cleartool's rules rather than those of the native system shell, so the ->quote method is extended to handle that case.

• readonly

  It's often useful to set the following class attribute:

      ClearCase::Argv->readonly('auto');

  This does nothing by itself but it modifies the behavior of the ->noexec attribute: instead of skipping execution of all commands, it only skips commands which modify ClearCase state.

  Consider a script which does an lsview to see if a view exists, then a mkview to create it if not. With just ->noexec set, both commands would be skipped. With readonly=auto also, only the state- modifying (mkview) operation is skipped. This causes scripts to behave far more realistically in ->noexec mode.

• outpathnorm

  On Windows, cleartool's way of handling pathnames is underdocumented and complex. Apparently, given a choice cleartool on Windows always prefers and uses the native (\-separated) format. Though it will understand and (mostly) preserve /-separated pathnames, any path information it adds (notably version-extended data) is always \-separated. For example:

      cleartool ls -s -d x:/vobs_xyz/foo/bar

  will return something like

      x:/vobs_xyz/foo\bar@@\main\3

  Note that the early forward slashes are retained but the last / before the @@ becomes a \ for some reason, perhaps just a bug in ls). And all version info after the @@ uses \.

  Normalizing pathnames is difficult because there's no way to determine with certainty which lines in the output of a cleartool command are pathnames and which might just happen to look like one. I.e. the phrase "either/or" might occur in a comment returned by cleartool describe; should we interpret it as a pathname?

  The strategy taken by the Argv->outpathnorm attribute of the base class is to "fix" each line of output returned by the ->qx method iff the entire line, when considered as a pathname, refers to an existing file. This can miss pathnames which are not alone on a line, as well as version-extended pathnames within a snapshot view.

  Having the advantage of knowing about ClearCase, the overridden ClearCase::Argv->outpathnorm extends the above strategy to also modify any strings internal to the line which (a) look like pathnames and (b) contain @@. This errs on the side of caution: it will rarely convert strings in error but may not convert pathnames in formats where they are neither alone on the line nor contain version-extended info. It can also be foiled by pathnames containing whitespace or by a change in the extended naming symbol from @@.

  In summary, ClearCase::Argv->outpathnorm will normalize (a) all version-extended pathnames and (b) paths of any type which are alone on a line and refer to an existing filesystem object.

ALTERNATE EXECUTION INTERFACES

The ->ctcmd method allows you to send cleartool commands directly to clearcase via the CtCmd interface rather than by exec-ing cleartool itself.

When called with no argument it returns a boolean indicating whether CtCmd mode is on or off. When called with a numerical argument, it sets the CtCmd mode as follows. If the argument is 0, CtCmd mode is turned off; subsequent commands are sent to real cleartool via the standard execution interface. With an argument of 1, it attempts to use CtCmd mode but if CtCmd fails to load for any reason it will silently continue in standard mode. With an argument of 2 the behavior is the same but a warning is printed on CtCmd failure. With an argument of 3 the warning becomes a fatal error.

Examples

    # Use CtCmd if available, else continue silently
    ClearCase::Argv->ctcmd(1);
    # Use CtCmd if available, else print warning and continue
    ClearCase::Argv->ctcmd(2);
    # Use CtCmd if available, else die with error msg
    ClearCase::Argv->ctcmd(3);
    # Turn off use of CtCmd
    ClearCase::Argv->ctcmd(0);

Typically ->ctcmd will be used as a class method to specify a place for all cleartool commands to be sent. However, it may also be invoked on an object to associate just that instance with CtCmd.

These rules apply to IPC::ClearTool the same way but with a different method name, e.g.:

    ClearCase::Argv->ipc_cleartool(1);

Note: you can tell which mode is in use by turning on the dbglevel attribute. Verbosity styles are as follows:

    + cleartool pwv             # standard (fork/exec)
    +> pwv                      # CtCmd
    -->> pwv                    # IPC::ClearTool

FUNCTIONAL INTERFACE

For those who don't like OO style, or who want to convert existing scripts with the least effort, the execution methods are made available as traditional functions. Examples:

        use ClearCase::Argv qw(ctsystem ctexec ctqx);
        my $cwv = ctqx(pwv -s);
        ctsystem('mklbtype', ['-global'], 'FOO') && exit $?>>8;
        my @vobs = ctqx({autochomp=>1}, 'lsvob -s');

If you prefer you can override the "real" Perl builtins. This is easier for converting an existing script which makes heavy use of system(), exec(), or qx():

        use ClearCase::Argv qw(system exec qv);
        my $cwv = qv(cleartool pwv -s);
        system('cleartool', 'mklbtype', ['-global'], 'FOO') && exit $?>>8;
        my @vobs = qv({autochomp=>1}, 'lsvob -s');

Note that when using an overridden system() et al you must still specify 'cleartool' as the program, whereas ctsystem() and friends handle that. Also, the qx operator cannot be overridden so we use qv() instead.

These interfaces may also be imported via the :functional tag:

        use ClearCase::Argv ':functional';

CAREFUL PROGRAMMERS WANTED

If you're the kind of programmer who tends to execute whole strings such as system("cleartool pwv -s") reflexively or who uses backquotes in a void context, this module won't help you much because it can't easily support those styles. These are bad habits regardless of whether you use ClearCase::Argv and you should strive to overcome them.

STICKINESS

A subtlety: when an execution attribute is set in a void context, it's "sticky", meaning that it's set until explicitly reset. But in a non-void context the new value is temporary or "non-sticky"; it's pushed on a stack and popped off after being read once. This applies to both class and instance uses. It's done this way to allow the following locutions:

    ClearCase::Argv->stdout(0); # turn off stdout for all objects
    $obj1->stdout(0);           # turn off stdout for this object, forever
    $obj2->stdout(0)->system;   # suppress stdout, this time only

This allows you to set up an object with various sticky attributes and keep it around, executing it at will and overriding other attrs temporarily. In the example below, note that another way of setting sticky attrs is illustrated:

    my $obj = ClearCase::Argv->new({autofail=>1, autochomp=>1});
    my $view = $obj->argv('pwv -s')->qx;
    my $exists = $obj->argv('lstype', 'brtype:FOO')->autofail(0)->qx;

Here we keep an object with attrs 'autochomp' and 'autofail' (autofail means to exit on any failure) around and use it to exec whichever commands we want. While checking to see if a type exists, we suppress autofail temporarily. On the next use the object will have both attributes again.

BUGS

I suspect there are still some special quoting situations unaccounted for in the quote method. This will need to be refined over time. Bug reports or patches gratefully accepted.

PORTABILITY

ClearCase::Argv should work on all ClearCase platforms. It's primarily been tested on Solaris 7 and NT 4.0, with CC 3.2.1 and 4.0, using Perl5.004, 5.005, and 5.6. The CAL stuff doesn't work with CC versions < 3.2.1.

FILES

This is a subclass of Argv and thus requires it to be installed. If running in ipc mode it will also need IPC::ClearTool.

SEE ALSO

perl(1), Argv, IPC::ClearTool, IPC::ChildSafe

AUTHOR

David Boyce <dsb@boyski.com>

COPYRIGHT

Copyright (c) 1999-2001 David Boyce. All rights reserved. This Perl program is free software; you may redistribute it and/or modify it under the same terms as Perl itself.

cpanm ClearCase::Argv

perl -MCPAN -e shell
install ClearCase::Argv