The Perl and Raku Conference 2025: Greenville, South Carolina - June 27-29 Learn more

SACHINJSK / WWW-Contact-0.16 / lib / WWW / Contact / Rediffmail.pm 

            

              
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
—
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125

              
package WWW::Contact::Rediffmail;
use Moose;
extends 'WWW::Contact::Base';
our $VERSION   = '0.16';
our $AUTHORITY = 'cpan:SACHINJSK';
sub get_contacts {
    my ($self, $email, $password) = @_;
    # reset errstr
    $self->errstr(undef);
    my @contacts;
     
    my $ua = $self->ua;
    $self->debug("start get_contacts from Rediff");
     
    # Get username from email.
    $email =~ /(.*)@.*/;
    my $username = $1;
     
    # get to login form
    $self->get('http://www.rediff.com') || return;
    $self->submit_form(
        form_name => 'loginform',
        fields    => {
            login  => $username,
            passwd => $password,
        },
    ) || return;
     
    my $content = $ua->content();
    if ($content =~ /Your login failed/ig) {
        $self->errstr('Wrong Username or Password');
        return;
    }
    $self->debug('Login OK');
     
    $ua->follow_link( url_regex => qr/login=/i );
    my $link = $ua->follow_link( url_regex => qr/folder=inbox/i );
    $content = $ua->content;
    # Go to new Rediffmail, if taken to old one.
    if ($content =~ /new Rediffmail/ig) {
        $link = $ua->follow_link(text_regex => qr/new Rediffmail/i );
    }
     
    # get url and session id.
    my $base_link = $link->base();
    $base_link =~ /(.*)\?.*session_id=(.*?)&/;
    my $base_url   = $1;
    my $session_id = $2;
    $self->get("$base_url?do=downaddrbook&login=$username&session_id=$session_id&service=thunderbird");
    my $address_content = $ua->content();
    @contacts = get_contacts_from_thunderbird_csv($address_content);
     
    return wantarray ? @contacts : \@contacts;
}
sub get_contacts_from_thunderbird_csv {
    my ($csv) = shift;
    my @contacts;
  
    # first_name, last_name, full_name, nickname, e-mail.
    my @lines = split(/\n/, $csv);
    foreach my $line (@lines) {
        $line =~ s/"//g;
        my @cols = split(',', $line);
        push @contacts, {
            name  => $cols[2],
            email => $cols[4]
        };
    }
     
    return wantarray ? @contacts : \@contacts;
}
no Moose;
__PACKAGE__->meta->make_immutable;
1;
__END__
=head1 NAME
WWW::Contact::Rediffmail - Get contacts from Rediffmail
=head1 SYNOPSIS
    use WWW::Contact;
     
    my $wc       = WWW::Contact->new();
    my @contacts = $wc->get_contacts('itsa@rediffmail.com', 'password');
    my $errstr   = $wc->errstr;
    if ($errstr) {
        die $errstr;
    } else {
        print Dumper(\@contacts);
    }
=head1 DESCRIPTION
get contacts from Rediff Mail. extends L<WWW::Contact::Base>
=head1 SEE ALSO
L<WWW::Contact>, L<WWW::Contact::Base>, L<WWW::Mechanize>
=head1 AUTHOR
Sachin Sebastian, C<< <sachinjsk at cpan.org> >>
=head1 COPYRIGHT & LICENSE
Copyright 2008 Sachin Sebastian, all rights reserved.
This program is free software; you can redistribute it and/or modify it
under the same terms as Perl itself.
=cut