From Code to Community: Sponsoring The Perl and Raku Conference 2025 Learn more

GUIMARD / Lemonldap-NG-Portal-2.16.4 / lib / Lemonldap / NG / Portal / 2F / REST.pm 

            

              
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153

              
package Lemonldap::NG::Portal::2F::REST;
use strict;
use Mouse;
use Lemonldap::NG::Portal::Main::Constants qw(
  PE_BADOTP
  PE_ERROR
  PE_FORMEMPTY
  PE_OK
  PE_SENDRESPONSE
);
our $VERSION = '2.0.16';
extends qw(
  Lemonldap::NG::Portal::Lib::Code2F
  Lemonldap::NG::Portal::Lib::REST
);
# INITIALIZATION
# Prefix can overriden by sfExtra and is used for routes
has prefix => ( is => 'rw', default => 'rest' );
# Used to lookup config
has conf_type => ( is => 'ro', default => 'rest' );
has legend    => ( is => 'rw', default => 'enterRest2fCode' );
has initAttrs => ( is => 'rw', default => sub { {} } );
has vrfyAttrs => ( is => 'rw', default => sub { {} } );
sub init {
    my ($self) = @_;
    if ( $self->code_activation ) {
        unless ( $self->conf->{rest2fInitUrl} ) {
            $self->logger->error(
                $self->prefix . '2f: missing intialization URL' );
            return 0;
        }
    }
    else {
        unless ( $self->conf->{rest2fVerifyUrl} ) {
            $self->logger->error(
                $self->prefix . '2f: missing verification URL' );
            return 0;
        }
    }
    foreach my $k ( keys %{ $self->conf->{rest2fInitArgs} } ) {
        my $attr = $self->conf->{rest2fInitArgs}->{$k};
        $attr =~ s/^$//;
        unless ( $attr =~ /^\w+$/ ) {
            $self->logger->error( $self->prefix
                  . "2f: $k key must point to a single attribute or macro" );
            return 0;
        }
        $self->initAttrs->{$k} = $attr;
    }
    foreach my $k ( keys %{ $self->conf->{rest2fVerifyArgs} } ) {
        my $attr = $self->conf->{rest2fVerifyArgs}->{$k};
        $attr =~ s/^$//;
        unless ( $attr =~ /^\w+$/ ) {
            $self->logger->error( $self->prefix
                  . "2f: $k key must point to a single attribute or macro" );
            return 0;
        }
        $self->logger->debug( $self->prefix . "2f: push verify attribute $k" );
        $self->vrfyAttrs->{$k} = $attr;
    }
    return $self->SUPER::init();
}
sub sendCode {
    my ( $self, $req, $sessionInfo, $code ) = @_;
    if ( $self->conf->{rest2fInitUrl} ) {
        # Prepare args
        my $args = {
            user => $sessionInfo->{ $self->conf->{whatToTrace} },
            ( $code ? ( code => $code ) : () ),
        };
        foreach my $k ( keys %{ $self->{initAttrs} } ) {
            $args->{$k} = $sessionInfo->{ $self->{initAttrs}->{$k} };
        }
        # Launch REST request
        $self->logger->debug( $self->prefix . '2f: call init URL' );
        my $res =
          eval { $self->restCall( $self->conf->{rest2fInitUrl}, $args ); };
        if ($@) {
            $self->logger->error( $self->prefix . "2f: error ($@)" );
            return PE_ERROR;
        }
        unless ( $res->{result} ) {
            $self->logger->error( $self->prefix . '2f: initialization failed' );
            return PE_ERROR;
        }
    }
    else {
        $self->logger->debug(
            $self->prefix . '2f: no init URL, skipping initialization' );
    }
    return 1;
}
sub verify_external {
    my ( $self, $req, $session, $code ) = @_;
    # Prepare args
    my $args = {
        user => $session->{ $self->conf->{whatToTrace} },
        code => $code
    };
    foreach my $k ( keys %{ $self->{vrfyAttrs} } ) {
        # in older versions, code was not automatically defined
        # if admins defined it explicitely, do not treat it as a session
        # attribute
        $args->{$k} = (
              $k eq 'code'
            ? $code
            : $session->{ $self->{vrfyAttrs}->{$k} }
        );
    }
    # Launch REST request
    $self->logger->debug( $self->prefix . '2f: call verify URL' );
    my $res =
      eval { $self->restCall( $self->conf->{rest2fVerifyUrl}, $args ); };
    if ($@) {
        $self->logger->error( $self->prefix . "2f: error ($@)" );
        return PE_ERROR;
    }
    # Result
    unless ( $res->{result} ) {
        $self->userLogger->warn( $self->prefix
              . '2f: failed for '
              . $session->{ $self->conf->{whatToTrace} } );
        return PE_BADOTP;
    }
    $self->logger->debug(
        $self->prefix . '2f: credentials accepted by server' );
    return PE_OK;
}
1;