The Perl and Raku Conference 2025: Greenville, South Carolina - June 27-29 Learn more

WYANT / DateTime-Fiction-JRRTolkien-Shire-0.908 / eg / date-convert 

            

              
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
—
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142

              
#!/usr/bin/env perl
use 5.008004;
use strict;
use warnings;
use Getopt::Long 2.33 qw{ :config auto_version };
use Pod::Usage;
our $VERSION = '0.908';
my %opt = (
    from        => 'DateTime',
    to          => 'DateTime::Fiction::JRRTolkien::Shire',
);
GetOptions( \%opt,
    qw{ from=s reverse! to=s },
    'instantiater=s'    => \( my $instantiater = 'new' ),
    'serializer=s'      => \( my $serializer ),
    help => sub { pod2usage( { -verbose => 2 } ) },
) or pod2usage( { -verbose => 0 } );
$opt{reverse}
    and @opt{ qw< to from > } = @opt{ qw< from to > };
foreach my $key ( qw{ from to } ) {
    local $@ = undef;
    eval "require $opt{$key}; 1"
        or die $@;
}
my $from = $opt{from}->$instantiater( @ARGV );
my $to = $opt{to}->from_object( object => $from );
my $calendar;
if ( my $code = $to->can( 'calendar_name' ) ) {
    $calendar = $code->( $to );
} else {
    ( $calendar = $opt{to} ) =~ s/ .* :: //smx
        or $calendar = 'Gregorian';
}
if ( $serializer ) {
    print $to->$serializer(), " $calendar\n";
} else {
    print "$to $calendar\n";
}
__END__
=head1 TITLE
date-convert - Convert dates from one calendar to another.
=head1 SYNOPSIS
 date-convert year 2016 month 4 day 1
 date-convert -reverse year 1419 holiday 3
 date-convert -help
 date-convert -version
=head1 OPTIONS
=head2 -from
This option specifies the class to be converted from.
The default is C<-from=DateTime>.
=head2 -help
This option displays the documentation for this script. The script then
exits.
=head2 -instantiater
This option specifies the name of the method used to instantiate the
object to be converted from.
The default is C<'new'>.
=head2 -reverse
If asserted, this Boolean option specifies that a reverse conversion is
to be done. It works by swapping the values of the C<-from> and C<-to>
options, whether specified or defaulted.
The default is C<-noreverse>.
=head2 serializer
This option specifies the name of the method to be used to serialize the
object converted to. This method must not take any arguments. If a false
value, the object is stringified.
The default is C<undef>.
=head2 -to
This option specifies the class to be converted to.
The default is C<-to=DateTime::Fiction::JRRTolkien::Shire>.
=head2 -version
This option displays the version of this script. The script then exits.
=head1 DETAILS
This Perl script uses L<DateTime|DateTime> modules to convert from one
calendar to another.
The command-line arguments are passed verbatim to the C<-from> class'
C<new()> method. The resultant object is passed to the C<-to> class'
C<from_object()> method, and the result of that method is stringified.
By default, this script converts from C<DateTime> to
C<DateTime::Fiction::JRRTolkien::Shire>, thus converting the given date
from Gregorian to Shire Reckoning.
=head1 AUTHOR
Thomas R. Wyant, III F<wyant at cpan dot org>
=head1 COPYRIGHT AND LICENSE
Copyright (C) 2017-2022, 2025 by Thomas R. Wyant, III
This program is free software; you can redistribute it and/or modify it
under the same terms as Perl 5.10.0. For more details, see the full text
of the licenses in the directory LICENSES.
This program is distributed in the hope that it will be useful, but
without any warranty; without even the implied warranty of
merchantability or fitness for a particular purpose.
=cut
# ex: set textwidth=72 :