NAME

AnyEvent::RipeRedis - Flexible non-blocking Redis client with reconnect feature

SYNOPSIS

  use AnyEvent;
  use AnyEvent::RipeRedis;

  my $redis = AnyEvent::RipeRedis->new(
    host     => 'localhost',
    port     => 6379,
    password => 'yourpass',
  );

  my $cv = AE::cv;

  $redis->get( 'foo',
    sub {
      my $reply = shift;
      my $err   = shift;

      if ( defined $err ) {
        my $err_msg  = $err->message;
        my $err_code = $err->code;

        warn "[$err_code] $err_msg\n";
        $cv->send;

        return;
      }

      print "$reply\n";
      $cv->send;
    }
  );

  $cv->recv;

DESCRIPTION

AnyEvent::RipeRedis is flexible non-blocking Redis client with reconnect feature. The client supports subscriptions, transactions and connection via UNIX-socket.

Requires Redis 1.2 or higher, and any supported event loop.

CONSTRUCTOR

new( %params )

  my $redis = AnyEvent::RipeRedis->new(
    host                   => 'localhost',
    port                   => 6379,
    password               => 'yourpass',
    database               => 7,
    lazy                   => 1,
    connection_timeout     => 5,
    read_timeout           => 5,
    min_reconnect_interval => 5,

    on_connect => sub {
      # handling...
    },

    on_disconnect => sub {
      # handling...
    },

    on_connect_error => sub {
      my $err = shift;

      # error handling...
    },

    on_error => sub {
      my $err = shift;

      # error handling...
    },
  );

host => $host

Server hostname (default: 127.0.0.1)

port => $port

Server port (default: 6379)

password => $password

If the password is specified, the AUTH command is sent to the server after connection.

database => $index

Database index. If the index is specified, the client is switched to the specified database after connection. You can also switch to another database after connection by using SELECT command. The client remembers last selected database after reconnection.

The default database index is 0.

utf8 => $boolean

If enabled, all strings will be converted to UTF-8 before sending to server, and all results will be decoded from UTF-8.

Enabled by default.

connection_timeout => $fractional_seconds

Timeout, within which the client will be wait the connection establishment to the Redis server. If the client could not connect to the server after specified timeout, the on_error or on_connect_error callback is called. In case when on_error callback is called, E_CANT_CONN error code is passed to callback in the second argument. The timeout specifies in seconds and can contain a fractional part.

  connection_timeout => 10.5,

By default the client use kernel's connection timeout.

read_timeout => $fractional_seconds

Timeout, within which the client will be wait a response on a command from the Redis server. If the client could not receive a response from the server after specified timeout, the client close connection and call on_error callback with the E_READ_TIMEDOUT error code. The timeout is specifies in seconds and can contain a fractional part.

  read_timeout => 3.5,

Not set by default.

lazy => $boolean

If enabled, the connection establishes at time when you will send the first command to the server. By default the connection establishes after calling of the new method.

Disabled by default.

reconnect => $boolean

If the connection to the Redis server was lost and the parameter reconnect is TRUE, the client try to restore the connection on a next command execution unless min_reconnect_interval is specified. The client try to reconnect only once and if it fails, is called the on_error callback. If you need several attempts of the reconnection, just retry a command from the on_error callback as many times, as you need. This feature made the client more responsive.

Enabled by default.

min_reconnect_interval => $fractional_seconds

If the parameter is specified, the client will try to reconnect not often than through this interval.

  min_reconnect_interval => 5,

Not set by default.

handle_params => \%params

Specifies AnyEvent::Handle parameters.

  handle_params => {
    autocork => 1,
    linger   => 60,
  }

on_connect => $cb->()

The on_connect callback is called when the connection is successfully established.

Not set by default.

on_disconnect => $cb->()

The on_disconnect callback is called when the connection is closed by any reason.

Not set by default.

on_connect_error => $cb->( $err )

