The London Perl and Raku Workshop takes place on 26th Oct 2024. If your company depends on Perl, please consider sponsoring and/or attending.
 / 
Socket-1.95_002
River stage five • 306 direct dependents • 12716 total dependents
9 ++
/ Socket

NAME

Socket - networking constants and structure manipulators

SYNOPSIS

This is a low-level module used by, among other things, the IO::Socket family of modules. The following examples demonstrate some low-level uses but a practical program would likely use the higher-level API provided by IO::Socket or similar instead.

 use Socket qw(PF_INET SOCK_STREAM pack_sockaddr_in inet_aton);

 socket(my $socket, PF_INET, SOCK_STREAM, 0)
     or die "socket: $!";

 my $port = getservbyname "echo", "tcp";
 connect($socket, pack_sockaddr_in($port, inet_aton("localhost")))
     or die "connect: $!";

 print $socket "Hello, world!\n";
 print <$socket>;

 use Socket qw(
     PF_INET6 SOCK_DGRAM 
     IPPROTO_IPV6 IPV6_V6ONLY
     AF_INET6 pack_sockaddr_in6 inet_pton
     unpack_sockaddr_in6 inet_ntop
 );

 socket(my $socket, PF_INET6, SOCK_DGRAM, 0)
     or die "socket: $!";
 setsockopt($socket, IPPROTO_IPV6, IPV6_V6ONLY, 1)
     or die "setsockopt: $!";
 bind($socket, pack_sockaddr_in6(12345, inet_pton(AF_INET6, "::1")))
     or die "bind: $!";
 
 while(my $sender = recv($socket, my $packet, 8192)) {
     my $sin6 = (unpack_sockaddr_in6 $sender)[1];
     print "Received packet from ", inet_ntop(AF_INET6, $sin6), "\n";
 }

 use Socket qw(PF_UNIX SOCK_STREAM pack_sockaddr_un unpack_sockaddr_un);

 socket(my $socket, PF_UNIX, SOCK_STREAM, 0)
     or die "socket: $!";
 bind($socket, pack_sockaddr_un("/var/run/usock"))
     or die "bind: $!";
 listen($socket, 5)
     or die "listen: $!";

 while(my $conn = accept($socket)) {
     my $peer = getpeername($conn);
     print "Accepted a connection from ",
         unpack_sockaddr_un($peer), "\n";
 }

DESCRIPTION

This module provides a variety of constants, structure manipulators and other functions related to socket-based networking. The values and functions provided are useful when used in conjunction with Perl core functions such as socket(), setsockopt() and bind(). It also provides several other support functions, mostly for dealing with conversions of network addresses between human-readable and native binary forms, and for hostname resolver operations.

Some constants and functions are exported by default by this module; but for backward-compatibility any recently-added symbols are not exported by default and must be requested explicitly. When an import list is provided to the use Socket line, the default exports are not automatically imported. It is therefore best practice to always to explicitly list all the symbols required.

Also, some common socket "newline" constants are provided: the constants CR, LF, and CRLF, as well as $CR, $LF, and $CRLF, which map to \015, \012, and \015\012. If you do not want to use the literal characters in your programs, then use the constants provided here. They are not exported by default, but can be imported individually, and with the :crlf export tag:

 use Socket qw(:DEFAULT :crlf);

 $sock->print( "GET / HTTP/1.0$CRLF" );

The entire getaddrinfo() subsystem can be exported using the tag :addrinfo; this exports the getaddrinfo() and getnameinfo() functions, and all the AI_*, NI_*, NIx_* and EAI_* constants.

CONSTANTS

The following constants are exported by default. In each of the following groups, there may be many more constants provided than just the ones given as examples in the section heading. If the heading ends ... then this means there are likely more; the exact constants provided will depend on the OS and headers found at compile-time.

PF_INET, PF_INET6, PF_UNIX, ...

Protocol family constants to use as the first argument to socket() or the value of the SO_FAMILY socket option.

AF_INET, AF_INET6, AF_UNIX, ...

Address family constants used by the socket address structures, to pass to such functions as inet_pton() or getaddrinfo(), or are returned by such functions as sockaddr_family().

SOCK_STREAM, SOCK_DGRAM, SOCK_RAW, ...

Socket type constants to use as the second argument to socket(), or the value of the SO_TYPE socket option.

SOL_SOCKET

Socket option level constant for setsockopt() and getsockopt().

SO_ACCEPTCONN, SO_BROADCAST, SO_ERROR, ...

