The Perl Toolchain Summit 2025 Needs You: You can help 🙏 Learn more

MASAKI / Test-Ika-0.08 / lib / Test / Ika / Reporter / Spec.pm 

            

              
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
—
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107

              
package Test::Ika::Reporter::Spec;
use strict;
use warnings;
use utf8;
use Scope::Guard ();
use Term::ANSIColor qw/colored/;
use Term::Encoding ();
sub new {
    my $class = shift;
    my $args  = shift;
    $|++;
    my $term_encoding = Term::Encoding::term_encoding();
    binmode *STDOUT, ":encoding($term_encoding)";
    binmode *STDERR, ":encoding($term_encoding)";
    print "\n";
    return bless {
        failed => 0,
        describe => [],
        results => [],
        color => (exists $args->{color} ? $args->{color} : 1),
    }, $class;
}
sub color {
    my ($self, $color, @args) = @_;
    return @args unless $self->{color};
    return Term::ANSIColor::colored($color, @args);
}
sub describe {
    my ($self, $name) = @_;
    push @{$self->{describe}}, $name;
    print(('  ' x @{$self->{describe}}) . "$name\n");
    return Scope::Guard->new(sub {
        pop @{$self->{describe}};
    });
}
sub it {
    my ($self, $name, $test, $results, $exception) = @_;
    print ('  ' x (@{$self->{describe}}+1));
    if ($test > 0) {
        print( $self->color( ['green'], "\x{2713} " ) );
    }
    elsif ($test < 0) {
        print( $self->color( ['yellow'], "\x{2713} " ) );
    }
    else {
        # not ok
        print( $self->color( ['red'], "\x{2716} " ) );
    }
    print( $self->color( ["BRIGHT_BLACK"], $name ) );
    if (!$test) {
        my $failed = ++$self->{failed};
        printf(" (FAILED - %d)", $failed);
        push @{$self->{results}}, [$results, $exception];
    }
    print("\n");
}
sub finalize {
    my $self = shift;
    if ($self->{finalized}++) {
        die "Do not finalize twice.";
    } else {
        print "\n";
        for my $i (0..$self->{failed}-1) {
            printf "  %s)\n", $i+1;
            my $indent = ' ' x 4;
            if (defined(my $msg = $self->{results}->[$i]->[0])) {
                $msg =~ s{\n(?!\z)}{\n$indent}sg;
                print $indent . $msg;
            }
            if (defined(my $err = $self->{results}->[$i]->[1])) {
                $err =~ s{\n(?!\z)}{\n$indent}sg;
                print $indent . $self->color(['red', 'bold'], 'Exception: ') . $self->color(['red'], $err);
            }
        }
        print "\n";
    }
}
1;
__END__
=head1 NAME
Test::Ika::Reporter::Spec - Reporter like RSpec
=head1 SYNOPSIS
    Test::Ika->set_reporter('Spec');
=head1 DESCRIPTION
This module displays pretty output like RSpec.
=head1 SEE ALSO
L<Test::Ika>