The on_connect_error callback is called, when the connection could not be established. If this callback isn't specified, the on_error callback is called.

Not set by default.

on_error => $cb->( $err )

The on_error callback is called when occurred an error, which was affected on entire client (e. g. connection error or authentication error). Also the on_error callback is called on command errors if command callback is not specified. If on_error callback is not specified, the client just print an error messages to STDERR.

COMMAND EXECUTION

<command>( [ @args ] [, $cb->( $reply, $err ) ] )

The callback in command method is optional and can be passed as last argument. If the callback specified, the reply is passed to the callback as first argument. If any error occurred during command execution, the error object is passed to the callback as second argument. If the callback in command method is not specified and error occurred, the on_error callback of the client is called.

Error object is the instance of the class AnyEvent::RipeRedis::Error and has two methods: message() to get error message and code() to get error code.

The full list of the Redis commands can be found here: http://redis.io/commands.

  $redis->set( 'foo', 'string' );

  $redis->get( 'foo',
    sub {
      my $reply = shift;
      my $err   = shift;

      if ( defined $err ) {
        # error handling...

        return;
      }

      print "$reply\n";
    }
  );

  $redis->lrange( 'list', 0, -1,
    sub {
      my $reply = shift;
      my $err   = shift;

      if ( defined $err ) {
        # error handling...

        return;
      }

      foreach my $value ( @{$reply}  ) {
        print "$value\n";
      }
    }
  );

TRANSACTIONS

The detailed information abount the Redis transactions can be found here: http://redis.io/topics/transactions.

multi( [ $cb->( $reply, $err ) ] )

Marks the start of a transaction block. Subsequent commands will be queued for atomic execution using EXEC.

exec( [ $cb->( $reply, $err ) ] )

Executes all previously queued commands in a transaction and restores the connection state to normal. When using WATCH, EXEC will execute commands only if the watched keys were not modified.

If during a transaction at least one command fails, to the callback of exec() method will be passed error object and the reply will be contain nested error objects for every failed command.

  $redis->multi();
  $redis->set( 'foo', 'string' );
  $redis->incr('foo');    # causes an error
  $redis->exec(
    sub {
      my $reply = shift;
      my $err   = shift;

      if ( defined $err ) {
        my $err_msg  = $err->message();
        my $err_code = $err->code();

        if ( defined $reply ) {
          foreach my $nested_reply ( @{$reply} ) {
            if ( ref($nested_reply) eq 'AnyEvent::RipeRedis::Error' ) {
              my $nested_err_msg  = $nested_reply->message();
              my $nested_err_code = $nested_reply->code();

              # error handling...
            }
          }

          return;
        }

        # error handling...

        return;
      }

      # reply handling...
    },
  );

discard( [ $cb->( $reply, $err ) ] )

Flushes all previously queued commands in a transaction and restores the connection state to normal.

If WATCH was used, DISCARD unwatches all keys.

watch( @keys [, $cb->( $reply, $err ) ] )

Marks the given keys to be watched for conditional execution of a transaction.

unwatch( [ $cb->( $reply, $err ) ] )

Forget about all watched keys.

SUBSCRIPTIONS

Once the client enters the subscribed state it is not supposed to issue any other commands, except for additional SUBSCRIBE, PSUBSCRIBE, UNSUBSCRIBE, PUNSUBSCRIBE and QUIT commands.

The detailed information about Redis Pub/Sub can be found here: http://redis.io/topics/pubsub

Subscribes the client to the specified channels. Method can accept two callbacks: on_reply and on_message. The on_reply callback is called once when subscription to all specified channels will be activated. In first argument to the callback is passed the number of channels we are currently subscribed. If subscription to specified channels was lost, the on_reply callback is called with the error object in the second argument. The on_message callback is called on every published message. If method is called with one callback, it will be act as on_message callback.

  $redis->subscribe( qw( foo bar ),
    { on_reply => sub {
        my $channels_num = shift;
        my $err          = shift;

        if ( defined $err ) {
          # error handling...

          return;
        }

        # reply handling...
      },

      on_message => sub {
        my $msg     = shift;
        my $channel = shift;

        # message handling...
      },
    }
  );

  $redis->subscribe( qw( foo bar ),
    sub {
      my $msg     = shift;
      my $channel = shift;

      # message handling...
    }
  );

