From Code to Community: Sponsoring The Perl and Raku Conference 2025 Learn more

TELS / Mediawiki-POD-0.04 / lib / Mediawiki / POD.pm 

            

              
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
—
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283

              
package Mediawiki::POD;
our $VERSION = '0.04';
use strict;
use Pod::Simple::HTML;
use Mediawiki::POD::HTML;
sub new
  {
  my $class = shift;
  my $self = bless {}, $class;
  # some defaults
  $self->{remove_newlines} = 1;
  $self->{body_only} = 1;
  $self;
  }
sub remove_newlines
  {
  my $self = shift;
  $self->{remove_newlines} = ( $_[0] ? 1 : 0 ) if @_ > 0;
  $self->{remove_newlines};
  }
sub body_only
  {
  my $self = shift;
  $self->{body_only} = ( $_[0] ? 1 : 0 ) if @_ > 0;
  $self->{body_only};
  }
sub as_html
  {
  my ($self, $input) = @_;
  my $parser = Mediawiki::POD::HTML->new();
  my ($html, $headlines);
  $parser->output_string( \$html );
  $parser->parse_string_document( $input );
  # remove comments
  $html =~ s/<!--(.|\n)*?-->//g;
  if ($self->{body_only})
    {
    # remove the unwanted HTML sections
    $html =~ s/<head>(.|\n)*<\/head>//;
    $html =~ s/<\/?(html|body).*?>//g;
    }
  # clean up some crazy tags
  # converting "<code lang='und' xml:lang='und'>" to "<code>
  $html =~ s/<(pre|code|p)\s.*?>/<$1>/g;
  # insert a class for <a name="">
  $html =~ s/<a name="/<a class="u" name="/g;
  # make it readable again :)
  $html =~ s/\&#39;/'/g;
  # remove empty paragraphs before a closing </div> (for instance for X keywords)
  $html =~ s/<p><\/p>\n<\/div>/<\/div>/g;
  # if the last item is a keyword, we need to add a closing </div>
  $html =~ s/<p><\/p>\s*\z/<\/div>/;
  # convert newlines between <pre> tags to <br>
  # remove all new lines and tabs
  $html = $self->_parse_output($html) if $self->{remove_newlines};
  $html = $self->_generate_toc( $parser->get_headlines() ) . $html;
  # return the result
  $html;
  };
###########################################################################
# We need to remove all new lines, other Mediawiki will insert spurious
# linebreaks. However, inside <pre></pre> we need to replace them with
# <br> so that verbatim sections render properly. A nested regexp could
# solve this, but is not possible. So we implement a very basic parser
# that recognizes three things: <tag>, </tag>, anything else.
# This routine assumes that the <pre> tags are not nested.
sub _parse_output
  {
  my ($self, $input) = @_;
  my $in_pre = 0;
  my $qr_tag = qr/^(<\w+(.|\n)*?>)/;
  my $qr_end_tag = qr/^(<\/\w+>)/;
  my $qr_else = qr/^((?:.|\n)*?)(<|\z)/;
  my $output = '';
  while (length($input) > 0)
    {
    # math the start of the input, and remove the matching part
    if ($input =~ $qr_tag)
      {
      $input =~ s/$qr_tag//;
      my $tag = $1;
      $tag =~ s/[\n\r\t]/ /g;
      $output .= $tag;
      if ($tag =~ /^<pre.*?>/i)
        {
        $in_pre++;
        }
      }
    elsif ($input =~ $qr_end_tag)
      {
      $input =~ s/$qr_end_tag//;
      my $tag = $1;
      $tag =~ s/[\n\r\t]/ /g;
      $output .= $tag;
      if ($tag =~ /^<\/pre.*?>/i)
        {
        $in_pre--;
        }
      }
    else
      {
      $input =~ s/$qr_else/$2/;
      # remove newlines
      my $else = $1;
      if ($in_pre > 0)
        {
        # also remove excessive leading whitespace
        $else =~ s/[\n\r\t]\s*/<br> /g;
        $else =~ s/^\s*/ /;
        }
      else
        {
        $else =~ s/[\n\r\t]/ /g;
        }
      $output .= $else;
      }
    }  
  $output;
  }
sub _generate_toc
  {
  my ($self, $headlines) = @_;
  my $toc = '<table id="toc" class="toc" summary="Contents"><tr><td><div id="toctitle"><h2>Contents</h2></div>';
  $toc .= "\n<ul>\n";
  my $level = 1;
  my @cur_nr = ( 0 );
  for my $headline (@$headlines)
    {
    $headline =~ /^head([1-9]) (.*)/;
    my $cur_level = $1;
    my $txt = $2;
    my $link = $txt; $link =~ s/ /_/g; $link =~ s/"<>//g;
    #print STDERR "$headline $cur_level $level\n";
    # we enter a scope
    if ($cur_level > $level)
      {
      my $levels_up = $cur_level - $level;
      for (1..$levels_up)
        {
        push @cur_nr, 0;
        $toc .= '<ul>';
        }
      }
    elsif ($cur_level < $level)
      {
      my $levels_down = $level - $cur_level;
      for (1..$levels_down)
        {
        pop @cur_nr;
        $toc .= '</ul>';
        }
      }
    $cur_nr[-1]++;
    my $tnr = join ('.', @cur_nr);
    $toc .= "<li class='toclevel-$cur_level'><a href=\"#$link\"><span class='tocnumber'>$tnr</span> <span class='toctext'>$txt</span></a></li>\n";
    $level = $cur_level;
    }
  $toc .= "</ul></td></tr></table>\n";
  $toc .= '<script type="text/javascript"> if (window.showTocToggle) { var tocShowText = "show"; var tocHideText = "hide"; showTocToggle(); } </script>';
  $toc =~ s/[\n\r\t]/ /g if $self->{remove_newlines};
  $toc;
  }
1;
__END__
=pod
=head1 NAME
Mediawiki::POD - convert POD to HTML suitable for a MediaWiki wiki
=head1 SYNOPSIS
        use Mediawiki::POD;
         
        my $converter = Mediawiki::POD->new();
        my $html = $converter->as_thml($POD);
=head1 DESCRIPTION
Turns a given POD (Plain Old Documentation) into HTML code.
=head1 VERSIONS
Please see the CHANGES file for a complete version history.
=head1 METHODS
=head2 new()
        my $converter = Mediawiki::POD->new();
Create a new converter object.
=head2 as_html()
        my $html = $converter->as_html( $pod_text);
Take the given POD text and return HTML suitable for embedding into
an Mediawiki page.
The returned HTML contains no newlines (as these would confuse the
Mdiawiki parser) and a table of contents.
=head2 remove_newlines()
        $self->remove_newlines(0);   # output contains \n
Set/get the flag that indicates that newlines should be removed from
the output. For Mediawiki integration, the output must be stripped
of newlines completely. Otherwise you might want to leave them in
to generated more readable HTML.
Default is true.
=head2 body_only()
        $self->body_only(0);         # output contains <head> etc.
Set/get the flag that indicates that only the body part should be
returned by L<as_html()>. The default means that the head section
as well as the body tags are removed from the output.
Default is true.
=head1 LICENSE
This library is free software; you can redistribute it and/or modify
it under the same terms of the GPL.
See the LICENSE file for information.
=head1 AUTHOR
(c) by Tels bloodgate.com 2007
=head1 SEE ALSO
L<http://bloodgate.com/wiki/>.
=cut