Socket option name constants for setsockopt() and getsockopt() at the SOL_SOCKET level.

IP_OPTIONS, IP_TOS, IP_TTL, ...

Socket option name constants for IPv4 socket options at the IPPROTO_IP level.

MSG_BCAST, MSG_OOB, MSG_TRUNC, ...

Message flag constants for send() and recv().

SHUT_RD, SHUT_RDWR, SHUT_WR

Direction constants for shutdown().

INADDR_ANY, INADDR_BROADCAST, INADDR_LOOPBACK, INADDR_NONE

Constants giving the special AF_INET addresses for wildcard, broadcast, local loopback, and invalid addresses.

Normally equivalent to inet_aton('0.0.0.0'), inet_aton('255.255.255.255'), inet_aton('localhost') and inet_aton('255.255.255.255') respectively.

The following constants are exported by request.

IPPROTO_IP, IPPROTO_IPV6, IPPROTO_TCP, ...

IP protocol constants to use as the third argument to socket(), the level argument to getsockopt() or setsockopt(), or the value of the SO_PROTOCOL socket option.

TCP_CORK, TCP_KEEPALIVE, TCP_NODELAY, ...

Socket option name constants for TCP socket options at the IPPROTO_TCP level.

IN6ADDR_ANY, IN6ADDR_LOOPBACK

Constants giving the special AF_INET6 addresses for wildcard and local loopback.

Normally equivalent to inet_pton(AF_INET6, "::") and inet_pton(AF_INET6, "::1") respectively.

IPV6_ADD_MEMBERSHIP, IPV6_MTU, IPV6_V6ONLY, ...

Socket option name constants for IPv6 socket options at the IPPROTO_IPV6 level.

STRUCTURE MANIPULATORS

The following functions convert between lists of Perl values and packed binary strings representing structures and are exported by default.

FAMILY = sockaddr_family SOCKADDR

Takes a packed socket address (as returned by pack_sockaddr_in(), pack_sockaddr_un() or the perl builtin functions getsockname() and getpeername()). Returns the address family tag. This will be one of the AF_* constants, such as AF_INET for a sockaddr_in addresses or AF_UNIX for a sockaddr_un. It can be used to figure out what unpack to use for a sockaddr of unknown type.

SOCKADDR = pack_sockaddr_in PORT, IP_ADDRESS

Takes two arguments, a port number and an opaque string (as returned by inet_aton(), or a v-string). Returns the sockaddr_in structure with those arguments packed in and AF_INET filled in. For Internet domain sockets, this structure is normally what you need for the arguments in bind(), connect(), and send().

( PORT, IP_ADDRESS ) = unpack_sockaddr_in SOCKADDR_IN

Takes a sockaddr_in structure (as returned by pack_sockaddr_in(), getpeername() or recv()). Returns a list of two elements: the port and an opaque string representing the IP address (you can use inet_ntoa() to convert the address to the four-dotted numeric format). Will croak if the structure does not represent an AF_INET address.

SOCKADDR = sockaddr_in PORT, IP_ADDRESS
( PORT, IP_ADDRESS ) = sockaddr_in SOCKADDR

A wrapper of pack_sockaddr_in() or unpack_sockaddr_in(). In list context, unpacks its argument and returns a list consisting of the port and IP address. In scalar context, packs its port and IP address arguments as a sockaddr_in and returns it.

Provided largely for legacy compatibility; it is better to use pack_sockaddr_in() or unpack_sockaddr_in() explicitly.

SOCKADDR = pack_sockaddr_in6 PORT, IP6_ADDRESS, [ SCOPE_ID, [ FLOWINFO ] ]

Takes two to four arguments, a port number, an opaque string (as returned by inet_pton()), optionally a scope ID number, and optionally a flow label number. Returns the sockaddr_in6 structure with those arguments packed in and AF_INET6 filled in. IPv6 equivalent of pack_sockaddr_in().

( PORT, IP6_ADDRESS, SCOPE_ID, FLOWINFO ) = unpack_sockaddr_in6 SOCKADDR_IN6

Takes a sockaddr_in6 structure. Returns a list of four elements: the port number, an opaque string representing the IPv6 address, the scope ID, and the flow label. (You can use inet_ntop() to convert the address to the usual string format). Will croak if the structure does not represent an AF_INET6 address.

SOCKADDR = sockaddr_in6 PORT, IP6_ADDRESS, [ SCOPE_ID, [ FLOWINFO ] ]
( PORT, IP6_ADDRESS, SCOPE_ID, FLOWINFO ) = sockaddr_in6 SOCKADDR