psubscribe( @patterns, ( $cb | \%cbs ) )

Subscribes the client to the given patterns. See subscribe() method for details.

  $redis->psubscribe( qw( foo_* bar_* ),
    { on_reply => sub {
        my $channels_num = shift;
        my $err          = shift;

        if ( defined $err ) {
          # error handling...

          return;
        }

        # reply handling...
      },

      on_message => sub {
        my $msg     = shift;
        my $pattern = shift;
        my $channel = shift;

        # message handling...
      },
    }
  );

  $redis->psubscribe( qw( foo_* bar_* ),
    sub {
      my $msg     = shift;
      my $pattern = shift;
      my $channel = shift;

      # message handling...
    }
  );

publish( $channel, $message [, $cb->( $reply, $err ) ] )

Posts a message to the given channel.

unsubscribe( [ @channels ] [, $cb->( $reply, $err ) ] )

Unsubscribes the client from the given channels, or from all of them if none is given. In first argument to the callback is passed the number of channels we are currently subscribed or zero if we are unsubscribed from all channels.

  $redis->unsubscribe( qw( foo bar ),
    sub {
      my $channels_num = shift;
      my $err          = shift;

      if ( defined $err ) {
        # error handling...

        return;
      }

      # reply handling...
    }
  );

punsubscribe( [ @patterns ] [, $cb->( $reply, $err ) ] )

Unsubscribes the client from the given patterns, or from all of them if none is given. See unsubscribe() method for details.

  $redis->punsubscribe( qw( foo_* bar_* ),
    sub {
      my $channels_num = shift;
      my $err          = shift;

      if ( defined $err ) {
        # error handling...

        return;
      }

      # reply handling...
    }
  );

CONNECTION VIA UNIX-SOCKET

Redis 2.2 and higher support connection via UNIX domain socket. To connect via a UNIX-socket in the parameter host you have to specify unix/, and in the parameter port you have to specify the path to the socket.

  my $redis = AnyEvent::RipeRedis->new(
    host => 'unix/',
    port => '/tmp/redis.sock',
  );

LUA SCRIPTS EXECUTION

Redis 2.6 and higher support execution of Lua scripts on the server side. To execute a Lua script you can send one of the commands EVAL or EVALSHA, or use the special method eval_cached().

eval_cached( $script, $numkeys [, @keys ] [, @args ] [, $cb->( $reply, $err ) ] ] );

When you call the eval_cached() method, the client first generate a SHA1 hash for a Lua script and cache it in memory. Then the client optimistically send the EVALSHA command under the hood. If the E_NO_SCRIPT error will be returned, the client send the EVAL command.

If you call the eval_cached() method with the same Lua script, client don not generate a SHA1 hash for this script repeatedly, it gets a hash from the cache instead.

  $redis->eval_cached( 'return { KEYS[1], KEYS[2], ARGV[1], ARGV[2] }',
      2, 'key1', 'key2', 'first', 'second',
    sub {
      my $reply = shift;
      my $err   = shift;

      if ( defined $err ) {
        # error handling...

        return;
      }

      foreach my $value ( @{$reply}  ) {
        print "$value\n";
      }
    }
  );

Be care, passing a different Lua scripts to eval_cached() method every time cause memory leaks.

