#!/usr/bin/perl -w
# Copyright 2011, 2012, 2013, 2014, 2015, 2016, 2017, 2018, 2019, 2020 Kevin Ryde
# This file is part of Math-PlanePath.
#
# Math-PlanePath is free software; you can redistribute it and/or modify it
# under the terms of the GNU General Public License as published by the Free
# Software Foundation; either version 3, or (at your option) any later
# version.
#
# Math-PlanePath is distributed in the hope that it will be useful, but
# WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
# or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
# for more details.
#
# You should have received a copy of the GNU General Public License along
# with Math-PlanePath.  If not, see <http://www.gnu.org/licenses/>.
use 5.004;
use strict;
use Test;
plan tests => 389;
use lib 't';
use MyTestHelpers;
BEGIN { MyTestHelpers::nowarnings(); }
use Math::PlanePath::Flowsnake;
#------------------------------------------------------------------------------
# VERSION
{
  my $want_version = 129;
  ok ($Math::PlanePath::Flowsnake::VERSION, $want_version,
      'VERSION variable');
  ok (Math::PlanePath::Flowsnake->VERSION,  $want_version,
      'VERSION class method');
  ok (eval { Math::PlanePath::Flowsnake->VERSION($want_version); 1 },
      1,
      "VERSION class check $want_version");
  my $check_version = $want_version + 1000;
  ok (! eval { Math::PlanePath::Flowsnake->VERSION($check_version); 1 },
      1,
      "VERSION class check $check_version");
  my $path = Math::PlanePath::Flowsnake->new;
  ok ($path->VERSION,  $want_version, 'VERSION object method');
  ok (eval { $path->VERSION($want_version); 1 },
      1,
      "VERSION object check $want_version");
  ok (! eval { $path->VERSION($check_version); 1 },
      1,
      "VERSION object check $check_version");
}
#------------------------------------------------------------------------------
# n_start, x_negative, y_negative
{
  my $path = Math::PlanePath::Flowsnake->new;
  ok ($path->n_start, 0, 'n_start()');
  ok ($path->x_negative, 1, 'x_negative()');
  ok ($path->y_negative, 1, 'y_negative()');
}
{
  my @pnames = map {$_->{'name'}}
    Math::PlanePath::Flowsnake->parameter_info_list;
  ok (join(',',@pnames), 'arms');
}
#------------------------------------------------------------------------------
# level_to_n_range()
{
  my $path = Math::PlanePath::Flowsnake->new;
  { my ($n_lo,$n_hi) = $path->level_to_n_range(0);
    ok ($n_lo, 0);
    ok ($n_hi, 1); }
  { my ($n_lo,$n_hi) = $path->level_to_n_range(1);
    ok ($n_lo, 0);
    ok ($n_hi, 7); }
  { my ($n_lo,$n_hi) = $path->level_to_n_range(2);
    ok ($n_lo, 0);
    ok ($n_hi, 49); }
}
{
  my $path = Math::PlanePath::Flowsnake->new (arms => 2);
  { my ($n_lo,$n_hi) = $path->level_to_n_range(0);
    ok ($n_lo, 0);
    ok ($n_hi, 2); }  # 7^0+1 + 7^0 - 1 = 2
  { my ($n_lo,$n_hi) = $path->level_to_n_range(1);
    ok ($n_lo, 0);
    ok ($n_hi, 14); }  # 7^1+1 + 7^1 - 1 = 14
  { my ($n_lo,$n_hi) = $path->level_to_n_range(2);
    ok ($n_lo, 0);
    ok ($n_hi, 98); }  # 7^2+1 + 7^2 - 1 = 98
}
{
  my $path = Math::PlanePath::Flowsnake->new (arms => 3);
  { my ($n_lo,$n_hi) = $path->level_to_n_range(0);
    ok ($n_lo, 0);
    ok ($n_hi, 3); } # 7^0+1 + 2*7^0 - 1 = 3
  { my ($n_lo,$n_hi) = $path->level_to_n_range(1);
    ok ($n_lo, 0);
    ok ($n_hi, 21); } # 7^1+1 + 2*7^1 - 1 = 21
}
#------------------------------------------------------------------------------
# first few points
{
  my @data = (
              # arms=1
              [ 1,   0,    0,0 ],
              [ 1,   1,    2,0 ],
              [ 1,   2,    3,1 ],
              [ 1,   3,    1,1 ],
              [ 1,   4,    0,2 ],
              [ 1,   5,    2,2 ],
              [ 1,   6,    4,2 ],
              [ 1,   7,    5,1 ],
              [ 1,   8,    7,1 ],
              [ 1,   9,    8,2 ],
              [ 1,   .25,   .5, 0 ],
              [ 1,   .5,     1, 0 ],
              [ 1,   1.75,   2.75, .75 ],
              # arms=2
              [ 2,  46,    -2,4 ],
              [ 2,   1,    -1,1 ],
             );
  foreach my $elem (@data) {
    my ($arms, $n, $x, $y) = @$elem;
    my $path = Math::PlanePath::Flowsnake->new (arms => $arms);
    {
      # n_to_xy()
      my ($got_x, $got_y) = $path->n_to_xy ($n);
      if ($got_x == 0) { $got_x = 0 }  # avoid "-0"
      if ($got_y == 0) { $got_y = 0 }
      ok ($got_x, $x, "arms=$arms  n_to_xy() x at n=$n");
      ok ($got_y, $y, "arms=$arms  n_to_xy() y at n=$n");
    }
    if ($n==int($n)) {
      # xy_to_n()
      my $got_n = $path->xy_to_n ($x, $y);
      ok ($got_n, $n, "xy_to_n() n at x=$x,y=$y");
    }
    if ($n == int($n)) {
      {
        my ($got_nlo, $got_nhi) = $path->rect_to_n_range (0,0, $x,$y);
        ok ($got_nlo <= $n, 1, "rect_to_n_range(0,0,$x,$y) arms=$arms for n=$n, got_nlo=$got_nlo");
        ok ($got_nhi >= $n, 1, "rect_to_n_range(0,0,$x,$y) arms=$arms for n=$n, got_nhi=$got_nhi");
      }
      {
        $n = int($n);
        my ($got_nlo, $got_nhi) = $path->rect_to_n_range ($x,$y, $x,$y);
        ok ($got_nlo <= $n, 1, "rect_to_n_range($x,$y,$x,$y) arms=$arms for n=$n, got_nlo=$got_nlo");
        ok ($got_nhi >= $n, 1, "rect_to_n_range($x,$y,$x,$y) arms=$arms for n=$n, got_nhi=$got_nhi");
      }
    }
  }
}
#------------------------------------------------------------------------------
# rect_to_n_range()
{
  my $path = Math::PlanePath::Flowsnake->new;
  my ($n_lo, $n_hi) = $path->rect_to_n_range(0,0, 0,0);
  ok ($n_lo == 0, 1, "rect_to_n_range() 0,0  n_lo=$n_lo");
  ok ($n_hi >= 0, 1, "rect_to_n_range() 0,0  n_hi=$n_hi");
}
#------------------------------------------------------------------------------
# random fracs
{
  my $path = Math::PlanePath::Flowsnake->new;
  for (1 .. 20) {
    my $bits = int(rand(20));         # 0 to 20, inclusive
    my $n = int(rand(2**$bits)) + 1;  # 1 to 2^bits, inclusive
    my ($x1,$y1) = $path->n_to_xy ($n);
    my ($x2,$y2) = $path->n_to_xy ($n+1);
    foreach my $frac (0.25, 0.5, 0.75) {
      my $want_xf = $x1 + ($x2-$x1)*$frac;
      my $want_yf = $y1 + ($y2-$y1)*$frac;
      my $nf = $n + $frac;
      my ($got_xf,$got_yf) = $path->n_to_xy ($nf);
      ok ($got_xf, $want_xf, "n_to_xy($n) random frac $frac, x");
      ok ($got_yf, $want_yf, "n_to_xy($n) random frac $frac, y");
    }
  }
}
#------------------------------------------------------------------------------
# random points
{
  my $path = Math::PlanePath::Flowsnake->new;
  for (1 .. 50) {
    my $bits = int(rand(20));         # 0 to 20, inclusive
    my $n = int(rand(2**$bits)) + 1;  # 1 to 2^bits, inclusive
    my ($x,$y) = $path->n_to_xy ($n);
    my $rev_n = $path->xy_to_n ($x,$y);
    if (! defined $rev_n) { $rev_n = 'undef'; }
    ok ($rev_n, $n, "xy_to_n($x,$y) reverse to expect n=$n, got $rev_n");
    my ($n_lo, $n_hi) = $path->rect_to_n_range ($x,$y, $x,$y);
    ok ($n_lo <= $n, 1, "rect_to_n_range() reverse n=$n cf got n_lo=$n_lo");
    ok ($n_hi >= $n, 1, "rect_to_n_range() reverse n=$n cf got n_hi=$n_hi");
  }
}
exit 0;