A wrapper of pack_sockaddr_in6() or unpack_sockaddr_in6(). In list context, unpacks its argument according to unpack_sockaddr_in6(). In scalar context, packs its arguments according to pack_sockaddr_in6().

Provided largely for legacy compatibility; it is better to use pack_sockaddr_in6() or unpack_sockaddr_in6() explicitly.

SOCKADDR = pack_sockaddr_un PATH

Takes one argument, a pathname. Returns the sockaddr_un structure with that path packed in with AF_UNIX filled in. For PF_UNIX sockets, this structure is normally what you need for the arguments in bind(), connect(), and send().

( PATH ) = unpack_sockaddr_un SOCKADDR

Takes a sockaddr_un structure (as returned by pack_sockaddr_un(), getpeername() or recv()). Returns a list of one element: the pathname. Will croak if the structure does not represent an AF_UNIX address.

SOCKADDR = sockaddr_un PATH
( PATH ) = sockaddr_un SOCKADDR

A wrapper of pack_sockaddr_un() or unpack_sockaddr_un(). In a list context, unpacks its argument and returns a list consisting of the pathname. In a scalar context, packs its pathname as a sockaddr_un and returns it.

Provided largely for legacy compatibility; it is better to use pack_sockaddr_un() or unpack_sockaddr_un() explicitly.

These are only supported if your system has <sys/un.h>.

The following pairs of functions are exported by request.

IPV6_MREQ = pack_ipv6_mreq IP6_MULTIADDR, INTERFACE

Takes an IPv6 address and an interface number. Returns the ipv6_mreq structure with those arguments packed in. Suitable for use with the IPV6_ADD_MEMBERSHIP and IPV6_DROP_MEMBERSHIP sockopts.

( IP6_MULTIADDR, INTERFACE ) = unpack_ipv6_mreq IPV6_MREQ

Takes an ipv6_mreq structure. Returns a list of two elements; the IPv6 address and an interface number.

FUNCTIONS

The following functions are exported by default.

IP_ADDRESS = inet_aton HOSTNAME

Takes a string giving the name of a host, or a textual representation of an IP address and translates that to an packed binary address structure suitable to pass to pack_sockaddr_in(). If passed a hostname that cannot be resolved, returns undef. For multi-homed hosts (hosts with more than one address), the first address found is returned.

For portability do not assume that the result of inet_aton() is 32 bits wide, in other words, that it would contain only the IPv4 address in network order.

This IPv4-only function is provided largely for legacy reasons. Newly-written code should use getaddrinfo() or inet_pton() instead for IPv6 support.

STRING = inet_ntoa IP_ADDRESS

Takes a packed binary address structure such as returned by unpack_sockaddr_in() (or a v-string representing the four octets of the IPv4 address in network order) and translates it into a string of the form d.d.d.d where the ds are numbers less than 256 (the normal human-readable four dotted number notation for Internet addresses).

This IPv4-only function is provided largely for legacy reasons. Newly-written code should use getnameinfo() or inet_ntop() instead for IPv6 support.

The following functions are exported by request.

IP_ADDRESS = inet_pton ADDRESS_FAMILY, HOSTNAME

Takes an address family (such as AF_INET or AF_INET6) and a string giving the name of a host, or a textual representation of an IP address and translates that to an packed binary address structure.

See also getaddrinfo() for a more powerful and flexible function to look up socket addresses given hostnames or textual addresses.

STRING = inet_ntop ADDRESS_FAMILY, IP_ADDRESS

Takes an address family and a packed binary address structure and translates it into a human-readable textual representation of the address; typically in d.d.d.d form for AF_INET or hhhh:hhhh::hhhh form for AF_INET6.

See also getnameinfo() for a more powerful and flexible function to turn socket addresses into human-readable textual representations.

( ERR, RESULT ... ) = getaddrinfo HOST, SERVICE, [ HINTS ]

Given both a hostname and service name, this function attempts to resolve the host name into a list of network addresses, and the service name into a protocol and port number, and then returns a list of address structures suitable to connect() to it.

Given just a host name, this function attempts to resolve it to a list of network addresses, and then returns a list of address structures giving these addresses.

Given just a service name, this function attempts to resolve it to a protocol and port number, and then returns a list of address structures that represent it suitable to bind() to. This use should be combined with the AI_PASSIVE flag; see below.