If Lua script returns multi-bulk reply with at least one error reply, to the callback of eval_cached method will be passed error object and the reply will be contain nested error objects.

  $redis->eval_cached( "return { 'foo', redis.error_reply( 'Error.' ) }", 0,
    sub {
      my $reply = shift;
      my $err   = shift;

      if ( defined $err ) {
        my $err_msg  = $err->message;
        my $err_code = $err->code;

        if ( defined $reply ) {
          foreach my $nested_reply ( @{$reply} ) {
            if ( ref($nested_reply) eq 'AnyEvent::RipeRedis::Error' ) {
              my $nested_err_msg  = $nested_reply->message();
              my $nested_err_code = $nested_reply->code();

              # error handling...
            }
          }
        }

        # error handling...

        return;
      }

      # reply handling...
    }
  );

ERROR CODES

Error codes can be used for programmatic handling of errors. AnyEvent::RipeRedis provides constants of error codes, which can be imported and used in expressions.

  use AnyEvent::RipeRedis qw( :err_codes );

E_CANT_CONN: Can't connect to the server. All operations were aborted.
E_LOADING_DATASET: Redis is loading the dataset in memory.
E_IO: Input/Output operation error. The connection to the Redis server was closed and all operations were aborted.
E_CONN_CLOSED_BY_REMOTE_HOST: The connection closed by remote host. All operations were aborted.
E_CONN_CLOSED_BY_CLIENT: Connection closed by client prematurely. Uncompleted operations were aborted.
E_NO_CONN: No connection to the Redis server. Connection was lost by any reason on previous operation.
E_OPRN_ERROR: Operation error. For example, wrong number of arguments for a command.
E_UNEXPECTED_DATA: The client received unexpected reply from the server. The connection to the Redis server was closed and all operations were aborted.
E_READ_TIMEDOUT: Read timed out. The connection to the Redis server was closed and all operations were aborted.

Error codes available since Redis 2.6.

E_NO_SCRIPT: No matching script. Use the EVAL command.
E_BUSY: Redis is busy running a script. You can only call SCRIPT KILL or SHUTDOWN NOSAVE.
E_MASTER_DOWN: Link with MASTER is down and slave-serve-stale-data is set to 'no'.
E_MISCONF: Redis is configured to save RDB snapshots, but is currently not able to persist on disk. Commands that may modify the data set are disabled. Please check Redis logs for details about the error.
E_READONLY: You can't write against a read only slave.
E_OOM: Command not allowed when used memory > 'maxmemory'.
E_EXEC_ABORT: Transaction discarded because of previous errors.

Error codes available since Redis 2.8.

E_NO_AUTH: Authentication required.
E_WRONG_TYPE: Operation against a key holding the wrong kind of value.
E_NO_REPLICAS: Not enough good slaves to write.
E_BUSY_KEY: Target key name already exists.

Error codes available since Redis 3.0.

E_CROSS_SLOT: Keys in request don't hash to the same slot.
E_TRY_AGAIN: Multiple keys request during rehashing of slot.
E_ASK: Redirection required. For more information see: http://redis.io/topics/cluster-spec
E_MOVED: Redirection required. For more information see: http://redis.io/topics/cluster-spec
E_CLUSTER_DOWN: The cluster is down or hash slot not served.

DISCONNECTION

When the connection to the server is no longer needed you can close it in three ways: call the method disconnect(), send the QUIT command or you can just "forget" any references to an AnyEvent::RipeRedis object, but in this case a client object is destroyed without calling any callbacks, including the on_disconnect callback, to avoid an unexpected behavior.

disconnect()

The method for synchronous disconnection. All uncompleted operations will be aborted.

  $redis->disconnect();

quit( [ $cb->( $reply, $err ) ] )

The method for asynchronous disconnection.

OTHER METHODS

info( [ $section ] [, $cb->( $reply, $err ) ] )

Gets and parses information and statistics about the server. The result is passed to callback as a hash reference.

More information abount INFO command can be found here: http://redis.io/commands/info

host()

Get current host of the client.

port()

Get current port of the client.

select( $index, [, $cb->( $reply, $err ) ] )

Selects the database by numeric index.

selected_database()

Get selected database index.

utf8( [ $boolean ] )

