JUSTER / WWW-AUR-0.10 / lib / WWW / AUR.pm 

            

              
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130

              
package WWW::AUR;
use warnings 'FATAL' => 'all';
use strict;
use Exporter;
use Carp       qw();
use File::Spec qw();
BEGIN {
    # We must define these as soon as possible. They are used in other
    # WWW::AUR modules. Like the ones we use after this block...
    our $VERSION   = '0.10';
    our $BASEPATH  = '/tmp/WWW-AUR';
    our $HOST      = 'aur.archlinux.org';
    our $USERAGENT = "WWW::AUR/v${VERSION}";
    our @ISA       = qw(Exporter);
    our @EXPORT_OK = qw(_is_path_param _path_params
                        _category_name _category_index);
}
use WWW::AUR::URI;
use WWW::AUR::RPC;
#---CONSTRUCTOR---
sub new
{
    my $class = shift;
    return bless { _path_params( @_ ) }, $class
}
#---PUBLIC METHOD---
sub search
{
    my ($self, $query) = @_;
    my $found_ref = WWW::AUR::RPC::search( $query );
    require WWW::AUR::Package;
    return map {
        WWW::AUR::Package->new( $_->{name}, info => $_, %$self );
    } @$found_ref;
}
#---HELPER FUNCTION---
sub _def_wrapper_method
{
    my ($name, $class) = @_;
    no strict 'refs';
    *{ "WWW::AUR::$name" } = sub {
        my $self = shift;
        eval "require $class";
        if ( $@ ) {
            Carp::confess "Failed to load $class module:\n$@";
        }
        return eval { $class->new( @_, %$self ) };
    };
}
_def_wrapper_method( 'find'       => 'WWW::AUR::Package'    );
_def_wrapper_method( 'maintainer' => 'WWW::AUR::Maintainer' );
_def_wrapper_method( 'iter'       => 'WWW::AUR::Iterator'   );
_def_wrapper_method( 'login'      => 'WWW::AUR::Login'      );
#-----------------------------------------------------------------------------
# UTILITY FUNCTIONS
#-----------------------------------------------------------------------------
# These functions are used internally by other WWW::AUR modules...
my %_IS_PATH_PARAM = map { ( $_ => 1 ) }
    qw/ basepath dlpath extpath destpath /;
#---INTERNAL FUNCTION---
sub _is_path_param
{
    my ($name) = @_;
    return $_IS_PATH_PARAM{ $name };
}
#---INTERNAL FUNCTION---
sub _path_params
{
    my @filterme = @_;
    my %result;
    FILTER_LOOP:
    while ( my $key = shift @filterme ) {
        next unless _is_path_param( $key );
        my $val = shift @filterme or last FILTER_LOOP;
        $result{ $key } = $val;
    }
    # Fill path parameters with default values if they are unspecified...
    our $BASEPATH;
    my $base = $result{ 'basepath' } || $BASEPATH;
    return ( 'dlpath'   => File::Spec->catdir( $base, 'src'   ),
             'extpath'  => File::Spec->catdir( $base, 'build' ),
             'destpath' => File::Spec->catdir( $base, 'cache' ),
             %result );
}
my @_CATEGORIES = qw{ daemons devel editors emulators games gnome
                      i18n kde kernels lib modules multimedia
                      network office science system x11 xfce };
#---INTERNAL FUNCTION---
sub _category_name
{
    my ($idx) = @_;
    return 'undefined' unless $idx > 0 && $idx <= scalar @_CATEGORIES;
    return $_CATEGORIES[ $idx - 1 ];
}
#---INTERNAL FUNCTION---
sub _category_index
{
    my ($name) = @_;
    $name = lc $name;
    for my $i ( 0 .. $#_CATEGORIES ) {
        return $i if $name eq $_CATEGORIES[ $i ];
    }
    Carp::croak "$name is not a valid category name";
}
1;