Given neither name, it generates an error.

If present, HINTS should be a reference to a hash, where the following keys are recognised:

flags => INT

A bitfield containing AI_* constants; see below.

family => INT

Restrict to only generating addresses in this address family

socktype => INT

Restrict to only generating addresses of this socket type

protocol => INT

Restrict to only generating addresses for this protocol

The return value will be a list; the first value being an error indication, followed by a list of address structures (if no error occurred).

 my ( $err, @results ) = getaddrinfo( ... );

The error value will be a dualvar; comparable to the EI_* error constants, or printable as a human-readable error message string. If no error occurred it will be zero numerically and an empty string.

Each value in the results list will be a hash reference containing the following fields:

family => INT

The address family (e.g. AF_INET)

socktype => INT

The socket type (e.g. SOCK_STREAM)

protocol => INT

The protocol (e.g. IPPROTO_TCP)

addr => STRING

The address in a packed string (such as would be returned by pack_sockaddr_in())

canonname => STRING

The canonical name for the host if the AI_CANONNAME flag was provided, or undef otherwise. This field will only be present on the first returned address.

The following flag constants are recognised in the HINTS hash. Other flag constants may exist as provided by the OS.

AI_PASSIVE

Indicates that this resolution is for a local bind() for a passive (i.e. listening) socket, rather than an active (i.e. connecting) socket.

AI_CANONNAME

Indicates that the caller wishes the canonical hostname (canonname) field of the result to be filled in.

AI_NUMERICHOST

Indicates that the caller will pass a numeric address, rather than a hostname, and that getaddrinfo() must not perform a resolve operation on this name. This flag will prevent a possibly-slow network lookup operation, and instead return an error if a hostname is passed.

( HOSTNAME, SERVICENAME ) = getnameinfo ADDR, FLAGS, XFLAGS

Given a packed socket address (such as from getsockname(), getpeername(), or returned by getaddrinfo() in a addr field), returns the hostname and symbolic service name it represents. FLAGS may be a bitmask of NI_* constants, or defaults to 0 if unspecified.

The return value will be a list; the first value being an error condition, followed by the hostname and service name.

 my ( $err, $host, $service ) = getnameinfo( ... );

The error value will be a dualvar; comparable to the EI_* error constants, or printable as a human-readable error message string. The host and service names will be plain strings.

The following flag constants are recognised as FLAGS. Other flag constants may exist as provided by the OS.

NI_NUMERICHOST

Requests that a human-readable string representation of the numeric address be returned directly, rather than performing a name resolve operation that may convert it into a hostname. This will also avoid potentially-blocking network IO.

NI_NUMERICSERV

Requests that the port number be returned directly as a number representation rather than performing a name resolve operation that may convert it into a service name.

NI_NAMEREQD

If a name resolve operation fails to provide a name, then this flag will cause getnameinfo() to indicate an error, rather than returning the numeric representation as a human-readable string.

NI_DGRAM

Indicates that the socket address relates to a SOCK_DGRAM socket, for the services whose name differs between TCP and UDP protocols.

The following constants may be supplied as XFLAGS.

NIx_NOHOST

Indicates that the caller is not interested in the hostname of the result, so it does not have to be converted. undef will be returned as the hostname.

NIx_NOSERV

Indicates that the caller is not interested in the service name of the result, so it does not have to be converted. undef will be returned as the service name.

getaddrinfo() / getnameinfo() ERROR CONSTANTS

The following constants may be returned by getaddrinfo() or getnameinfo(). Others may be provided by the OS.

EAI_AGAIN

A temporary failure occurred during name resolution. The operation may be successful if it is retried later.

EAI_BADFLAGS

The value of the flags hint to getaddrinfo(), or the FLAGS parameter to getnameinfo() contains unrecognised flags.

EAI_FAMILY

The family hint to getaddrinfo(), or the family of the socket address passed to getnameinfo() is not supported.

EAI_NODATA

The host name supplied to getaddrinfo() did not provide any usable address data.

EAI_NONAME

The host name supplied to getaddrinfo() does not exist, or the address supplied to getnameinfo() is not associated with a host name and the NI_NAMEREQD flag was supplied.

EAI_SERVICE

The service name supplied to getaddrinfo() is not available for the socket type given in the HINTS.

AUTHOR

This module was originally maintained in Perl core by the Perl 5 Porters.

It was extracted to dual-life on CPAN at version 1.95 by Paul Evans <leonerd@leonerd.org.uk>