Enables or disables UTF-8 mode.

connection_timeout( [ $fractional_seconds ] )

Get or set the connection_timeout of the client. The undef value resets the connection_timeout to default value.

read_timeout( [ $fractional_seconds ] )

Get or set the read_timeout of the client.

reconnect( [ $boolean ] )

Enables or disables reconnection mode of the client.

min_reconnect_interval( [ $fractional_seconds ] )

Get or set min_reconnect_interval of the client.

on_connect( [ $callback ] )

Get or set the on_connect callback.

on_disconnect( [ $callback ] )

Get or set the on_disconnect callback.

on_connect_error( [ $callback ] )

Get or set the on_connect_error callback.

on_error( [ $callback ] )

Get or set the on_error callback.

AUTHOR

Eugene Ponizovsky, <ponizovsky@gmail.com>

Special thanks

Alexey Shrub
Vadim Vlasov
Konstantin Uvarin
Ivan Kruglov

COPYRIGHT AND LICENSE

This module is free software; you can redistribute it and/or modify it under the same terms as Perl itself.

To install AnyEvent::RipeRedis, copy and paste the appropriate command in to your terminal.

cpanm

cpanm AnyEvent::RipeRedis

CPAN shell

perl -MCPAN -e shell
install AnyEvent::RipeRedis

For more information on module installation, please visit the detailed CPAN module installation guide.

	Global
`s`	Focus search bar
`?`	Bring up this help dialog

	GitHub
`g` `p`	Go to pull requests
`g` `i`	go to github issues (only if github is preferred repository)

	POD
`g` `a`	Go to author
`g` `c`	Go to changes
`g` `i`	Go to issues
`g` `d`	Go to dist
`g` `r`	Go to repository/SCM
`g` `s`	Go to source
`g` `b`	Go to file browse

	Search terms
module: (e.g. module:Plugin)
distribution: (e.g. distribution:Dancer auth)
author: (e.g. author:SONGMU Redis)
version: (e.g. version:1.00)

NAME

SYNOPSIS

DESCRIPTION

CONSTRUCTOR

new( %params )

COMMAND EXECUTION

<command>( [ @args ] [, $cb->( $reply, $err ) ] )

TRANSACTIONS

multi( [ $cb->( $reply, $err ) ] )

exec( [ $cb->( $reply, $err ) ] )

discard( [ $cb->( $reply, $err ) ] )

watch( @keys [, $cb->( $reply, $err ) ] )

unwatch( [ $cb->( $reply, $err ) ] )

SUBSCRIPTIONS

subscribe( @channels, ( $cb | \%cbs ) )

psubscribe( @patterns, ( $cb | \%cbs ) )

publish( $channel, $message [, $cb->( $reply, $err ) ] )

unsubscribe( [ @channels ] [, $cb->( $reply, $err ) ] )

punsubscribe( [ @patterns ] [, $cb->( $reply, $err ) ] )

CONNECTION VIA UNIX-SOCKET

LUA SCRIPTS EXECUTION

eval_cached( $script, $numkeys [, @keys ] [, @args ] [, $cb->( $reply, $err ) ] ] );

ERROR CODES

DISCONNECTION

disconnect()

quit( [ $cb->( $reply, $err ) ] )

OTHER METHODS

info( [ $section ] [, $cb->( $reply, $err ) ] )

host()

port()

select( $index, [, $cb->( $reply, $err ) ] )

selected_database()

utf8( [ $boolean ] )

connection_timeout( [ $fractional_seconds ] )

read_timeout( [ $fractional_seconds ] )

reconnect( [ $boolean ] )

min_reconnect_interval( [ $fractional_seconds ] )

on_connect( [ $callback ] )

on_disconnect( [ $callback ] )

on_connect_error( [ $callback ] )

on_error( [ $callback ] )

SEE ALSO

AUTHOR

Special thanks

COPYRIGHT AND LICENSE

Module Install Instructions