NAME

Moose::Util::TypeConstraints - Type constraint system for Moose

SYNOPSIS

  use Moose::Util::TypeConstraints;

  type 'Num' => where { Scalar::Util::looks_like_number($_) };
  
  subtype 'Natural' 
      => as 'Num' 
      => where { $_ > 0 };
  
  subtype 'NaturalLessThanTen' 
      => as 'Natural'
      => where { $_ < 10 }
      => message { "This number ($_) is not less than ten!" };
      
  coerce 'Num' 
      => from 'Str'
        => via { 0+$_ }; 
        
  enum 'RGBColors' => qw(red green blue);

DESCRIPTION

This module provides Moose with the ability to create custom type contraints to be used in attribute definition.

Important Caveat

This is NOT a type system for Perl 5. These are type constraints, and they are not used by Moose unless you tell it to. No type inference is performed, expression are not typed, etc. etc. etc.

This is simply a means of creating small constraint functions which can be used to simplify your own type-checking code.

Slightly Less Important Caveat

It is almost always a good idea to quote your type and subtype names. This is to prevent perl from trying to execute the call as an indirect object call. This issue only seems to come up when you have a subtype the same name as a valid class, but when the issue does arise it tends to be quite annoying to debug.

So for instance, this:

  subtype DateTime => as Object => where { $_->isa('DateTime') };

will Just Work, while this:

  use DateTime;
  subtype DateTime => as Object => where { $_->isa('DateTime') };

will fail silently and cause many headaches. The simple way to solve this, as well as future proof your subtypes from classes which have yet to have been created yet, is to simply do this:

  use DateTime;
  subtype 'DateTime' => as 'Object' => where { $_->isa('DateTime') };

Default Type Constraints

This module also provides a simple hierarchy for Perl 5 types, this could probably use some work, but it works for me at the moment.

  Any
  Item 
      Bool
      Undef
      Defined
          Value
              Num
                Int
              Str
                ClassName
          Ref
              ScalarRef
              ArrayRef
              HashRef
              CodeRef
              RegexpRef
              GlobRef
                FileHandle
              Object    
                  Role

Suggestions for improvement are welcome.

NOTE: The Undef type constraint does not work correctly in every occasion, please use it sparringly.

NOTE: The ClassName type constraint is simply a subtype of string which responds true to isa('UNIVERSAL'). This means that your class must be loaded for this type constraint to pass. I know this is not ideal for all, but it is a saner restriction then most others.

Use with Other Constraint Modules

This module should play fairly nicely with other constraint modules with only some slight tweaking. The where clause in types is expected to be a CODE reference which checks it's first argument and returns a bool. Since most constraint modules work in a similar way, it should be simple to adapt them to work with Moose.

For instance, this is how you could use it with Declare::Constraints::Simple to declare a completely new type.

  type 'HashOfArrayOfObjects' 
      => IsHashRef(
          -keys   => HasLength,
          -values => IsArrayRef( IsObject ));

For more examples see the t/204_example_w_DCS.t test file.

Here is an example of using Test::Deep and it's non-test related eq_deeply function.

  type 'ArrayOfHashOfBarsAndRandomNumbers' 
      => where {
          eq_deeply($_, 
              array_each(subhashof({
                  bar           => isa('Bar'),
                  random_number => ignore()
              }))) 
        };

For a complete example see the t/205_example_w_TestDeep.t test file.

FUNCTIONS

Type Constraint Registry

find_type_constraint ($type_name)

This function can be used to locate a specific type constraint meta-object. What you do with it from there is up to you :)

create_type_constraint_union (@type_constraint_names)

Given a list of @type_constraint_names, this will return a Moose::Meta::TypeConstraint::Union instance.

export_type_constraints_as_functions

This will export all the current type constraints as functions into the caller's namespace. Right now, this is mostly used for testing, but it might prove useful to others.

export_type_contstraints_as_functions

Alias for the above function.

list_all_type_constraints

This will return a list of type constraint names, you can then fetch them using find_type_constraint ($type_name) if you want to.

list_all_builtin_type_constraints

This will return a list of builtin type constraints, meaning, those which are defined in this module. See the section labeled "Default Type Constraints" for a complete list.

Type Constraint Constructors

The following functions are used to create type constraints. They will then register the type constraints in a global store where Moose can get to them if it needs to.

See the SYNOPSIS for an example of how to use these.

type ($name, $where_clause)

This creates a base type, which has no parent.

subtype ($name, $parent, $where_clause, ?$message)

This creates a named subtype.

subtype ($parent, $where_clause, ?$message)

This creates an unnamed subtype and will return the type constraint meta-object, which will be an instance of Moose::Meta::TypeConstraint.

enum ($name, @values)

This will create a basic subtype for a given set of strings. The resulting constraint will be a subtype of Str and will match any of the items in @values. See the SYNOPSIS for a simple example.

NOTE: This is not a true proper enum type, it is simple a convient constraint builder.

as

This is just sugar for the type constraint construction syntax.

where

This is just sugar for the type constraint construction syntax.

message

This is just sugar for the type constraint construction syntax.

optimize_as

This can be used to define a "hand optimized" version of your type constraint which can be used to avoid traversing a subtype constraint heirarchy.

NOTE: You should only use this if you know what you are doing, all the built in types use this, so your subtypes (assuming they are shallow) will not likely need to use this.

Type Coercion Constructors

Type constraints can also contain type coercions as well. If you ask your accessor too coerce, the Moose will run the type-coercion code first, followed by the type constraint check. This feature should be used carefully as it is very powerful and could easily take off a limb if you are not careful.

See the SYNOPSIS for an example of how to use these.

coerce
from

This is just sugar for the type coercion construction syntax.

via

This is just sugar for the type coercion construction syntax.

Namespace Management

unimport

This will remove all the type constraint keywords from the calling class namespace.

BUGS

All complex software has bugs lurking in it, and this module is no exception. If you find a bug please either email me, or add the bug to cpan-RT.

AUTHOR

Stevan Little <stevan@iinteractive.com>

COPYRIGHT AND LICENSE

Copyright 2006, 2007 by Infinity Interactive, Inc.

http://www.iinteractive.com

This library is free software; you can redistribute it and/or modify it under the same terms as Perl itself.